;Alteration of screen dimensions
;-------------------------------
;Just a test routine for height and width alteration.  Move the joystick
;around to move the entire screen, while moving the mouse to alter the
;height and width.
;
;Press LMB to exit.

	opt	o+

	INCLUDE	"exec/exec_lib.i"
	INCLUDE	"games/games_lib.i"
	INCLUDE	"games/games.i

CALL	MACRO
	jsr	_LVO\1(a6)
	ENDM

	SECTION	"Redimension",CODE

;===========================================================================;
;                             INITIALISE DEMO
;===========================================================================;

Start:	MOVEM.L	A0-A6/D1-D7,-(SP)
	move.l	($4).w,a6
	lea	GMS_Name(pc),a1
	moveq	#$00,d0
	CALL	OpenLibrary
	move.l	d0,GMS_Base
	beq	Quit

	move.l	GMS_Base(pc),a6
	CALL	SetUserPri

	lea	ScreenStruct(pc),a0
	CALL	Add_Screen
	tst.l	d0
	bne	Error

	lea	Picture(pc),a1	;a1 = Picture struct.
	move.l	SS_MemPtr1(a0),PIC_Data(a1)
	lea	PicFile(pc),a0	;a0 = Picture file.
	CALL	LoadPic	;>> = Load the picture.
	tst.w	d0
	bne	ReturnToDOS

	lea	ScreenStruct(pc),a0      ;Now show the screen/pic.
	CALL	Show_Screen

;===========================================================================;
;                                MAIN LOOP
;===========================================================================;

Loop:	moveq	#JPORT1,d0               ;Read from port 1
	moveq	#JT_ZBXY,d1
	CALL	Read_JoyPort             ;Go get port status.
	btst	#MB_LMB,d0
	bne	Fade_Here
	move.w	d0,d1
	ext.w	d0
	asr.w	#8,d1
	add.w	d1,SS_ScrWidth(a0)
	add.w	d0,SS_ScrHeight(a0)

	moveq	#JPORT2,d0               ;Read from port 2
	moveq	#JT_ZBXY,d1
	CALL	Read_JoyPort             ;Go get port status.
	btst	#JB_FIRE1,d0
	bne.s	Fade_Here
	move.w	d0,d1
	ext.w	d0
	asr.w	#8,d1
	add.w	d1,SS_ScrXOffset(a0)
	add.w	d0,SS_ScrYOffset(a0)

.chksrx	cmp.w	#35,SS_ScrXOffset(a0)
	ble.s	.chkslx
	move.w	#35,SS_ScrXOffset(a0)

.chkslx	cmp.w	#-40,SS_ScrXOffset(a0)
	bge.s	.chksty
	move.w	#-40,SS_ScrXOffset(a0)

.chksty	cmp.w	#-20,SS_ScrYOffset(a0)
	bge.s	.chkty
	move.w	#-20,SS_ScrYOffset(a0)

.chkty	tst.w	SS_ScrHeight(a0)
	bge.s	.chkby
	clr.w	SS_ScrHeight(a0)

.chkby	cmp.w	#256,SS_ScrHeight(a0)
	ble.s	.chklx
	move.w	#256,SS_ScrHeight(a0)

.chklx	cmp.w	#1,SS_ScrWidth(a0)
	bge.s	.chkrx
	move.w	#1,SS_ScrWidth(a0)

.chkrx	cmp.w	#320,SS_ScrWidth(a0)
	ble.s	.done
	move.w	#320,SS_ScrWidth(a0)

.done	CALL	Wait_OSVBL               ;Always wait for a VBL first.
	CALL	Remake_Screen            ;Reposition the screen now.
	bra	Loop

Fade_Here:
	moveq	#$00,d0
.Fade	CALL	Wait_OSVBL               ;Keep looping until the fade is
	CALL	B12_FadeToBlack          ;completely finished (ie all
	tst.w	d0                       ;colours are black).
	bne.s	.Fade

;===========================================================================;
;                              RETURN TO DOS
;===========================================================================;

ReturnToDOS:
	move.l	GMS_Base(pc),a6
	lea	ScreenStruct(pc),a0
	CALL	Delete_Screen            ;Give back screen memory etc.
Error:	move.l	GMS_Base(pc),a1
	move.l	($4).w,a6
	CALL	CloseLibrary
Quit:	MOVEM.L	(SP)+,A0-A6/D1-D7
	moveq	#$00,d0
	rts

;===========================================================================;
;                           CODE-RELATIVE DATA
;===========================================================================;

GMS_Name:
	dc.b	"games.library",0
	even
GMS_Base:
	dc.l	0

AMT_PLANES =	5

ScreenStruct:
	dc.l	"GSV1",0
	dc.l	0,0,0            ;Screen_Mem1/2/3
	dc.l	0                ;Screen link.
	dc.l	Palette          ;Address of screen palette
	dc.l	0                ;Address of rasterlist.
	dc.l	0                ;Amt of colours in palette.
	dc.w	320,256,320,256  ;Screen & Pic Height/Width
	dc.w	AMT_PLANES       ;Amt_Planes
	dc.w	0,0              ;X/Y screen offset
	dc.w	0,0              ;X/Y picture offset
	dc.l	0                ;Special attributes
	dc.w	LORES            ;Screen mode
	dc.b	INTERLEAVED      ;Screen type
	dc.b	0                ;Reserved
	even

Palette	dc.w	$0000,$0130,$0FCB,$0FA9,$0D88,$0965,$0644,$0211
	dc.w	$0400,$0444,$0FF0,$0432,$0CC0,$0150,$0501,$0880
	dc.w	$0261,$0271,$0382,$0492,$05A3,$05B4,$0677,$06C4
	dc.w	$0788,$09AA,$0BCC,$0801,$0901,$0A02,$0701,$0601

Picture	dc.l	"PCV1",0	;Version header.
	dc.l	0	;Source data.
	dc.w	320,256	;Width, Height.
	dc.w	AMT_PLANES	;Amount of Planes.
	dc.l	32	;Amount of colours.
	dc.l	Palette	;Source palette (remap).
	dc.w	LORES	;Screen mode.
	dc.w	INTERLEAVED	;Destination
	dc.l	0	;Parameters.

PicFile	dc.b	"GAMESLIB:data/IFF.Pic320",0
	even