; The Problem's Australia EP Installer Script.
; Written with help of ASCII-Edit in March/May 1995.

;two vars for scrolling logo through window
SET scrollUP 
SET scrollDN 
SET empty " >                                                                       "

SETFONT topaz.font 8

IF NOT Exists Australia-Install
  ECHO "You  have  either already installed Australia, or something weird happened!*nI can not find this directory:*n`CD`Australia-Install/"
  ECHO NOLINE "*n*n > Press Return "
  SET >NIL: Return ?
  ENDCLI
ENDIF

;Install the cli-commands first
CD Australia-install
ECHO NOLINE "Please wait...*n*nInstalling commands in C: ..."
COPY >NIL: Cli-Stuff/#? C:
COPY >NIL: ASCIIEdit.config S:
SetRGB >NIL: RESET
;
;The following part magically converts the "Install.DATA" file to a
;protracker module, loads it into SmartPlay and then deletes it...
IF EXISTS Install.DATA
  ECHO NOLINE "...done!*nLoading & Converting Install.DATA file ..."
  ECHO NOLINE >RAM:Header piano
  JOIN RAM:Header Install.DATA TO RAM:Mod.Piano
  DELETE >NIL: RAM:Header
  SP RAM:Mod.Piano NW NM NE NC
  DELETE >NIL: RAM:Mod.Piano
  ECHO "...done!"
ENDIF

ECHO "*ec"
TYPE TP-Logo.ASCII
WAIT 1

TYPE TP-AUSTRALIA.ASCII
WAIT 1

ECHO Press Return(C)1995 by The Problem
SET >NIL: Return ?

ECHO "*ec"
TYPE TP-AUSTRALIA.ASCII
WAIT 1

;scroll up half a screen and display info
ECHO 
ECHO "Welcome to The Problem's Australia EP installer.*n"
ECHO " This  script will fully install the Australia EP where you want it.  Please*n note  that  you  need  about 5 Mb of free space on your harddisk during the*n installation.  After installation, Australia will take up about ??Mb.*n"
ECHO " It IS VITAL that you use this installer.  If you copy stuff by hand, we can*n ensure  you  that  some things in the EP won't work.  (Some files have been*n deliberately corrupted; they will be restored by the installer.)*n"
ECHO " Coming  up  is  a  Path  Requester in which you should choose a destination*n directory.   If you are unsure wether you have enough diskspace, cancel the*n requester to quit the installation procedure."
ECHO NOLINE " Press Return "
SET >NIL: Return ?
ECHO "              "

;where to install, the Path requester...
LAB Repeat
SET Path ""
SET Path `RequestFile DRAWER "Ram:" DRAWERSONLY TITLE "Select Path for AUSTRALIA!" POSITIVE "Install Here" NEGATIVE "Quit!"`

IF NOT $Path
  ECHO "  Are you sure you DON'T want to install Australia? (Y/N)"
  SET YPos 
  SET YES "Yeah! I hate installing EP's! (What?!) "
  SET NO "No! O my God! What have I done!?! (you pressed Quit!...) "
  SET label Quit
  SKIP SUB_YesNo
ELSE
  SKIP DontQuit
ENDIF

LAB Quit
IF $answer EQ Y
  SP STOP
  ENDCLI
ELSE
  SKIP BACK Repeat
ENDIF

LAB DontQuit
ECHO $scrollDN

LAB questions
ECHO " Okay, now please answer the following questions...*n"

ECHO " Do you want 8-colour Magic WB icons (in stead of 4-colour)? (Y/N)"
ECHO "$empty"
ECHO "*n Do you want the new WB backdrop to be activated? (in prefs file!) (Y/N)"
ECHO "$empty"
ECHO "*n Do you run an 'interlaced' workbench? (Y/N)"
ECHO "$empty"
ECHO "*n Are you sure about all this? (Y/N)"
ECHO "$empty"
ECHO ""

;the following makes use of the 'sub-routine', (see further down)
LAB Repeat2
  SET Ypos 
  SET YES "Yes please, give me the beautyfull ones!"
  SET NO "No, I want 4 colour icons..."
  SET label Repeat3
  SKIP SUB_YesNo

LAB Repeat3
  SET Q1 $answer
  SET Ypos 
  SET YES "Yes, I guess I do."
  SET NO "No, just leave me alone will you!"
  SET label Repeat4
  SKIP SUB_YesNo

