'
'       *************************************************************
'       *****                                                   *****
'       *****    DiaInstall V2.0 - © in 1992 by Stefan Hirth    *****
'       *****                                                   *****
'       *************************************************************
'
'       Die Sterne in Programm zeigen, an welcher Stelle Besitzer nur
'       eines Laufwerkes Disketten wechseln müssen
'
ALERT 0,"DiaInstall V2.0|GFA-Basic-Programm|von Stefan Hirth|June 27th, MCMXCII",1,"Weiter",i|
ALERT 0,"Sie sollten mit Ihrer|normalen Startdiskette|gebootet haben!",1,"OK|Abbruch",i|
'
akdir$=DIR$(0)
'
IF i|=2
  END
ENDIF
'
copy$="RAM:Copy_dia_tmp"
'
' ******************************************************* WORKBENCH
'
IF EXIST("C:Copy")=FALSE
  ALERT 0,"Sie benötigen den|COPY-Befehl|im C-Verzeichnis|der Bootdisk",1,"Abbruch",i|
  END
ELSE
  EXEC "Copy C:Copy "+copy$,-1,-1
ENDIF
'
CHDIR "SYS:"
i%=DFREE(0)
'
IF i%<40000
  ALERT 0,"Es sollten noch etwa|40 KB|frei sein!",1,"Abbruch|Weiter",i|
  IF i|=1
    END
  ENDIF
ENDIF
'
tmp$="RAM:DiaInstall_tmp"
ss$="S:Startup-Sequence"
'
CHDIR akdir$
'
req$="LIBS:req.library"
IF NOT EXIST(req$)
  ALERT 0,"Installiere|REQ-Library|im LIBS: - Dir",1,"OK|Nein!",i|
  IF i|=1
    ' *************************************************** DIA
    EXEC copy$+" "+akdir$+"req.library "+tmp$,-1,-1
    ' *************************************************** WORKBENCH
    EXEC copy$+" "+tmp$+" "+req$,-1,-1
  ENDIF
ELSE
  ALERT 0,"REQ-Library|ist schon vorhanden.",1," OK ",i|
ENDIF
'
rt$="LIBS:reqtools.library"
IF NOT EXIST(rt$)
  ALERT 0,"Installiere|RT-Library|im LIBS: - Dir",1,"OK|Nein!",i|
  IF i|=1
    ' *************************************************** DIA
    EXEC copy$+" "+akdir$+"reqtools.library "+tmp$,-1,-1
    ' *************************************************** WORKBENCH
    EXEC copy$+" "+tmp$+" "+rt$,-1,-1
  ENDIF
ELSE
  ALERT 0,"REQTOOLS-Library|ist schon vorhanden.",1," OK ",i|
ENDIF
'
rtp$="C:RTPatch"
IF NOT EXIST(rtp$)
  ALERT 0,"Befehl|RTPatch|kopieren ?",1,"OK|Nein!",i|
  IF i|=1
    ' *************************************************** DIA
    EXEC copy$+" "+akdir$+"RTPatch "+tmp$,-1,-1
    ' *************************************************** WORKBENCH
    EXEC copy$+" "+tmp$+" "+rtp$,-1,-1
  ENDIF
ELSE
  ALERT 0,"Befehl RTPatch|ist schon vorhanden.",1," OK ",i|
ENDIF
'
ALERT 0,"Fertig, um die|Startup-Sequence|zu patchen ?",1,"OK|Nein!",i|
IF i|=1
  IF EXIST(ss$)
    OPEN "I",#1,ss$
    OPEN "O",#2,tmp$
    PRINT #2,"RTPatch >NIL:"
    WHILE NOT EOF(#1)
      LINE INPUT #1,z$
      PRINT #2,z$
      IF z$="RTPatch >NIL:"
        schon_installiert!=TRUE
      ENDIF
    WEND
    CLOSE
    IF schon_installiert!=FALSE
      EXEC copy$+" "+tmp$+" "+ss$,-1,-1
    ELSE
      ALERT 0,"Die Startup-Sequence|ist schon erwei-|tert worden!",1," OK ",i|
    ENDIF
  ELSE
    ALERT 0,ss$+"|existiert nicht!",1,"Abbruch",i|
  ENDIF
ENDIF
'
IF EXIST(tmp$)
  KILL tmp$
ENDIF
'
IF EXIST(copy$)
  KILL copy$
ENDIF
'
ALERT 0,"Ciao|und viel Spaß|mit DIA V2.0|wünscht|STEFAN HIRTH",1,"Danke!",i|
END