* CLS basiert auf dem MS-Dos Befehl CLS, es löscht den Bildschirm.
* cls ist PD, und wurde mit dem Wissen aus dem Buch von M&T erstellt.
* Ausführung: Öpfel am 25.11.`88
* --------------------------------------------------------------------

_SysBase         equ   4            ;Basis von Exec
_LVOOpenLibrary  equ    -552        ;Library oeffnen
_LVOCloseLibrary equ    -414        ;Library schliessen

_LVOOutput       equ    -60         ;DOS: Output-Handle holen
_LVOWrite        equ    -48         ;     Ausgabe

*DOS/Lib oeffnen:

_main   move.l   #dosname,a1             ;Nane der DOS-Lib 
        moveq   #0,d0                    ;Version egal
        move.l  _SysBase,a6              ;Basis Exec
        jsr     _LVOOpenLibrary(a6)      ;DOS-Lib oeffnen
        tst.l   d0                       ;Fehler?
        beq   fini                       ;wenn Fehler, Ende
        move.l   d0,_DOSBase             ;Zeiger merken

* Ausgabe-Handle ermitteln:

        move.l   _DOSBase,a6      ;DOS-Funktion rufen   
        jsr   _LVOOutput(a6)      ;Hole Output-Handle
        move.l   d0,d4            ;und in d4 merken

* nun Text ausgeben:

        move.l   d4,d1           ;Ausgabe-Handle
        move.l   #string,d2      ;Address Text
        moveq   #1,d3           ;Laenge Text
        move.l  _DOSBase,a6      ;Basis DOS
        jsr   _LVOWrite(a6)      ;Funktion "Schreiben"

* Zum Schluss immer die Lib schliessen!

        move.l   _DOSBase,a1           ;Basis der Lib
        move.l  _SysBase,a6            ;Basis Exec
        jsr     _LVOCloseLibrary(a6)   ;Funktion "Schliessen"

fini   rts            ;Return zum CLI

* Datenbereich:

_DOSBase dc.l   0

dosname    dc.b   'dos.library',0
    even   0,2

string     dc.b   12
    even   0,2

    end