; ******************************************
; *                                        *
; *   ViperTools-Installationsskript      *
; *                                        *
; *  $VER: 1.0 (14.08.99) by J.Reinert     *
; *                                        *
; ******************************************



; *************************************************************************
; Definition der globalen Konstanten
; *************************************************************************

(set #liesmichtext  "Lies_mich.TXT")       ; Schlusswort
(set #progssource   "ViperTools/")         ; Programm

; *************************************************************************
; Version der Workbench bestimmen
; *************************************************************************

(set #os_version (/ (getversion "libs:version.library") 65536))

; *************************************************************************
; Definition der deutschen Texte
; *************************************************************************

(set #msg2
  (cat "\nMit \"ViperTools\" haben es auch Amiga-Anwender "
       "einfach, die ISDN-DataBox \"Speed Viper\" von Hagenuk "
       "mit neuer Firmware zu \"bestücken\""
  )
)

(set #bad-kick "\"ViperTools\" benötigt Amiga-OS 3.0 oder höher!")

(set #askdirmsg
  (cat "Bitte wählen Sie ein Ziel für "@app-name". Eine Schublade "
       "mit Namen \"ViperTools\" wird erzeugt"
  )
)

(set #askdirhelp
  (cat "Wählen Sie möglichst ein Ziel aus, welches nicht permanent "
       "schreibgeschützt ist!"
  )
)

(set #libshelp
  (cat "Die 'wizard.library' wird zum erzeugen und verwalten der "
       "grafischen Benutzerschnittstelle benötigt! \n\ndie 'xprxmodem.library' "
       "wird nur benötigt, wenn Sie neue Firmware-Dateien in die DataBox "
       "laden möchten\n\n"
  )
)

(set #prgprompt "Kopieren des Programmes und Zubehör")

(set #iconprompt "Kopieren der Piktogramme")

(set #prghelp
  (cat "*Die Dateien \"ViperTools\", \"ViperTools.info\", \"ViperTools.wizard\" "
       "und \"SelectSerial\" müssen Sie unbedingt auswählen.\n\n"
       "*Ob Sie die \"Docs\" (Anleitungen) umkopieren, überlasse ich Ihnen :)"
  )
)

; *************************************************************************
; Beginn der Installation
; *************************************************************************

(complete 0)
(if (< #os_version 39)
  (
    (abort #bad-kick)
  )
)
(message #msg2)
(welcome)
(complete 1)

; *************************************************************************
; Zielverzeichnis auswählen lassen
; *************************************************************************

(set name
  (askdir
    (prompt  #askdirmsg)
    (help    #askdirhelp)
    (default @default-dest)
  )
)
(set #destname (tackon name "ViperTools"))
(complete 5)

; *************************************************************************
; Icon-Typ auswählen
; *************************************************************************

(set #icontyp
  (askchoice (prompt "Wählen Sie einen Icon-Typ aus")
             (help "")
             (choices "Standard" "MagicWB")
  )
)
(if (= #icontyp 0)
  (
    (set #iconsource #progssource)
  )
  (
    (set #iconsource "MWBIcons")
  )
)
(complete 10)

; *************************************************************************
; Datenschubladen erzeugen
; *************************************************************************

(makedir #destname (infos))
(complete 20)

; *************************************************************************
; Kopieren der Librarys
; *************************************************************************

(copylib (prompt "Kopieren der 'wizard.library'")
         (help #libshelp) 
         (source "libs/wizard.library")
         (dest "Libs:") 
         (confirm "EXPERT")
)
(complete 30)

(copylib (prompt "Kopieren der 'xprxmodem.library'")
         (help #libshelp) 
         (source "libs/xprxmodem.library")
         (dest "Libs:") 
         (confirm "EXPERT")
)

(complete 40)

; *************************************************************************
; Kopieren des Programms
; *************************************************************************

(copyfiles (prompt #prgprompt) 
           (help #prghelp) 
           (source #progssource) 
           (dest #destname) 
           (pattern "~(#?.info)")
           (confirm "EXPERT")
)
(complete 80)

; *************************************************************************
; Kopieren der Icons
; *************************************************************************

(working "Icons kopieren...")
(run (cat "IconCopy " (tackon #iconsource "ViperTools") " " (tackon #destname "ViperTools") " UPDATE"))
(run (cat "IconCopy " (tackon #iconsource "Docs") " " (tackon #destname "Docs") " UPDATE"))

(complete 100)

; *************************************************************************
; Aktuelles Verzeichnis setzen
; *************************************************************************

(if (exists (tackon #destname "ViperTools"))
  (
    (set @default-dest #destname)
  )
  (
    (set @default-dest "")
  )
)


; *************************************************************************
; Falls vorhanden, einen LiesMich-Text anzeigen
; *************************************************************************

(if (exists #liesmichtext)
  (run (cat "sys:utilities/Multiview " #liesmichtext))
)

; *************************************************************************
; Ende der Installation
; *************************************************************************