;**************************************************************************
;
; Filename : KEY_ENDE.ASM
; -----------------------
;
; (c) 1990 by Thomas Lehmann
;
;
; Jackophone V5.00
;
;
; Ende Taste auswerten
;
;
;**************************************************************************


; =========================================================================
;
; Type	: Hauptprg.
;
; Eingang	: bei Endetaste
;	: Offset auf Tastaturtabelle in X-Reg.
;	: Tastenwert im Accu
;
; Ausgang	: Displayanzeige umgeschaltet
;	: Speichern, Kontrolle ... ausgeschaltet
;	: Wähltastenprg. wieder original
;
; Register	: ------
;
; (c) by Thomas Lehmann März 1990
;
; =========================================================================

key_ende	stz modus	; kein Modus aktiv eintragen
	stz displ_prg	; Uhr anzeigen
	stz wta_prg	; Wähltasten normal auswerten

	lda #$ff
	sta term_nr	; Termintext eines erreichten Termins ausgeben

	pha		; Register retten
	phy
	ldy #LD_L|LD_R|LD_OFF	; Statusbyte laden

	lda #KEY_SP	; Tastenwert für Speichertaste laden
	jsr set_prgled	; alle zum Tastenwert gehörenden LED`s aus

	lda #KEY_KO	; Tastenwert für Kontrolltaste laden
	jsr set_prgled	; alle zum Tastenwert gehörenden LED`s aus

	lda #KEY_UHR	; Tastenwert für Uhrtaste laden
	jsr set_prgled	; alle zum Tastenwert gehörenden LED`s aus

	lda #KEY_NAM	; Tastenwert für Namentaste laden
	jsr set_prgled	; alle zum Tastenwert gehörenden LED`s aus

	jsr set_postbea	; Post und Beantworter-Relais + LED zurück

	bbr LTG_BEL,ltg_stat,key_ende_e	; keine Ltg. belegt

	jsr whl_displ	; Wahlziffern wieder ins Display
	lda #WHLCU_DISPL	; Wahlablauf-Cursorprg. Nr. laden
	sta displ_prg	; und bei Displayausgabe ausführen

key_ende_e	ply		; Register zurück
	pla
	rts