;**************************************************************************
;
; Filename : HOERTON.ASM
; ----------------------
;
; (c) 1991 by Thomas Lehmann
;
;
; Jackophone V5.00
;
;
; Hörtonauswertung
;
;
;**************************************************************************

MODUL_START	set	*	; Größe des Moduls berechnen


; =========================================================================
;
; Type	: Timer IRQ
;	: Hörton testen
;
; Eingang	: alle 10mS
;
; Ausgang	: BIT "HTON_OK" in hgeb_stat gesetzt wenn Hörtonzeit erreicht
;
; Register	: Accu
;
; (c) by Thomas Lehmann Mai 1990
;
; =========================================================================

tst_hton	bbr HTON_UEB,hgeb_stat,tst_hton_e	; keine Überwachung eingesch.

	lda Via_porta	; Zustand des Ports laden
	and #HTON	; ist Hörton vorhanden ?
	bne tst_hton_e	; nein, Ende

	if TEST
	lda #$ff
	sta led_ram+1+YL1
	endif

	dec hton_tim	; Hörtonzeit nachtriggern
	bpl tst_hton_e1	; Hörton ist noch ungültig

	smb HTON_OK,hgeb_stat	; Flag für Hörton erkannt setzen
	rmb HTON_UEB,hgeb_stat	; Überwachung ausschalten
	jmp htport_off	; Hörton Port löschen

tst_hton_e
	if TEST
	stz led_ram+1+YL1
	endif

	lda #HTON_TIM	; Timerwert laden
	sta hton_tim	; Timer aufziehen
tst_hton_e1	rts


; =========================================================================
;
; Type	: Unterprg.
;	: Hörtonauswertung einschalten
;
; Eingang	: --------
;
; Ausgang	: BIT`s für Hörtonerkennung geschaltet
;
; Register	: ------
;
; (c) by Thomas Lehmann Mai 1990
;
; =========================================================================

hton_on	bbr DIP_HTON,dip_stat,hton_on_1	; Hardware ist installiert

	smb HTON_OK,hgeb_stat	; Hörton erkannt eintragen
	ldx #VORWHL_TIM	; Timerwert Vorwahlzeit ohne Hörton laden
	stx vorwahl_tim	; und für Wahlzeit eintragen
	rts

hton_on_1	ldx #04		; Timerwert Vorwahlzeit mit Hörton laden
	stx vorwahl_tim	; und für Wahlzeit eintragen
	smb HTON_UEB,hgeb_stat	; Überwachung einschalten
	rmb HTON_OK,hgeb_stat	; kein Hörton erkannt eintragen
	jmp htport_on	; Hörton Port setzen





; --------------------------------------------------------------------------

HLP	set	*
_HOERTON	equ	HLP-MODUL_START		; Größe des Moduls