LAB Repeat4
  SET Q2 $answer
  SET Ypos 
  SET YES "Yes, I've got loads of memory and/or own a multiscan monitor!"
  SET NO "No, I'm just an honest bloke! (Or I own a 1 GIG HD instead!)"
  SET label Repeat5
  SKIP SUB_YesNo

LAB Repeat5
  SET Q3 $answer
  SET Ypos 
  SET YES "Yes, I'm not stupid you know!"
  SET NO "No, I made a little mistake."
  SET label Continue
  SKIP SUB_YesNo

LAB Continue
  SET Q4 $answer
  ECHO NOLINE "*n*n*n Hit The Return Key! (Again) "
  SET >NIL: Return ?

  IF $Q4 EQ N
    ECHO "          Try again!         "
    SKIP BACK questions 
  ENDIF

  ECHO $scrollUP$scrollUP


;And now for the backdrops...
ECHO "*ec"
ECHO "You  will  now have the opportunity to select which background picture will*nbe  installed.   Wether or not you have chosen to activate it, we will copy*nit  to  your  SYS:Prefs/Patterns  directory."

SET label BACKSELEC1
IF $Q1 EQ Y
  SKIP Pics8col
ELSE
  SKIP Pics4col
ENDIF

LAB BACKSELEC1
ECHO "*n*n*n  1    2  "
IF $Q3 EQ Y
  ECHO "        These are nonlaced versions. A laced version will be installed!    "
ENDIF

LAB BACKSELEC2
ECHO NOLINE "Enter your choice:                  "
SET >NIL: back ?

CD Backdrops/
SET patterns "SYS:Prefs/Patterns/AustBugles"
IF NOT EXISTS SYS:Prefs/Patterns/"
  MakeDir >NIL: SYS:Prefs/Patterns
ENDIF
IF NOT VAL "$back" EQ 1
  IF NOT VAL "$back" EQ 2
    SKIP BACK BACKSELEC2
  ELSE
    IF $Q1 EQ Y
      IF $Q3 EQ Y
        COPY >NIL: Bugles2.HL $patterns
      ELSE
        COPY >NIL: Bugles2 $patterns
      ENDIF
    ELSE
      IF $Q3 EQ Y
        COPY >NIL: Bugles4.HL $patterns
      ELSE
        COPY >NIL: Bugles4 $patterns
      ENDIF
    ENDIF
  ENDIF
ELSE
  IF $Q1 EQ Y
    IF $Q3 EQ Y
      COPY >NIL: Bugles.HL $patterns
    ELSE
      COPY >NIL: Bugles $patterns
    ENDIF
  ELSE
    IF $Q3 EQ Y
      COPY >NIL: Bugles3.HL $patterns
    ELSE
      COPY >NIL: Bugles3 $patterns
    ENDIF
  ENDIF
ENDIF

;Copy window backdrop
COPY >NIL: AustraliaWindows sys:prefs/patterns/

CD /
DELETE >NIL: Backdrops ALL
ECHO "*ec"
TYPE TP-AUSTRALIA.ASCII
ECHO "The selected pattern has been installed."
IF $Q2 EQ Y
  IF $Q1 EQ Y
    COPY >NIL: WbPattern8.prefs SYS:Prefs/Env-Archive/Sys/WbPattern.prefs
    ECHO "An 8 colour Window Backdrop has been copied to your SYS:Prefs/Patterns*ndirectory. This backdrop has also been actived in WBPattern.prefs!"
  ELSE
    COPY >NIL: WbPattern4.prefs SYS:Prefs/Env-Archive/Sys/WbPattern.prefs 
    ECHO "An 8 colour Window Backdrop has been copied to your SYS:Prefs/Patterns*ndirectory. This backdrop can be actived using WBPattern!"
  ENDIF
  ECHO "And it has been activated (WbPattern.prefs file has been altered)."
ELSE
  ECHO "Use WbPattern to put it on your worbench!"
ENDIF

DELETE >NIL: WbPattern#?.prefs
WBPattern FROM SYS:Prefs/Env-Archive/Sys/WbPattern.prefs USE

ECHO NOLINE "Press Return... "
SET >NIL: Return ?
ECHO 

;Superb usage of 'list' in order to rename the iconz.
ECHO NOLINE "Now installing your icons..."
IF $Q1 EQ Y
  LIST #? >RAM:Iconz LFORMAT "DELETE >NIL: *"%P%S*"" ALL SUB .info2
ELSE
  LIST >RAM:Iconz LFORMAT "DELETE >NIL: *"%P%M.info*"*nRENAME >NIL: *"%P%S*" *"%P%M.info*"" ALL SUB .info2
