;
; $VER: Amiga Crossword Deluxe installation 2.0 (31.12.99)
;
; Copyright (c) 1999 Kees Coenradi
;

;****************************************************************************
;
; English texts
;
(if (not (= @language "nederlands"))
  (
    (set #bad-kick "You must have AmigaOS 3.0 (V39) or newer to be able to use ACD.")
    (set #bad-cpu "You must have at least an MC68020 to use CyberAVI.")
    (set #selectdir "Please select where to install ACD\nA directory 'ACD' will be created automatically")
    (set #makediracd "Creating directory 'ACD'")
    (set #copymainprg "Copying Amiga Crossword Deluxe...")
    (set #copydocs "Copying documentation...")
    (set #copypuzzle "Copying Crosswordpuzzles...")
    (set #copyfonts "Copying Fonts...")
    
  )
)

;****************************************************************************
;
; Nederlandse tekst
;
(if (= @language "nederlands")
  (
    (set #bad-kick "U heeft minimaal AmigaOS 3.0 (V39) of hoger nodig om ACD te gebruiken.")
    (set #selectdir "Waar moet ACD geinstalleerd worden?\nEen lade voor 'ACD' wordt automatisch gemaakt.")
    (set #makediracd "Ik maak lade 'ACD'")
    (set #copymainprg "Kopieer Amiga Crossword Deluxe...")
    (set #copydocs "Kopieer Handleiding...")
    (set #copypuzzle "Kopieer Kruiswoordpuzzels...")
    (set #copyfonts "Kopieer Fonts...")
    
  )
)

;****************************************************************************
;
; Setup
;

(complete 0)

(if (< (/ (getversion) 65536) 39)
  (abort #bad-kick)
)



;****************************************************************************
;
; Welcome
;

(welcome)

(complete 10)

;****************************************************************************
;
; Setup directory
;

(set #destdir
  (askdir
    (prompt #selectdir)
    (help @askdir-help)
    (default @default-dest)
    (newpath)
  )
)


(set @default-dest (tackon #destdir "ACD"))


(complete 20)

(makedir @default-dest
  (prompt #makediracd)
  (help @makedir-help)
  (infos)
)

(complete 40)

;****************************************************************************
;
; Copy main program
;

(copyfiles
  (prompt #copymainprg)
  (help @copyfiles-help)
  (source "Crossword_Deluxe")
  (dest @default-dest)
  (infos)
  (confirm)
)

(complete 50)

;****************************************************************************
;
; Copy puzzels
;

(set puzzle_dir (tackon @default-dest "Puzzles"))
(if (not (exists puzzle_dir))
(makedir puzzle_dir)
)

(copyfiles
  (prompt #copypuzzle)
  (help @copyfiles-help)
  (source "Puzzles/")
  (dest puzzle_dir)
  (all)
  (confirm)
 )

(complete 60)

;****************************************************************************
;
; Copy fonts
;

(set Fonts_dir (tackon @default-dest "Fonts"))
(if (not (exists Fonts_dir))
(makedir Fonts_dir)
)

(copyfiles
  (prompt #copyfonts)
  (help @copyfiles-help)
  (source "Fonts/")
  (dest Fonts_dir)
  (all)
  (confirm)
 )

(complete 80)

;****************************************************************************
;
; Copy documentation
;

(copyfiles
  (prompt #copydocs)
  (help @copyfiles-help)
  (source "")
  (pattern "#?.(guide|readme)")
  (dest @default-dest)
  (infos)
  (confirm)
)

(complete 90)


;****************************************************************************
;
; Exit
;

(complete 100)
(exit)