;Wide Scroll & Mirror
;--------------------
;Tests the Mirror command under a wide scrolling screen, also uses the
;NewPalette command to create a water type effect.

	opt	o+

	INCLUDE	"exec/exec_lib.i"
	INCLUDE	"games/games_lib.i"
	INCLUDE	"games/games.i"

CALL	MACRO
	jsr	_LVO\1(a6)
	ENDM

	SECTION	"WideScroll",CODE

;===========================================================================;
;                             INITIALISE DEMO
;===========================================================================;

Start:	MOVEM.L	A0-A6/D1-D7,-(SP)
	move.l	($4).w,a6
	lea	GMS_Name(pc),a1
	moveq	#$00,d0
	CALL	OpenLibrary
	move.l	d0,GMS_Base
	beq	Quit

	move.l	GMS_Base(pc),a6
	CALL	SetUserPri

	lea	ScreenStruct(pc),a0
	CALL	Add_Screen
	tst.l	d0
	bne.s	Error

	lea	Picture(pc),a1	;a1 = Picture struct.
	move.l	SS_MemPtr1(a0),PIC_Data(a1)
	lea	PicFile(pc),a0	;a0 = Picture file.
	CALL	LoadPic	;>> = Load the picture.
	tst.w	d0
	bne.s	ReturnToDOS

	lea	ScreenStruct(pc),a0      ;Now show the screen/pic.
	CALL	Show_Screen

;===========================================================================;
;                                MAIN LOOP
;===========================================================================;

	moveq	#1,d2

Loop:	CALL	Wait_OSVBL
	tst.w	d2
	bgt.s	.Right

.Left	tst.w	SS_PicXOffset(a0)
	ble.s	.Right
	moveq	#-1,d2
	bra.s	.scroll
.Right	cmp.w	#320,SS_PicXOffset(a0)
	bge.s	.Left
	moveq	#1,d2

.scroll	add.w	d2,SS_PicXOffset(a0)
	CALL	Move_Picture
	moveq	#JPORT1,d0               ;Port 1 (Mouse)
	moveq	#JT_ZBXY,d1
	CALL	Read_JoyPort
	btst	#MB_LMB,d0
	beq.s	Loop

;===========================================================================;
;                              RETURN TO DOS
;===========================================================================;

ReturnToDOS:
	move.l	GMS_Base(pc),a6
	lea	ScreenStruct(pc),a0
	CALL	Delete_Screen	;Give back screen memory etc.
Error:	move.l	GMS_Base(pc),a1
	move.l	($4).w,a6
	CALL	CloseLibrary
Quit:	MOVEM.L	(SP)+,A0-A6/D1-D7
	moveq	#$00,d0
	rts

;===========================================================================;
;                                  DATA
;===========================================================================;

GMS_Name:
	dc.b	"games.library",0
	even
GMS_Base:
	dc.l	0

AMT_PLANES =	4

ScreenStruct:
	dc.l	"GSV1",0
	dc.l	0,0,0             ;Screen_Mem1/2/3
	dc.l	0                 ;Screen link.
	dc.l	Palette           ;Address of palette.
	dc.l	RasterList        ;Address of rasterlist.
	dc.l	16                ;Amt of colours in palette.
	dc.w	320,256,640,256   ;Screen & Pic Height/Width. 
	dc.w	AMT_PLANES        ;Amt_Planes
	dc.w	0,0               ;X/Y screen offset.
	dc.w	0,0               ;X/Y picture offset.
	dc.l	HSCROLL|HBUFFER   ;Special attributes.
	dc.w	LORES             ;Screen mode.
	dc.b	INTERLEAVED       ;Screen type
	dc.b	0                 ;Reserved.
	even

Palette	dc.w	$0000,$0300,$0400,$0500,$0600,$0700,$0800,$0900
	dc.w	$0A00,$0B00,$0C00,$0432,$0CC0,$0F00,$0211,$0880

RasterList:
	WAITLINE 129
	MIRROR
	NEWPALETTE 0,16,WaterPalette
	RASTEND

WaterPalette
	dc.w	$0000,$0200,$0200,$0300,$0300,$0300,$0400,$0400
	dc.w	$0500,$0600,$0700,$0221,$0770,$0800,$0100,$0440

Picture	dc.l	"PCV1",0	;Version header.
	dc.l	0	;Source data.
	dc.w	640,256	;Width, Height.
	dc.w	AMT_PLANES	;Amount of Planes.
	dc.l	16	;Amount of colours.
	dc.l	Palette	;Source palette (remap).
	dc.w	LORES	;Screen mode.
	dc.w	INTERLEAVED	;Destination
	dc.l	0	;Parameters.

PicFile	dc.b	"GAMESLIB:data/IFF.Pic640x256",0
	even