;**************************************************************************
;
; Filename : BEA_POST.ASM
; -----------------------
;
; (c) 1990 by Thomas Lehmann
;
;
; Jackophone V5.00
;
;
; Anrufbeantworter und Postapparat
;
;
;**************************************************************************

MODUL_START	set	*	; Größe des Moduls berechnen


; =========================================================================
;
; Type	: Hauptprg.
;
; Eingang	: bei Anrufbeantwortertaste
;	: Offset auf Tastaturtabelle in X-Reg.
;	: Tastenwert im Accu
;
; Ausgang	: Anrufbeantworter ein/ausschalten
;
; Register	: Accu
;
; (c) by Thomas Lehmann März 1990
;
; =========================================================================

key_beantw	bbs ST_BEANTW,feap_stat,kbea_off	; Beantworter abschalten

bea_set_on	smb ST_BEANTW,feap_stat	; Status eintragen
	bbs LTG_BEL,ltg_stat,kbea_ltg	; Ltg. ist belegt

	jmp beantw_on	; Beantworter anschalten

kbea_ltg	lda #KEY_BEA
	ldy #LD_L|LD_N	; LED Status laden
	jmp set_prgled

kbea_off	rmb ST_BEANTW,feap_stat	; Status austragen
	jmp beantw_off	; Beantworter abschalten


; =========================================================================
;
; Type	: Hauptprg.
;
; Eingang	: bei Postapparattaste
;	: Offset auf Tastaturtabelle in X-Reg.
;	: Tastenwert im Accu
;
; Ausgang	:
;
; Register	: Accu, X, Y
;
; (c) by Thomas Lehmann März 1990
;
; =========================================================================

key_post	bbr ST_POST,feap_stat,kpost_off	; Postapparat abschalten

po_set_on	rmb ST_POST,feap_stat		; Status eintragen
	bbs LTG_HLT,ltg_stat,kpost_on	; Ltg. ist in Halten
	bbs LTG_BEL,ltg_stat,kpost_led	; Ltg. ist belegt

kpost_on	jmp post_on	; Postapp. anschalten

kpost_led	lda #KEY_POST
	ldy #LD_L|LD_N	; nur LED schalten
	jmp set_prgled

kpost_off	smb ST_POST,feap_stat	; Status eintragen
	jmp post_off	; Postapp. abschalten


; =========================================================================
;
; Funktion	: Terminzeit für Beantworter ein/aus eingeben
;
; Eingang	: Auswahl bei Speichern/Kontrolle
;
; Ausgang	: Terminzeit ausgegeben
;	: Wähltasten auf Termin-Eingabe umgeleitet wenn speichern aktiv
;	: sonst auf Terminkontrolle
;
; Register	: X
;
; (c) by Thomas Lehmann Mai 1990
;
; =========================================================================


spko_bea	lda #MAX_TERM+TERM_BEA_ON	; Terminnr. laden
	jmp term_beapo	; Termin ausgeben

spko_post	lda #MAX_TERM+TERM_ZW_ON	; Terminnr. laden
	jmp term_beapo	; Termin ausgeben




; =========================================================================
;
; Funktion	: Termin für Beantworter / Zweitapp. ist erreicht
;
; Eingang	: Termin Nr. im ACCU
;
; Ausgang	: --------
;
; Register	:
;
; (c) by Thomas Lehmann März 1993
;
; =========================================================================

beapo_ttab	word bea_set_on
	word kbea_off
	word kpost_off
	word po_set_on


beapo_term	sec
	sbc #MAX_TERM	; Beantw. ein/aus, Zweit ein/aus
	asl		; Offset auf Tabelle
	tax
	jmp (beapo_ttab,x)	; Beantw. / Zweitapp. schalten





; --------------------------------------------------------------------------

HLP	set	*
_BEA_POST	equ	HLP-MODUL_START		; Größe des Moduls