;**************************************************************************
;
; Filename : KEY_LÖSCH.ASM
; ------------------------
;
; (c) 1990 by Thomas Lehmann
;
;
; Jackophone V5.00
;
;
; Lösch-Funktionen
;
;
;**************************************************************************

MODUL_START	set	*	; Größe des Moduls berechnen

; =========================================================================
;
; Funktion	: Löschfunktion in Abhängigkeit des Wta-Prg. ausgeführt
;
; Eingang	: bei Löschentaste
;	: Offset auf Tastaturtabelle in X-Reg.
;	: Tastenwert in "tw"
;
; Ausgang	: --------
;
; Register	: Accu, X
;
; (c) by Thomas Lehmann Januar 1991
;
; =========================================================================

key_loesch	ldx #$00	; Ptr. auf Tabellenstart

key_loe_lp	lda loesch_tab,x	; Wähltastenprg. für Löschfunktion laden
	cmp #$ff	; Tabellenende
	beq key_loe_1	; ja, Löschfunktion ausführen

	cmp wta_prg	; Funktion gefunden ?
	beq key_loe_1	; ja, Löschfunktion ausführen

	inx		; Ptr. auf nächsten Eintrag
	inx
	inx
	bra key_loe_lp

key_loe_1	jmp (loesch_tab+1,x)	; Lösch-Programm ausführen


; -----------------------------------------------------------------------
; die Tabelle der Löschtastenfunktionen ist abhängig von dem WTA-Programm
; -----------------------------------------------------------------------

loesch_tab	byte WTA_WAHL
	word err_ter_clr	; erreichten Termin clr, (Ruhezustand)

	byte WTA_UHRSET
	word uhrset_clr	; Uhr stellen

	byte WTA_SPNAM
	word namziff_clr	; Namentasten speichern, letzte Ziffer clr

	byte WTA_TERMEIN
	word term_clr	; Termin löschen, (Terminzeit eingeben)

	byte WTA_TERMTXT
	word ttxt_clr	; Termintext löschen, (Text für Termin eingeben)

	byte WTA_STAT
	word stat_clr	; Statistikdaten clr

	byte WTA_SPREL
	word rel_clr	; Relais speichern/kontrollieren


	byte $ff	; Tabellenende
	word _rts	; keine Löschfunktion ausführen






; --------------------------------------------------------------------------

HLP	set	*
_KEY_LOESCH	equ	HLP-MODUL_START		; Größe des Moduls