;Wide Scroll
;-----------
;This opens an extra wide picture of 640x256 pixels and scrolls it left
;and right.  Extremely large pictures are *totally* inadequate for games
;such as platformers and shoot'em-ups, because the picture size takes
;up  huge  amounts  of  memory.   However  for games like Skidmarks,
;Lemmings, Monkey Island, etc, such large screens can be a necessity.

	opt	o+

	INCLUDE	"exec/exec_lib.i"
	INCLUDE	"games/games_lib.i"
	INCLUDE	"games/games.i"

CALL	MACRO
	jsr	_LVO\1(a6)
	ENDM

	SECTION	"WideScroll",CODE

;===========================================================================;
;                             INITIALISE DEMO
;===========================================================================;

Start:	MOVEM.L	A0-A6/D1-D7,-(SP)
	move.l	($4).w,a6
	lea	GMS_Name(pc),a1
	moveq	#$00,d0
	CALL	OpenLibrary
	move.l	d0,GMS_Base
	beq.s	Quit

	move.l	GMS_Base(pc),a6          ;Tell GMS that we want to add a
	CALL	SetUserPri

	lea	ScreenStruct(pc),a0      ;screen for use.
	CALL	Add_Screen
	tst.l	d0
	bne.s	Error

	lea	PicFile(pc),a0           ;a0 = Picture file.
	lea	Picture(pc),a1           ;a1 = Picture struct.
	move.l	ScreenStruct+SS_MemPtr1(pc),PIC_Data(a1)
	CALL	LoadPic
	tst.w	d0
	bne.s	ReturnToDOS

	lea	ScreenStruct(pc),a0      ;Now show the screen/pic.
	CALL	Show_Screen

;===========================================================================;
;                                MAIN LOOP
;===========================================================================;

	moveq	#0,d2

Loop:	CALL	Wait_OSVBL
	tst.w	d2
	bgt.s	.Right

.Left	tst.w	SS_PicXOffset(a0)
	ble.s	.Right
	moveq	#-2,d2
	bra.s	.scroll

.Right	cmp.w	#320,SS_PicXOffset(a0)
	bge.s	.Left
	moveq	#2,d2

.scroll	add.w	d2,SS_PicXOffset(a0)
	CALL	Move_Picture

.done	moveq	#JPORT1,d0               ;Port 1 (Mouse)
	moveq	#JT_ZBXY,d1
	CALL	Read_JoyPort
	btst	#MB_LMB,d0
	beq.s	Loop

;===========================================================================;
;                              RETURN TO DOS
;===========================================================================;

ReturnToDOS:
	move.l	GMS_Base(pc),a6
	lea	ScreenStruct(pc),a0
	CALL	Delete_Screen            ;Give back screen memory etc.
Error:	move.l	GMS_Base(pc),a1
	move.l	($4).w,a6
	CALL	CloseLibrary
Quit:	MOVEM.L	(SP)+,A0-A6/D1-D7
	moveq	#$00,d0
	rts

;===========================================================================;
;                                  DATA
;===========================================================================;

Direction:
	dc.w	0

GMS_Name:
	dc.b	"games.library",0
	even
GMS_Base:
	dc.l	0

AMT_PLANES =	4

ScreenStruct:
	dc.l	"GSV1",0
	dc.l	0,0,0             ;Screen_Mem1/2/3
	dc.l	0                 ;Screen link.
	dc.l	Palette           ;Address of palette
	dc.l	0                 ;Address of rasterlist.
	dc.l	16                ;Amt of colours in palette.
	dc.w	320,256,640,256   ;Screen & Pic Height/Width. 
	dc.w	AMT_PLANES        ;Amt_Planes
	dc.w	0,0               ;Top Of Screen, X/Y
	dc.w	0,0               ;X/Y offsets.
	dc.l	HSCROLL           ;Special attributes.
	dc.w	LORES             ;Screen mode.
	dc.b	INTERLEAVED       ;Screen type
	dc.b	0                 ;Reserved.
	even

Palette	dc.w	$0000,$0400,$0501,$0501,$0601,$0701,$0701,$0801
	dc.w	$0901,$0A01,$0B02,$0432,$0CC0,$0F00,$0211,$0880

Picture	dc.l	"PCV1",0           ;Version header.
	dc.l	0                  ;Source data.
	dc.w	640,256            ;Width, Height.
	dc.w	AMT_PLANES         ;Amount of Planes.
	dc.l	16                 ;Amount of colours.
	dc.l	Palette            ;Source palette (remap).
	dc.w	LORES              ;Screen mode.
	dc.w	INTERLEAVED        ;Destination
	dc.l	0                  ;Parameters.

PicFile	dc.b	"GAMESLIB:data/IFF.Pic640x256",0
	even