;
; $VER: Installer Script 1.0 for NewsCoaster v1.0 (c) Mark Harman (5.7.99)
;

(set #wrongOS  "NewsCoaster needs at least OS3.0 to run\n")
(set #wrongMUI "NewsCoaster needs at least MUI3.8 to run\n")
(set #wrongCPU "NewsCoaster needs at least a 68020 CPU to run\n")
(set #icons_prompt "Which icons do you wish to install?\n")
(set #NewsCoaster_dir (cat "Choose a folder to install NewsCoaster in - an\n"
                           "extra drawer will be created. (If you wish to\n"
                           "update NewsCoaster, please select the folder\n"
                           "which contains the NewsCoaster folder.)\n"))

(set #done (cat "\nNewsCoaster has been succesfully installed.\n\n"))

(set OS_ver (getversion "exec.library" (resident)))
(if (< OS_ver (* 39 65536)) (abort #wrongOS))

(set MUI_ver (getversion "MUI:libs/muimaster.library"))
(if (AND (< MUI_ver (* 19 65536)) (<> MUI_ver 0)) (abort #wrongMUI))

(set cpu_type (database "cpu"))
(if (< cpu_type "68020") (abort #wrongCPU))

(complete 0)

(set Icon_set
        (askchoice
                (prompt #icons_prompt)
                (help @askoptions-help)
                (choices "Amiga 4 Colour" "NewIcons")
                (default 1)
        )
)

(complete 10)

(set NewsCoaster_def_dir @default-dest)

(set NewsCoaster_dir
        (askdir
                (default NewsCoaster_def_dir)
                (prompt  #NewsCoaster_dir)
                (help    @askdir-help)
        )
)

(set NewsCoaster_dir (tackon NewsCoaster_dir "NewsCoaster"))

(complete 20)

(if (not (exists NewsCoaster_dir))
        (makedir NewsCoaster_dir (infos))
)

(copyfiles (source "NewsCoaster") (dest NewsCoaster_dir) (infos) (help @copyfiles-help))
(copyfiles (source "NewsCoaster.guide") (dest NewsCoaster_dir) (infos) (help @copyfiles-help))
(copyfiles (source "NewsCoaster.readme") (dest NewsCoaster_dir) (infos) (help @copyfiles-help))
(copyfiles (source "default.index") (dest NewsCoaster_dir) (infos) (help @copyfiles-help))
(copyfiles (source "gotoURL.rx") (dest NewsCoaster_dir) (infos) (help @copyfiles-help))

(if (= Icon_set 0)
        (copyfiles (source "Icons/NewsCoaster.info") (dest NewsCoaster_dir) (help @copyfiles-help))
)

(if (= Icon_set 1)
        (copyfiles (source "/NewsCoaster.info") (dest (tackon NewsCoaster_dir "/")) (help @copyfiles-help))
)

(complete 100)

(message #done "\"" NewsCoaster_dir "\"")

(exit (QUIET))