; Install script for TIFFView (Workbench 2.1 or higher)

(set @default-dest "SYS:Tools")
(set old_level @user-level)

(set reqtoolslib "reqtools.library")
(set TIFFViewapp "TIFFView")

;=============================================================================
; English strings

(set default_lang 1)

(set #bad-kick
(cat "You must be using Kickstart 2.04 to install using this script!"
))

(set #reqtools-copy "Copying reqtools.library to Libs:...")
(set #reqtools-help "Copies the reqtools.library to the Libs: directory")

(set #TIFFView-copy "Copying TIFFView...")
(set #TIFFView-help "Copies TIFFView to your disk for usage.")

(set #select-TIFFView "Select the location to install TIFFView")
(set #select-help "Choose a destination directory to contain the TIFFView application")

(set #which-language
(cat "\nWhich languages should be installed?"
))
(set #which-language-help
(cat "\nThe Amiga can be operated in many different "
	  "languages. If you want TIFFView to use the same "
	  "language as the Amiga Workbench "
	  "then a catalog file must be copied to your"
	  " system disk for each language supported.\n\n"
	  "To reduce the amount of space consumed by the"
	  " language files, you can select to have only the"
	  " files of specific languages copied.\n\n"
	  "Simply check the boxes of the languages you wish"
	  " to have available on your system.\n\n"
	  @askoptions-help
))

(set #install-msg
(cat "\n\nTIFFView installation script.\n"
     "This script installs TIFFView and the ReqTools.library on your Amiga.\n\n"
     "Read the TIFFView.readme file for more information.\n"
	 "TIFFView © 1993 Bert Wynants\n"
     "ReqTools © 1991-1993 Nico François\n"
     "All rights reserved."
))


;=============================================================================
; Dutch strings

(if (= @language "nederlands")
(

(set default_lang 4)

(set #bad-kick
(cat "U moet Kickstart 2.04 gebruiken om met dit installatie script te installeren!"
))

(set #reqtools-copy "Kopieer reqtools.library naar Libs:...")
(set #reqtools-help "Kopieert de reqtools.library naar de Libs: lade")

(set #TIFFView-copy "Kopieer TIFFView...")
(set #TIFFView-help "Kopieert TIFFView naar uw disk om te gebruiken")

(set #select-TIFFView "Selecteer de lade om TIFFView te installeren")
(set #select-help "Kies de lade waarin de TIFFView applicatie moet komen")

(set #which-language
(cat "\nWelke talen moeten geïnstalleerd worden?"
))
(set #which-language-help
(cat "\nDe Amiga kan werken in verschillende talen."
	  " Als u wilt dat TIFFView in dezelfde taal werkt als uw Workbbench"
	  " dan moet er voor elke taal een bestand naar"
	  " uw systeem disk gekopieerd worden.\n\n"
	  "Om de grootte van het geheugen die de taal bestanden"
	  " innemen te verkleinen, kunt u een keuze maken uit"
	  " de talen, die vervolgens naar uw systeem disk worden"
	  " gekopieerd .\n\nU hoeft alleen die talen die u op"
	  " uw systeem wilt hebben aan te klikken.\n\n"
     @askoptions-help
))

(set #install-msg
(cat "\n\nTIFFView installatie script.\n"
     "Dit script installeert TIFFView en de ReqTools library op uw Amiga.\n\n"
     "Lees het TIFFView.readme bestand voor meer informatie\n"
	 "TIFFView © 1993 Bert Wynants\n"
     "ReqTools © 1991-1993 Nico François\n"
     "All rights reserved."
))

))

;=============================================================================
; procedure to call on exit...

(procedure TERMINATE

)

;=============================================================================
; termination stuff

(onerror (TERMINATE))

;=============================================================================
; make sure we are running under a 2.04 ROM

(if (< (/ (getversion) 65536) 37)
(
    (abort #bad-kick)
))

;=============================================================================

(message #install-msg)

; copy reqtools, including version checking

(copylib
		(prompt "\n" #reqtools-copy)
		(help #reqtools-help)
		(source reqtoolslib)
		(dest "Libs:")
		(confirm)
)

(complete 20)

(set thedest 
		(askdir (prompt #select-TIFFView)
    			(default @default-dest)
	    		(help #select-help)
        )
)

; copy TIFFView, including version checking
(copylib
	(prompt "\n" #TIFFView-copy)
	(help #TIFFView-help)
	(source TIFFViewapp)
	(dest thedest)
	(infos)
	(confirm)
)

(complete 50)

(if (exists "SYS:Locale")
(
	(if (exists "LOCALE:")
	(
		(user 2)
		(set lang (askoptions (prompt #which-language)
							  (help #which-language-help)
							  (choices "English" "Nederlands")
							  (default default_lang)
				  )
		)
		(user old_level)

		(set n 0)
		(while (set language (select n "english" "nederlands" ""))
		(
			(if (IN lang n)
			(
				(if (<> 0 n)
				(
					(makedir (cat "LOCALE:Catalogs/" language))
					(copyfiles (source (cat "Catalogs/" language))
							   (dest (cat "LOCALE:Catalogs/" language))
							   (all)
					)
				))
			))
			(set n (+ n 1))
		))
	))
))

(complete 100)