;$VER: QCInstall v1.0
;By Bo Lincoln 1993
;This script uses the installer program to install Quadra Composer to
;your hard drive. 

(complete 0)
(welcome)

;Check kickver
(if (< (/ (getversion) 65536) 37)
	(abort ("You must have kickstart 2.0x to use this installation "
		"utility, and to run QuadraComposer 2.0")  
	)
)

(message
	("\nThis program lets you install Quadra Composer to your hard ")
	("disk drive. If you don't own one, abort installation immediately. ")
)

(set sdir (pathonly @icon))
;Get dir for drawer
(set tdir (askdir (prompt ("Where do you want to install Quadra Composer 2.0?"))
		(help ("Select a drawer where you want to install the ")
		("Quadra Composer 2.0.\n")
		)
		(default @default-dest)
	)
)
(set @default-dest tdir)

(set ans (askbool 
			(
			(prompt "\nDo you want to make a new drawer called QuadraComposer?")
			(help "")
			)
		)
)
(if 
	(= 1 ans)

	(
		(makedir (tackon tdir "QuadraComposer") (infos))
		(set tdir (tackon tdir "QuadraComposer"))
	)

)
(working ("Copying Quadra Composer"))
;Copy main program
(copyfiles
	(source (tackon sdir "QuadraComposer"))
	(dest tdir)
	(help @copyfiles-help)
	(infos)
)
;50%
(complete 70)
(message
	"\nAnd now the fonts, QC 6 & 8, will be copied..."
)
(copyfiles
	(source (tackon sdir "fonts"))
	(all)
	(dest "FONTS:")
	(fonts)
	(help @copyfiles-help)
)
(complete 75)
(message
	"\nSome textfiles are included in this package; manual and replayroutines."
	" They will now be installed..."
)
;Copy manual
(copyfiles
	(prompt "Select files to copy:")
	(source sdir)
	(dest tdir)
	(help @copyfiles-help)
	(choices
		"QCManual2.0.txt"
		"QCReplay.s"
		"QCFastreplay.s"
	)
	(confirm)
	(infos)
)
(complete 90)
(message
	"\nThis is the last part of this installation. 'reqtools.library' will "
	"be copied to your libs: drawer, if you don't " 
	"already have a later version installed."
)
(copylib
	(prompt "Copying reqtools...")
	(help @copylib-help)
	(source (tackon sdir "libs/reqtools.library"))
	(dest "libs:")
	(confirm)
)
(complete 100)
(exit ("Have fun!"))