(*********************************************************************
 *
 *  :Program.		Gibt Requester mit meinem Namen aus
 *  :Author.		Hans Schafft
 *  :Address.		Landfriedstraße 1A - Hinterhaus
 *  :Address.		6900 Heidelberg
 *  :Phone.		06221 - 22416
 *  :Version.		1.0
 *  :Date.		1989
 *  :Copyright.		PD
 *  :Language.		Modula-II
 *  :Translator.	M2Amiga
 *
 *********************************************************************)

IMPLEMENTATION MODULE VonWem;

FROM SYSTEM	IMPORT	ADR, ADDRESS, LONGSET;
FROM Graphics	IMPORT  jam2, jam1;
FROM Intuition	IMPORT 	boolGadget, reqGadget,ActivationFlags,
		      	Gadget, GadgetFlagSet, IDCMPFlagSet, IntuiText,
                      	Requester, RequesterFlagSet, InitRequester,
                      	Border, ActivationFlagSet,WindowPtr, Request;

CONST
 RequBreite = 250; RequHoehe = 100;
 GadBreite  =  95; GadHoehe  =  10;

VAR
 InfoRequest  : Requester;
 InfoGadText  : IntuiText;
 InfoGad      : Gadget;
 InfoGadBorder: Border;
 InfoGadPairs : ARRAY [1..10] OF INTEGER;


(***************************************************************)
PROCEDURE ShowReq(wp: WindowPtr);
BEGIN
  IF Request(ADR(InfoRequest), wp) THEN END
END ShowReq;


(***************************************************************)
PROCEDURE SetUpGadget;
BEGIN
   (* Koordinaten für den Rand der Gadget Box *)
  InfoGadPairs[1] := 0;              InfoGadPairs[2] := 0;
  InfoGadPairs[3] := GadBreite+1;    InfoGadPairs[4] := 0;
  InfoGadPairs[5] := GadBreite+1;    InfoGadPairs[6] := GadHoehe+1;
  InfoGadPairs[7] := 0;              InfoGadPairs[8] := GadHoehe+1;
  InfoGadPairs[9] := 0;              InfoGadPairs[10] := 0;

  WITH InfoGadBorder DO
    leftEdge := -1; 			topEdge    := -1;
    frontPen := 3; 			backPen    := 11;
    drawMode := jam1; 			count 	   := 5;
    xy 	     := ADR(InfoGadPairs); 	nextBorder := NIL;
  END;

  WITH InfoGadText DO
    leftEdge  := 3; 			topEdge  := 1;
    frontPen  := 12; 			backPen  := 4;
    drawMode  := jam2;
    iText     := ADR("Is ja irre!");
    iTextFont := NIL; 			nextText := NIL;
  END;

  WITH InfoGad DO
    leftEdge  	  := ( RequBreite DIV 2) - ( GadBreite DIV 2);
    topEdge  	  :=  RequHoehe - (GadHoehe + 5);
    width  	  :=  GadBreite; height := GadHoehe;
    flags  	  :=  GadgetFlagSet{};
    activation 	  :=  ActivationFlagSet{endGadget, relVerify};
    gadgetType 	  :=  boolGadget + reqGadget;
    gadgetRender  :=  ADR(InfoGadBorder);
    gadgetText 	  :=  ADR(InfoGadText);
    mutualExclude :=  LONGSET{};
    nextGadget 	  :=  NIL; 		selectRender := NIL;
    specialInfo   :=  NIL; 		userData     := NIL;
    gadgetID 	  :=  0;
  END;
 END SetUpGadget;


VAR
 InfoReqBorder: Border;
 InfoReqPairs : ARRAY [1..10] OF INTEGER;
 InfoReqText  : ARRAY [0..5] OF IntuiText;


(***************************************************************)
PROCEDURE SetUpRequester;
 BEGIN
  InfoReqPairs[1] := 0;              InfoReqPairs[2] := 0;
  InfoReqPairs[3] := RequBreite-3;   InfoReqPairs[4] := 0;
  InfoReqPairs[5] := RequBreite-3;   InfoReqPairs[6] := RequHoehe-3;
  InfoReqPairs[7] := 0;              InfoReqPairs[8] := RequHoehe-3;
  InfoReqPairs[9] := 0;              InfoReqPairs[10] := 0;

  WITH InfoReqBorder DO
    leftEdge := 1;  		  topEdge := 1;
    frontPen := 3;  		  backPen := 5;
    drawMode := jam2; 		    count := 5;
    xy := ADR(InfoReqPairs);   nextBorder := NIL;
  END;

  InitRequester(ADR(InfoRequest));

  WITH InfoRequest DO
    leftEdge 	:= 50;
    topEdge	:= 360;
    width 	:= RequBreite;
    height	:= RequHoehe;
    reqGadget 	:= ADR(InfoGad);
    reqText 	:= ADR(InfoReqText);
    reqBorder 	:= ADR(InfoReqBorder);
    backFill 	:= 6;
  END;

 END SetUpRequester;


(***************************************************************)
PROCEDURE SetUpRequesterText;

 PROCEDURE InitIText(VAR itext: IntuiText; L, T: CARDINAL; Next, text: ADDRESS);
  BEGIN
   WITH itext DO
     leftEdge  := L+2; 	topEdge := T;
     frontPen  := 0; 	backPen := 6;
     drawMode  := jam2;
     iText     := text;
     iTextFont := NIL; nextText := Next
   END
  END InitIText;

 BEGIN
  InitIText(InfoReqText[0], 4, 10, ADR(InfoReqText[1]),
        ADR("AMIGA - MASTERMIND - ADAPTION."));
  InitIText(InfoReqText[1], 4, 30, ADR(InfoReqText[2]),
        ADR("Anregungen, Komplimente, Geld,"));
  InitIText(InfoReqText[2], 4, 40, ADR(InfoReqText[3]),
        ADR("Verbesserungsvorschläge !? an:"));
  InitIText(InfoReqText[3], 4, 50, ADR(InfoReqText[4]),
        ADR("Hans Schafft, 6900 Heidelberg"));
  InitIText(InfoReqText[4], 4, 60, ADR(InfoReqText[5]),
        ADR("Landfriedstr. 1A - Hinterhaus"));
  InitIText(InfoReqText[5], 40, 70, NIL,
        ADR("Telefon: 06221 - 22416"));
 END SetUpRequesterText;


BEGIN
 SetUpGadget; SetUpRequesterText; SetUpRequester;
END VonWem.