;
; $VER: Installer script 1.1 (7.12.1998)
;
;  Copyright 1998 Justin Cruttenden and Chris Page
;
;  for StartPanel, Copyright 1998 Chris Page (chris@worldfoundry.demon.co.uk)
;

(set #def_SP_ver_030    0)
(set #def_SP_ver_040    1)
(set #def_SP_ver_060    2)

;----------------------------------------------------------------------------

; ***** English
(set #wrongMUI "StartPanel needs at least MUI3.8 to run\n")
(set #wrongCPU "StartPanel needs at least a 68030 CPU to run\n")

(set #SP_dir  (cat "Choose directory to install StartPanel\n"
                    "(NO drawer will be created!)"))
(set #SPP_dir  (cat "Choose directory to install the StartPanel Prefs\n"
                    "(NO drawer will be created!)"))

(set #SP_ver (cat "Which processor do you have?"))

(set #arexx_prompt "Where do you want to install the ARexx scripts?")

(set #docs_prompt (cat "Where do you want to install the Startpanel documentation?\n"
                       "(NO directory will be created!)"))

(set #done_1   (cat "\nStartPanel has been succesfuly installed.\n\n"
                    "Click the \"StartPanel\" icon in the\n"))
(set #done_2        "\ndirectory.")


;----------------------------------------------------------------------------

;**** Checking environment
(set MUI_ver (getversion "MUI:libs/muimaster.library"))
(if (AND (< MUI_ver (* 19 65536)) (<> MUI_ver 0)) (abort #wrongMUI))

(set cpu_type (database "cpu"))
(if (< cpu_type "68030") (abort #wrongCPU))

;----------------------------------------------------------------------------

(complete 0)

(set SP_dir
        (askdir
                (default "SYS:WBStartup")
                (prompt  #SP_dir)
                (help    @askdir-help)
        )
)


(complete 10)

(set SPP_dir
        (askdir
                (default "SYS:Prefs")
                (prompt  #SPP_dir)
                (help    @askdir-help)
        )
)


(complete 15)

(set SP_ver
        (askchoice
                (prompt  #SP_ver)
                (help @askoptions-help)
                (choices "68030" "68040" "68060")
                (default #def_SP_ver_030)
        )
)


(complete 20)

(set ARexx_dir
       (askdir
                (default "REXX:")
                (prompt  #arexx_prompt)
                (help    @askdir-help)
       )
)
(complete 25)

(set Doc_dir
       (askdir
                (default "HELP:")
                (prompt  #docs_prompt)
                (help    @askdir-help)
       )
)


;--- Install files...

(complete 30)

(makedir SP_dir (infos))

(if (= SP_ver #def_SP_ver_030 ) (copyfiles (source "StartPanel.030") (dest SP_dir) (newname "StartPanel") (help @copyfiles-help)))
(if (= SP_ver #def_SP_ver_040 ) (copyfiles (source "StartPanel.040") (dest SP_dir) (newname "StartPanel") (help @copyfiles-help)))
(if (= SP_ver #def_SP_ver_060 ) (copyfiles (source "StartPanel.060") (dest SP_dir) (newname "StartPanel") (help @copyfiles-help)))

(copyfiles (source "StartPanel.info") (dest SP_dir) (help @copyfiles-help))

(complete 40)

(copyfiles (source "StartPanelPrefs") (dest SPP_dir) (infos) (help @copyfiles-help))

(complete 50)

(copyfiles (source "Docs/") (dest Doc_dir) (all))

(complete 60)

(copyfiles (source "ARexx/") (dest ARexx_dir) (all))

(complete 70)
(copylib (prompt "MUI - TWFmultiLED.mcc") (source "libs/MUI/TWFmultiLED.mcc") (dest "MUI:Libs/MUI/") (confirm) (help @copylib-help))

(complete 80)
(copylib (prompt "MUI - TWFmultiLED.mcp") (source "libs/MUI/TWFmultiLED.mcp") (dest "MUI:Libs/MUI/") (confirm) (help @copylib-help))

(complete 90)
(copylib (prompt "WBStart.library") (source "libs/WBstart.library") (dest "LIBS:") (confirm) (help @copylib-help))

(complete 100)
(message #done_1 "\"" SP_dir "\"" #done_2)



(exit (QUIET))