opt	o+,ow6-,w+,c+,l+,p=68030,autopc

		xdef	_AECryptCmp
		xdef	_AECryptStr
		xdef	_AECryptCpy
		xdef	_AEClearMem
		xdef	_crctab32

*******************************************************************************
* AECryptCmp:
* ŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻ
* $Inputs:	a0.L = GSTR3
*		a1.L = User.Pass (ptr to 1L containing ENCRYPTED CYPHIERKEY
* $Outputs:	d0
*******************************************************************************

		cnop	0,4
_AECryptCmp:	bsr.s	_AECryptStr
		cmp.l	(a1),d0			;are both cyphiers identical ?
		bne.s	cyphier_fail		;if not... passkey is WRONG!
		moveq	#0,d0			;return = SUCCESS
		rts
		cnop	0,4
cyphier_fail:	moveq	#-1,d0			;return = FAIL
		rts

*******************************************************************************
* AECryptCpy:
* ŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻ
* $Inputs:	a1.L = GSTR3 (source)
*		a0.L = User.Pass (destination)
* $Outputs:	None.
*******************************************************************************

		cnop	0,4
_AECryptCpy:	exg.l	a0,a1
		bsr.s	_AECryptStr
		move.l	d0,(a1)
		rts
		cnop	0,4

******************************************************************************
* AECryptStr:
* ŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻ
* $Inputs:	a0.L = GSTR3 (ASCIIZ String Ptr)
* $Outputs:	d0.L = CYPHIER KEY or 0 if failed
******************************************************************************

_AECryptStr:	movem.l	d1-d4/a1,-(sp)		;push used registers to stack
		moveq	#0,d0
		move.l	a0,a1
		tst.b	(a1)			;is user input string null?
		beq.s	NullStr			;if so .. exit.. input error
		moveq	#-1,d4			;0-1
GetStrLen:	addq.l	#1,d4			;inc count
		tst.b	(a1)+			;count string length
		bne.s	GetStrLen		;d4=String Length
		lea	_crctab32(pc),a1
		moveq	#8,d2
		moveq	#-1,d3
DoCRC:		moveq	#0,d1
		move.b	(a0)+,d1
		eor.b	d0,d1
		and.w	d3,d1
		move.l	(a1,d1.L*4),d1
		lsr.l	d2,d0
		eor.l	d1,d0
		subq.l	#1,d4			;decr length
		bne.s	DoCRC			;d0.L = 32-bit CRC
		swap	d0			;swap low and hi words
		not.w	d0			;not low word
		roxl.l	d0,d0			;rotate x amount of bits
		neg.l	d0			;not the whole expression
NullStr:	movem.l	(sp)+,d1-d4/a1		;pull used registers from stack
						;d0.L = Encrypted PassCyphier
		rts

*****************************************************************************
* AEClearMem:
* ŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻ
* $Inputs:	a0.L = GSTR3 (MemPtr)
*		d0.L = Length
* $Outputs:	None.
******************************************************************************

		cnop	0,4
_AEClearMem:	movem.l	d0-d7/a0-a6,-(sp)
		tst.l	d0
		beq.s	nochars
		subq.l	#1,d0
clsloop		sf.b	(a0)+			;decr length
		dbra	d0,clsloop		;d0.L = 32-bit CRC
nochars:	movem.l	(sp)+,d0-d7/a0-a6
		rts

;/* [CRC Polynomial $EDB88320] */

_crctab32:	dc.l	$00000000,$77073096,$EE0E612C,$990951BA,$076DC419,$706AF48F,$E963A535,$9E6495A3
		dc.l	$0EDB8832,$79DCB8A4,$E0D5E91E,$97D2D988,$09B64C2B,$7EB17CBD,$E7B82D07,$90BF1D91
		dc.l	$1DB71064,$6AB020F2,$F3B97148,$84BE41DE,$1ADAD47D,$6DDDE4EB,$F4D4B551,$83D385C7
		dc.l	$136C9856,$646BA8C0,$FD62F97A,$8A65C9EC,$14015C4F,$63066CD9,$FA0F3D63,$8D080DF5
		dc.l	$3B6E20C8,$4C69105E,$D56041E4,$A2677172,$3C03E4D1,$4B04D447,$D20D85FD,$A50AB56B
		dc.l	$35B5A8FA,$42B2986C,$DBBBC9D6,$ACBCF940,$32D86CE3,$45DF5C75,$DCD60DCF,$ABD13D59
		dc.l	$26D930AC,$51DE003A,$C8D75180,$BFD06116,$21B4F4B5,$56B3C423,$CFBA9599,$B8BDA50F
		dc.l	$2802B89E,$5F058808,$C60CD9B2,$B10BE924,$2F6F7C87,$58684C11,$C1611DAB,$B6662D3D
		dc.l	$76DC4190,$01DB7106,$98D220BC,$EFD5102A,$71B18589,$06B6B51F,$9FBFE4A5,$E8B8D433
		dc.l	$7807C9A2,$0F00F934,$9609A88E,$E10E9818,$7F6A0DBB,$086D3D2D,$91646C97,$E6635C01
		dc.l	$6B6B51F4,$1C6C6162,$856530D8,$F262004E,$6C0695ED,$1B01A57B,$8208F4C1,$F50FC457
		dc.l	$65B0D9C6,$12B7E950,$8BBEB8EA,$FCB9887C,$62DD1DDF,$15DA2D49,$8CD37CF3,$FBD44C65
		dc.l	$4DB26158,$3AB551CE,$A3BC0074,$D4BB30E2,$4ADFA541,$3DD895D7,$A4D1C46D,$D3D6F4FB
		dc.l	$4369E96A,$346ED9FC,$AD678846,$DA60B8D0,$44042D73,$33031DE5,$AA0A4C5F,$DD0D7CC9
		dc.l	$5005713C,$270241AA,$BE0B1010,$C90C2086,$5768B525,$206F85B3,$B966D409,$CE61E49F
		dc.l	$5EDEF90E,$29D9C998,$B0D09822,$C7D7A8B4,$59B33D17,$2EB40D81,$B7BD5C3B,$C0BA6CAD
		dc.l	$EDB88320,$9ABFB3B6,$03B6E20C,$74B1D29A,$EAD54739,$9DD277AF,$04DB2615,$73DC1683
		dc.l	$E3630B12,$94643B84,$0D6D6A3E,$7A6A5AA8,$E40ECF0B,$9309FF9D,$0A00AE27,$7D079EB1
		dc.l	$F00F9344,$8708A3D2,$1E01F268,$6906C2FE,$F762575D,$806567CB,$196C3671,$6E6B06E7
		dc.l	$FED41B76,$89D32BE0,$10DA7A5A,$67DD4ACC,$F9B9DF6F,$8EBEEFF9,$17B7BE43,$60B08ED5
		dc.l	$D6D6A3E8,$A1D1937E,$38D8C2C4,$4FDFF252,$D1BB67F1,$A6BC5767,$3FB506DD,$48B2364B
		dc.l	$D80D2BDA,$AF0A1B4C,$36034AF6,$41047A60,$DF60EFC3,$A867DF55,$316E8EEF,$4669BE79
		dc.l	$CB61B38C,$BC66831A,$256FD2A0,$5268E236,$CC0C7795,$BB0B4703,$220216B9,$5505262F
		dc.l	$C5BA3BBE,$B2BD0B28,$2BB45A92,$5CB36A04,$C2D7FFA7,$B5D0CF31,$2CD99E8B,$5BDEAE1D
		dc.l	$9B64C2B0,$EC63F226,$756AA39C,$026D930A,$9C0906A9,$EB0E363F,$72076785,$05005713
		dc.l	$95BF4A82,$E2B87A14,$7BB12BAE,$0CB61B38,$92D28E9B,$E5D5BE0D,$7CDCEFB7,$0BDBDF21
		dc.l	$86D3D2D4,$F1D4E242,$68DDB3F8,$1FDA836E,$81BE16CD,$F6B9265B,$6FB077E1,$18B74777
		dc.l	$88085AE6,$FF0F6A70,$66063BCA,$11010B5C,$8F659EFF,$F862AE69,$616BFFD3,$166CCF45
		dc.l	$A00AE278,$D70DD2EE,$4E048354,$3903B3C2,$A7672661,$D06016F7,$4969474D,$3E6E77DB
		dc.l	$AED16A4A,$D9D65ADC,$40DF0B66,$37D83BF0,$A9BCAE53,$DEBB9EC5,$47B2CF7F,$30B5FFE9
		dc.l	$BDBDF21C,$CABAC28A,$53B39330,$24B4A3A6,$BAD03605,$CDD70693,$54DE5729,$23D967BF
		dc.l	$B3667A2E,$C4614AB8,$5D681B02,$2A6F2B94,$B40BBE37,$C30C8EA1,$5A05DF1B,$2D02EF8D