; ArtPRO installations Script
; © 1996 DEFECT SOFTWORKS All rights reserved.
; May only be distributed within the ArtPRO package
; 
; Written by Crazy Copper /DFT
; Date: 15/Jan/96

(set flasekickmsg	"You need at least OS 2.04 to run ArtPRO!")

(set OS_VER (/ (getversion) 65536) )

(if(< OS_VER 37)
  (abort falsekickmsg)
)

(Set #WhatInstall
(cat  "Which parts of the ArtPRO Package do you want to install now ?"
))

(set #InstallParts
		(askoptions
			(prompt #WhatInstall)
			(help @askoptions-help)
			(choices
				("ArtPRO Main Program")		;Bit 0
				("External Loaders")		;Bit 1
				("External Savers")		;Bit 2
				("Second IconSet")		;Bit 3
				("needed Libraries")		;Bit 4
				("Documentations")		;Bit 5
				("External AppIcon")		;Bit 6
			)
                        (default 127)
		)
)

(set progdir1
 (askdir (prompt "In wich drawer should ArtPRO be installed?\n (a drawer will be created)")
   (help @askdir-help)
   (DEFAULT @default-dest)))


(	(makedir (tackon progdir1 "ArtPRO")) 
	(copyfiles (source "Icons/ArtPRO.info")
	(dest progdir1))

	(set progdir (tackon progdir1 "ArtPRO"))
)
;--------------------------------------------------------------------------
(if (IN #InstallParts 0)
 (
	(copyfiles (source "ArtPRO")
	(dest progdir))

	(copyfiles (source "ArtPRO.info")
	(dest progdir))
 )
)

(if (IN #InstallParts 1)

 (
	(makedir (tackon progdir "ALoaders"))
	(copyfiles (source "Aloaders")
	(dest (tackon progdir "ALoaders"))
	(all))
 )
)

(if (IN #InstallParts 2)

 (
	(makedir (tackon progdir "ASavers"))
	(copyfiles (source "ASavers")
	(dest (tackon progdir "ASavers"))
	(all))
 )
)

(if (IN #InstallParts 4)

 (
	(copylib
		(prompt "Copy ReqTools.library")
		(help @copylib-help)
		(source "libs/reqTools.library")
		(dest "Libs:")
		(confirm)
		(optional "nofail"))
 )
)

(if (IN #InstallParts 5)

 (
	(set docdir
		(askdir (prompt "Select a drawer for the Guide:")
		(help @askdir-help)
		(DEFAULT progdir)))

	(copyfiles (source "ArtPRO.guide")
		(dest docdir))

	(copyfiles (source "ArtPRO.guide.info")
		(dest docdir))
 )
)

(if (IN #InstallParts 3)

 (
	(makedir (tackon progdir "Icons"))
	(copyfiles (source "Icons")
		(dest (tackon progdir "Icons"))
		(all))
	(copyfiles (source "Icons.info")
		(dest progdir))
 )
)

(if (IN #InstallParts 6)

 (
  (set appdir
  (askdir (prompt "In wich drawer should the external AppIcon be installed?")
   (help @askdir-help)
   (DEFAULT progdir)))

 	(copyfiles (source "Icons/AppIcon.info")
		(dest appdir)
	)
	(Tooltype (dest (tackon progdir "ArtPRO"))
		(Settooltype "APPICON" (tackon appdir "AppIcon"))
	)
 
 )
)

(set @default-dest progdir)

(copyfiles (source "Orderform.doc")
	(dest progdir)
)
(copyfiles (source "Orderform.dok")
	(dest progdir)
)
(makedir "ENV:ArtPRO")
(makedir "ENVARC:ArtPRO")

(exit "Note: ArtPRO is Shareware!\n\n"
      "Enjoy this!")