;$VER:DigitalAlmanac Install_Exe 39.13

(if (= @language "deutsch")
	(
	(set #choose-dest "Wählen Sie ein Verzeichnis aus,\nwo Digital Almanac installiert werden soll.\nEine Schublade 'DigitalAlmanac' wird automatisch erzeugt.")
	(set #choose-lang "Wählen Sie eine Sprache für Digital Almanac aus.")
	(set #choose-lang-def 0)
	(set #msg-install "Installiere Digital Almanac.")
	(set #msg-async-requires "Digital Almanac benötigt asyncio.library 39.x.")
	(set #msg-xpk-requires "Digital Almanac benötigt Xpk.mcc 17.0.")
	(set #ask-rgfx "Soll das RGFX-Datatype 43.1 installiert werden ?")
	(set #help-rgfx "Das RGFX-Format bietet alle Vorteile eines IFF-Formates einschliesslich Xpk-Kompression.\nDie Dateigröße ist wesentlich kleiner als im ILBM-Format.")
	(set #ja "Ja (empfohlen)")
	(set #nein "Nein")
	(set #rgfx-lib "Wo befinden sich ihre Datatypes ?")
	(set #rgfx-dev "Wo befinden sich die Deskriptoren ?")
	(set #msg-assign "Digital Almanac benötigt einen assign\nin Ihrer S:User-Startup")
	(set #msg-exit "Booten Sie Ihren Amiga neu,\num Digital Almanac zu starten.\nVergessen Sie nicht, das Datenarchive zu installieren !!")
	)
)

(if (= @language "english")
	(
	(set #choose-dest "Choose directory to install Digital Almanac.\nA drawer 'DigitalAlmanac' will automatically be created.")
	(set #choose-lang "Select language you want to use with Digital Almanac.")
	(set #choose-lang-def 1)
	(set #msg-install "Installing Digital Almanac.")
	(set #msg-async-requires "Digital Almanac requires asyncio.library 39.x.")
	(set #msg-xpk-requires "Digital Almanac requires Xpk.mcc 17.0.")
	(set #ask-rgfx "Do you want to have the RGFX-Datatype 43.1 to be installed ?")
	(set #help-rgfx "The RGFX format offers all advantages of an IFF format including Xpk compression.\nThe file size is much smaller than with ILBM format.")
	(set #ja "Yes (recommended)")
	(set #nein "No")
	(set #rgfx-lib "Where do you store your datatypes ?")
	(set #rgfx-dev "Where do you store the the descriptors ?")
	(set #msg-assign "Digital Almanac needs an assign\nin your S:User-Startup")
	(set #msg-exit "Reboot your Amiga to start Digital Almanac.\nDon't forget to install the data archive !!")
	)
)

(if (= @language "français")
	(
	(set #choose-dest "Choisissez un répertoire pour installer Digital Almanac.\nUn tiroir 'DigitalAlmanac' sera crée automatiquement.")
	(set #choose-lang "Selectionnez la langue que vous voulez utiliser pour Digital Almanac.")
	(set #choose-lang-def 2)
	(set #msg-install "Installation de Digital Almanac.")
	(set #msg-async-requires "Digital Almanac nécessite asyncio.library 39.x.")
	(set #msg-xpk-requires "Digital Almanac nécessite Xpk.mcc 17.0.")
	(set #ask-rgfx "Do you want to have the RGFX-Datatype 43.1 to be installed ?")
	(set #help-rgfx "The RGFX format offers all advantages of an IFF format including Xpk compression.\nThe file size is much smaller than with ILBM format.")
	(set #ja "Oui (recommandé)")
	(set #nein "Non")
	(set #msg-assign "Digital Almanac besoin d'un assign\ndans votre S:User-Startup")
	(set #msg-exit "Redémarrer votre Amiga pour exécuter Digital Almanac.\nDon't forget to install the data archive !!")
	)
)

(set #inst-dir
	(askdir
		(prompt #choose-dest)
		(help @askdir-help)
		(default @default-dest)
		(disk)
	)
)

(set #dest-dir (tackon #inst-dir "DigitalAlmanac"))
(set #dest-cat-dir (tackon #dest-dir "Catalogs"))
(set #dest-fonts-dir (tackon #dest-dir "Fonts"))
(set #dest-icons-dir (tackon #dest-dir "Icons"))
(set #dest-pictures-dir (tackon #dest-dir "Pictures"))
(set #dest-projects-dir (tackon #dest-dir "Projects"))

(set #langcat
	(select
		(askchoice
			(prompt #choose-lang)
			(choices "Deutsch" "English" "Français")
			(help @askchoice-help)
			(default #choose-lang-def)
		)
	"Deutsch" "English" "Français"
	)
)

(set #src-lang-dir (tackon "//Catalogs" #langcat))
(set #src-docs-dir (tackon "//Docs" #langcat))
(set #dest-lang-dir (tackon #dest-cat-dir #langcat))

(working #msg-install)
(makedir #dest-dir)
(copyfiles
	(source "///Install_DigitalAlmanac.info")
	(dest #inst-dir)
	(newname (tackon #inst-dir "DigitalAlmanac.info"))
)
(copyfiles
	(source "//DigitalAlmanac")
	(dest #dest-dir)
	(infos)
)
(copyfiles
	(source (tackon #src-docs-dir "DigitalAlmanac.guide"))
	(dest #dest-dir)
	(infos)
)

(makedir #dest-cat-dir)
(makedir #dest-lang-dir)
(copyfiles
	(source (tackon #src-lang-dir "DigitalAlmanac.catalog"))
	(dest #dest-lang-dir)
)

(makedir #dest-fonts-dir)
(copyfiles
	(source "//Fonts")
	(dest #dest-fonts-dir)
	(all)
)

(makedir #dest-icons-dir)
(copyfiles
	(source "//Icons.info")
	(dest #dest-dir)
)
(copyfiles
	(source "//Icons")
	(dest #dest-icons-dir)
	(all)
)

(makedir #dest-pictures-dir)
(copyfiles
	(source "//Pictures.info")
	(dest #dest-dir)
)

(makedir #dest-projects-dir)
(copyfiles
	(source "//Projects.info")
	(dest #dest-dir)
)
(copyfiles
	(source "//Projects")
	(dest #dest-projects-dir)
	(all)
)
(copylib
	(prompt #msg-async-requires)
	(help @copylib-help)
	(source "//Libs/asyncio.library")
	(dest "LIBS:")
	(confirm)
)
(copylib
	(prompt #msg-xpk-requires)
	(help @copylib-help)
	(source "//Libs/Xpk.mcc")
	(dest "MUI:Libs/MUI")
	(confirm)
)
(startup "DigitalAlmanac"
	(prompt #msg-assign)
	(help @startup-help)
	(command "assign FONTS: \"" #dest-fonts-dir "\" add")
)

(set #rgfx
	(askchoice
		(prompt #ask-rgfx)
		(choices #ja #nein)
		(help #help-rgfx)
		(default 0)
	)
)

(if (= #rgfx 0)
	(
	(set #dt-dir
		(askdir
			(prompt #rgfx-lib)
			(help @askdir-help)
			(default "SYS:Classes/DataTypes")
			(disk)
		)
	)
	(set #de-dir
		(askdir
			(prompt #rgfx-dev)
			(help @askdir-help)
			(default "DEVS:DataTypes")
			(disk)
		)
	)
	(copylib
		(prompt "")
		(help @copylib-help)
		(source "//Libs/rgfx.datatype")
		(dest #dt-dir)
		(confirm)
	)
	(copyfiles
		(source "//Devs/DataTypes/RGFX")
		(dest #de-dir)
	)
	)
)

(set @default-dest #inst-dir)
(exit #msg-exit)