ENDIF
EXECUTE >NIL: RAM:Iconz
DELETE >NIL: RAM:Iconz
ECHO "...FINISHED!!!"

;WOW! a scroll! You saw that?!
ECHO "$scrollDN$scrollDN*ec"

;move outside the Australia-install dir...
CD /
SET Path "$Path"Australia
ECHO "And now... All HELL will break loose! Just a second...*n"
COPY Australia-install $Path ALL

ECHO NOLINE "*nCleaning up..."
DELETE >NIL: Australia-install ALL

;create a script in ram to delete this installer...
ECHO >RAM:KillInstaller "WAIT 3*nCD *"`CD`*"*nDELETE Australia-install ALL*nDELETE Australia.#?"
CD $Path

ECHO "*ec"
TYPE TP-Logo.ASCII
ECHO "    That's IT! The Australia EP is yours for EVER! Explore The Outback!"
ECHO NOLINE "Press Return"
SET >NIL: Return ?

ECHO "$scrollDN$scrollDN"
TYPE TP-Australia.ASCII
ECHO 
ECHO "- This installer was created by the following Problem members-"
ECHO "*nGraphics*nSolution*nAlcoRhythm"
ECHO "*nCoding/Scripting*nAlcoRhythm*nSolution"
ECHO "*nDesign*nWanda"
ECHO "*nQuality Assurance*nCSilla*nInfinity"
ECHO "*nMusic*nAlcoRhythm"
ECHO NOLINE " Press Return "
SET >NIL: Return ?

ECHO "$scrollDN$scrollDN"
TYPE TP-Australia.ASCII
ECHO 
ECHO " The Australia EP project is brought to you by The Problem Collective 1995*n- It may only be spread in the original unchanged archive -*n"
ECHO "Music:Graphics:*nAlcoRhythmMushRoom (Logos)*nSolutionAlcoRhythm/Solution (Icons)*n"
ECHO "Coding:*nAlcoRhythm (ASCII-Editor, SetRGB)*n*nThe Problem wishes to thank:*nPeter Hjelt (Excellent SmartPlay)*nJohn Hendrix (FastView)"
ECHO "HellRaiser (The Twilight Zone)*nLeo Elsinga (TP Internet)*nAcid Software (Blitz Basic 2)*nAnd The People Of Australia (Outback)*n"
ECHO "We're The Problem, Gotta Love Us!"
ECHO NOLINE " Press Return "
SET >NIL: Return ?

ECHO "$scrollDN$scrollDN"
ECHO "We're The Problem, Gotta Love Us!"

;delete the ASCII-logos
DELETE >NIL: TP-#?.ASCII

;move the Australia icon
CD /
RENAME >NIL: Australia/Australia.info Australia.info

;delete this installer...
RUN >NIL: C:EXECUTE RAM:KillInstaller

;but first stop smartplay and endcli...
SP STOP
ENDCLI



;the SUB_YesNo routine needs the following variables:
;$Ypos     - the line number string (H, x is the line number)
;$YES      - the text to replace a positive answer (y/Y) with
;$NO       - the text to replace a negative answer (n/N) with

LAB SUB_YesNo
  ECHO NOLINE "$Ypos$empty$Ypos"

  SET answer ""
  SET >NIL: answer ?

  IF "$answer" EQ "y"
    SET answer "Y"
  ENDIF
  IF "$answer" EQ "n"
    SET answer "N"
  ENDIF
  IF "$answer" EQ "Y"
    ECHO "$Ypos$YES"
  ELSE 
    IF "$answer" EQ "N"
      ECHO "$Ypos$NO"
    ELSE
      SKIP BACK SUB_YesNo
    ENDIF
  ENDIF
SKIP BACK $label

LAB Pics8col
CD Backdrops/
pictocli >NIL: bugles 20 68
pictocli >NIL: bugles 155 68
pictocli >NIL: bugles 20 153
pictocli >NIL: bugles 155 153
pictocli >NIL: bugles2 330 68
pictocli >NIL: bugles2 465 68
pictocli >NIL: bugles2 330 153
pictocli >NIL: bugles2 465 153
CD /
SKIP BACK $label

LAB Pics4col
CD Backdrops/
pictocli >NIL: bugles3 20 68
pictocli >NIL: bugles3 155 68
pictocli >NIL: bugles3 20 153
pictocli >NIL: bugles3 155 153
pictocli >NIL: bugles4 330 68
pictocli >NIL: bugles4 465 68
pictocli >NIL: bugles4 330 153
pictocli >NIL: bugles4 465 153
CD /
SKIP BACK $label