G4C

; Helper gui for sced.gc - Scala Script Editor
; Opens on double clicking of an item in CODE or FILE mode


winbig 0 0 80 60 ''
wintype 000010
winonmouse 30 7
varpath sced.gc

xOnRMB 
guiclose sc.DCline

xOnInactive
guiclose sc.DCline

xOnFail
ezreq "Error during operation" OK ""

xonopen
rec = $$lv.rec
cutvar rec copy word 1 obj
if $obj = PICTURE
or $obj = ANIM
or $obj = BRUSH
   setgad sc.DCline 1/2 ON
elseif $obj = SOUND			; only view these
   setgad sc.DCline 1 on
   setgad sc.DCline 2 off
else
   setgad sc.DCline 1/2 OFF
endif

; ------------------------------------------------------------------------
;       View item
; ------------------------------------------------------------------------

xbutton 0 0  0 15 View
gadid 1
gadhelp 'View selected item'
guiclose sc.DCline
oldmode = $mode
mode = $obj		; set mode temporarily
gosub sc.DCobj viewitem
mode = $oldmode
        
; ------------------------------------------------------------------------
;       Edit item
; ------------------------------------------------------------------------

xbutton 0 15 0 15 Edit
gadhelp 'Edit selected item (Picture, brush etc)'
gadid 2
guiclose sc.DCline
oldmode = $mode
mode = $obj		; set mode temporarily
gosub sc.DCobj edititem
mode = $oldmode


; ------------------------------------------------------------------------
;       Copy item over all other selected items
; ------------------------------------------------------------------------

xbutton 0 30 0 15 List
gadhelp 'List all similar lines in the script'
guiclose sc.DCline
cutvar item cut word 1 item
gosub sced.gc GetList $item


; ------------------------------------------------------------------------
;       Delete
; ------------------------------------------------------------------------

xbutton 0 45 0 15 Delete
gadhelp 'Delete selected item'
guiclose sc.DCline
lvuse sced.gc 1
linenum = $$lv.line
lvdel -1
if $mode = CODE
   linenum == $linenum + $eventstart
   lvuse sced.gc 2
   lvgo #$linenum
   lvdel -1
endif
saveflag = 1
gosub sced.gc report 'Deleted line $linenum' 1