;**************************************************************************
;
; Filename : SS.ASM
; -----------------
;
; (c) 1990 by Thomas Lehmann
;
;
; Jackophone V5.00
;
;
; Zustand des Schlüsselschalters ausgeben
;
;
;**************************************************************************

MODUL_START	set	*	; Größe des Moduls berechnen

; =========================================================================
;
; Funktion	: Zustand des SS direkt anzeigen
;
; Eingang	: ------
;
; Ausgang	: ------
;
; Register	: ------
;
; (c) by Thomas Lehmann Januar 1991
;
; =========================================================================

tst_ss	bbr DIP_SS,dip_stat,tst_ss_1		; SS ist ausgeschaltet

	; testen ob SS-ON Status bereits bekannt ist
	; ------------------------------------------
	bbs SS_STAT,allg_stat,tst_ss_end	; ja, Ende
	
	smb SS_STAT,allg_stat			; akt. Status eintragen
	bra tst_ss_2				; direkt anzeigen


	; testen ob SS-OFF Status bereits bekannt ist
	; -------------------------------------------
tst_ss_1	bbr SS_STAT,allg_stat,tst_ss_end	; ja, Ende

	rmb SS_STAT,allg_stat			; akt. Status eintragen
tst_ss_2	rmb 7,sekunde				; direktes Update
	jmp baby_ss				; Babyphone testen

tst_ss_end	rts



; =========================================================================
;
; Funktion	: Schlüsselschalter Zustand bzw. Anzahl Anrufe im Display zeigen
;	  wird von Uhrausgabe aus aufgerufen
;
; Eingang	: ------
;
; Ausgang	: ------
;
; Register	: Accu, X
;
; (c) by Thomas Lehmann März 1990
;
; =========================================================================

put_ss	lda #21		; Cursorposition laden
	jsr curs_set	; Cursor setzen

	bbr SS_STAT,allg_stat,ss_off	; SS ist ausgeschaltet
		
	; Anzahl der nicht abgefragten Anrufe ausgeben, SS ein
	; ----------------------------------------------------
	lda struct_stat+STAT_NANR	; Anz. nicht abgefr. Anrufe laden
	jsr putdez	; 3-stellig ausgeben
	jmp nanr_led	; LED`s für nicht abgefragte Anrufe schalten


	; SS ist ausgeschaltet
	; --------------------
ss_off	lda displ_prg	; !!! puttxt schaltet DSP-Ausgabe aus !!!
	ldx #<ss_txt	; Text ausgeben
	ldy #>ss_txt
	jsr puttxt
	sta displ_prg	; wieder zurücksetzen
	rts

ss_txt	byte 00
	shift "Aus"






; --------------------------------------------------------------------------

HLP	set	*
_SS	equ	HLP-MODUL_START		; Größe des Moduls