;
; $VER: IOBlix1200 installation 1.4 (9.11.98)
;
; Copyright (c) 1998 Thore Böckelmann and RBM Computertechnik
;

;****************************************************************************
;
; English texts
;
(if (not (= @language "deutsch"))
    (
        (set #bad-kick      "You must have AmigaOS 2.0 (V37) or newer to be able to use the IOBlix1200 I/O board.")
        (set #bad-cpu       "You must have at least an MC68020 to use the IOBlix1200 software.")
        (set #noparmodule   (cat "You have no IOBlix1200 parallel module installed! "
                                 "Please install the module first, before you install the software!"))
        (set #selectdevs    "\nWhere to install the device drivers?\n")
        (set #selectl       "\nWhere to install the IOBlix-Handler?\n")
        (set #selecttool    "\nWhere to install the additional tools?\n")
        (set #copypardev    "\nCopying ioblix12par.device...\n")
        (set #copyzipdev    "\nCopying ioblix12zip.device...\n")
        (set #copyhandler   "\nCopying IOBlix-Handler...\n")
        (set #copydosdriver "\nCopying DOSDrivers...\n")
        (set #copytools     "\nCopying Tools...\n")
        (set #createtest    "\nCreating \"Test_Board\" script...\n")
        (set #ssmodify      "\nAdding some command to S:User-Startup...\n")
        (set #toolsource    "C/english")
        (set #nsdinfo       (cat "\n"
                                 "\n"
                                 "If don't want to use IOBlix' own drivers SERxx: and PARxx: "
                                 "but the original drivers instead, then you also have to install the NSDPatch software!\n"
                                 "\n"
                                 "NSDPatch can be found in the drawer \"Goodies\""))
        (set #zipquery      (cat "Do want to install drivers for a "
                                 "parallel port ZIP drive?"))
        (set #zipstart      "Do you want the ZIP driver to be started on bootup?")
        (set #zipinfo       (cat "The driver PZIP0: is meant for FFS formatted ZIP disks with 512 bytes blocksize,\n"
                                 "and the driver PZIPC: is meant for PC formatted ZIP disks. This requires CrossDOS to be installed."))
    )
)

;****************************************************************************
;
; Deutsche Texte
;
(if (= @language "deutsch")
    (
        (set #bad-kick      "Sie müssen AmigaOS 2.0 (V37) oder höher installieren, um die IOBlix1200-Karte zu benutzen.")
        (set #bad-cpu       "Sie brauchen mindestens einen MC68020, um die IOBlix1200-Software zu benutzen.")
        (set #noparmodule   (cat "Sie haben kein IOBlix1200 Parallel-Modul in Ihrem Rechner installiert! "
                                 "Bitte bauen Sie erst das Modul ein, bevor Sie die Software installieren!"))
        (set #selectdevs    "\nWohin sollen die Gerätetreiber kopiert werden?\n")
        (set #selectl       "\nWohin soll der IOBlix-Handler kopiert werden?\n")
        (set #selecttool    "\nWohin sollen die Zusatzprogramme kopiert werden?\n")
        (set #copypardev    "\nKopiere ioblix12par.device...\n")
        (set #copyzipdev    "\nKopiere ioblix12zip.device...\n")
        (set #copyhandler   "\nKopiere IOBlix-Handler...\n")
        (set #copydosdriver "\nKopiere DOSDrivers...\n")
        (set #copytools     "\nKopiere Zusatzprogramme...\n")
        (set #createtest    "\nErstelle \"Test_Board\" Skript...\n")
        (set #ssmodify      "\nFüge Befehle in S:User-Startup ein...\n")
        (set #toolsource    "C/deutsch")
        (set #nsdinfo       (cat "\n"
                                 "\n"
                                 "Wenn Sie statt der IOBlix-eigenen Treibern SERxx: und PARxx: "
                                 "lieber weiterhin die originalen Treiber benutzen wollen, dann müssen Sie noch die NSDPatch-Software installieren!\n"
                                 "\n"
                                 "NSDPatch finden Sie in der Schublade \"Goodies\""))
        (set #zipquery      (cat "\n"
                                 "Wollen Sie Treiber für ein Parallel-Port ZIP Laufwerk installieren?"))
        (set #zipstart      "Soll der ZIP Treiber gleich beim Booten gestartet werden?")
        (set #zipinfo       (cat "Der Treiber PZIP0: ist für FFS-formatierte ZIP-Medien mit einer Blockgröße von 512 Bytes gedacht,\n"
                                 "und der Treiber PZIPC: for PC-formatierte ZIP-Medien. Dafür muß CrossDOS installiert sein."))
    )
)

;****************************************************************************
;
; Setup
;

(complete 0)

(if (< (/ (getversion) 65536) 37)
    (abort #bad-kick)
)

(if (patmatch "68000|68010" (database "cpu"))
    (abort #bad-cpu)
)

;****************************************************************************
;
; Welcome
;

(welcome)

(complete 10)

;****************************************************************************
;
; Check for IOBlix module
;

(run "IOBlix-Install:C/english/SetupIOBlix reinit" (safe))
(if
    (= 0
        (run "IOBlix-Install:C/Look4IOBlix a1200 par" (safe))
    )
    (abort #noparmodule)
)

(complete 20)

;****************************************************************************
;
; Setup directory
;

(set #destdevs
    (askdir
        (prompt #selectdevs)
        (help @askdir-help)
        (default "DEVS:")
    )
)

(set #destl
    (askdir
        (prompt #selectl)
        (help @askdir-help)
        (default "L:")
    )
)

(set #desttool
    (askdir
        (prompt #selecttool)
        (help @askdir-help)
        (default "SYS:IOBlix")
        (newpath)
    )
)

(set @default-dest #desttool)

(complete 20)

(makedir #desttool
    (prompt "")
    (help @makedir-help)
    (infos)
)

(complete 30)

(set #installzip
    (askbool
        (prompt #zipquery)
        (help @askbool-help)
        (default 1)
    )
)

;****************************************************************************
;
; Install devices
;

(copylib
    (help @copylib-help)
    (prompt #copypardev)
    (source "devs/ioblix12par.device")
    (dest #destdevs)
    (confirm)
)

(copylib
    (help @copylib-help)
    (prompt #copyhandler)
    (source "l/IOBlix-Handler")
    (dest #destl)
    (confirm)
)

(copyfiles
    (help @copyfiles-help)
    (prompt #copydosdriver)
    (source "DEVS/DOSDrivers")
    (choices "PAR00" "PAR01")
    (dest "SYS:Storage/DOSDrivers")
    (infos)
    (confirm)
)

(complete 40)

;****************************************************************************
;
; Install tools
;

(copyfiles
  (help @copyfiles-help)
  (prompt #copytools)
  (source #toolsource)
  (choices "SetupIOBlix" "QueryIOBlix")
  (dest #desttool)
  (confirm)
)

(startup "IOBlix I/O Board"
  (help @startup-help)
  (prompt #ssmodify)
  (command (cat (tackon #desttool "SetupIOBlix") " a1200 par >NIL:"))
)

(complete 60)

(copyfiles
  (help @copyfiles-help)
  (prompt #createtest)
  (dest #desttool)
  (source "Test_Board")
  (infos)
)

(textfile
  (dest (tackon #desttool "Test_Board"))
  (prompt #createtest)
  (help "")
  (append (tackon #desttool "QueryIOBlix >t:queryioblix{$$}\n"))
  (append "more t:queryioblix{$$}\n")
  (append "delete t:queryioblix{$$} >nil:\n")
)

;****************************************************************************
;
; Install parallel ZIP driver
;

(if (= #installzip 1)
    (
        (copylib
            (help @copylib-help)
            (prompt #copyzipdev)
            (source "devs/ioblix12zip.device")
            (dest #destdevs)
            (confirm)
        )

        (copyfiles
            (help @copyfiles-help)
            (prompt #copydosdriver)
            (source "DEVS/DOSDrivers")
            (choices "PZIP0" "PZIPC")
            (dest "SYS:Storage/DOSDrivers")
            (infos)
            (confirm)
        )

        (startup "IOBlix1200 ZIP driver"
            (help @startup-help)
            (prompt #zipstart)
            (command "mount PZIP0: >nil:")
        )

        (message #zipinfo)
    )
)

(complete 80)

(message #nsdinfo)

;****************************************************************************
;
; Exit
;

(complete 100)
(exit)