;
; Install script for PowerData (Workbench 2.1 or higher)
;
; Some code and strings derived from Nico François' installation script
; for ReqTools 2.1a. (It is very hard to create installer-scripts without
; any kind of documentation..! This is my first!)
;
; French strings by Reza Elghazi. Thanks, Reza!

(set @default-dest "")
(set old_level @user-level)

(set reqtoolslib "//libs/reqtools.library")
(set pplib       "//libs/powerpacker.library")
(set powerdata   "//PowerData")
(set powerdatarx "//PowerDataARexx")

(set catalogdir "/Locale/Catalogs/")

;=============================================================================
; English strings

(set default_lang 1)

(set #targetstr ("In which directory should PowerData be installed?"))
(set #targetsel
	(cat "\nPlease select the directory or partition on which you would like "
	     "PowerData installed. You may enter the name of a directory which "
	     "does not yet exist. It will be created as the installation "
	     "proceeds.\n\nClick PROCEED to start the installation process.\n\n"
	)
)

(set #bad-kick
	("You must be using Kickstart 2.04+ to install PowerData using this script!")
)

(set #copying-reqtools  "Copying reqtools.library to LIBS:")
(set #copying-pplib     "Copying powerpacker.library to LIBS:")
(set #copying-powerdata "Copying PowerData...")

(set #which-language ("\nWhich languages should be installed?"))
(set #what-versions ("\nWhich version(s) would you like to install?"))
(set #what-versions-help
	(cat "\nARexx is a special command language that is used "
	     "to operate programs automatically.\n\nIn this distribution "
	     "you will find two seperate versions of PowerData. One "
	     "with an ARexx interface, and one without. If you don't use "
	     "ARexx, then you should select to install only the non-ARexx "
	     "version, as it is a bit shorter than its ARexx counterpart. "
	     "This way you can save a couple of KB of memory when PowerData "
	     "is running (and on your drive, too).\n\nYou may install both "
	     "versions if you like.\n\n"
	     @askoptions-help
))

(set #pd-without-arexx ("PowerData without ARexx"))
(set #pd-with-arexx ("PowerData with ARexx"))

(set #which-language-help
(cat "\nThe Amiga can be operated in many different "
	  "languages. If you want PowerData to "
	  "use the same language as the Amiga Workbench "
	  "then a catalog file must be copied to your "
	  "system disk for each language supported.\n\n"
	  "To reduce the amount of space consumed by the "
	  "language files, you can select to have only the "
	  "files of specific languages copied.\n\n"
	  "Simply check the boxes of the languages you wish "
	  "to have available on your system.\n\n"
	  @askoptions-help
))

;=============================================================================
; German strings - These are still VERY incomplete (to say the least :-)

(if (= @language "deutsch")
(
	(set default_lang 4)
))

;=============================================================================
; French strings [Reza Elghazi]

(if (= @language "français")
(

(set default_lang 8)

(set #targetstr ("Dans quel tiroir PowerData doit-il être installé ?"))
(set #targetsel
	(cat "\n Veuillez selectionner le répértoire ou la partition"
	     " dans lequel vous aimeriez que PowerData soit installé"
	     " Vous pouvez enter le nom d'un répértoire qui n'existe"
	     " pas encore."
	     " Ce dernier sera crée durant l'installation."
	     "\n\nClickez sur \"Continuer\" pour commencer la procédure"
	     " d'installation.\n\n"
	)
)

(set #bad-kick
	("Vous devez utiliser le Kickstart 2.04+ afin d'installer PowerData avec ce script!")
)

(set #copying-reqtools  "Copie de la reqtools.library dans LIBS:")
(set #copying-pplib     "Copie de la powerpacker.library to LIBS:")
(set #copying-powerdata "Copie de PowerData...")

(set #which-language ("\nQuelles sont les langages à installer?"))

(set #which-language-help
	(cat "\nL'Amiga peut fonctionner dans différentes langages. "
	     "Plusieurs fichiers doivent être copiés sur le disque dur "
	     "pour chaque langue utiliséee\n\n"
	     "Pour réduire la quantité d'espace utilisé par ces fichiers, "
	     "vous devez sélectionner seulement les langages qui vous seront "
	     "utiles.\n\n"
	     "Cochez les langues que vous souhaitez "
	     "sur votre système\n\n"
	     @askoptions-help
	)
)

))

;=============================================================================
; Italian strings [Mirco Zanca]

(if (= @language "italiano")
(

(set default_lang 16)

(set #targetstr ("In quale cassetto vuoi installare PowerData?"))
(set #targetsel
	(cat "\nSeleziona il cassetto o la partizione in cui vuoi "
	     "installare PowerData. Puoi inserire il nome di un cassetto "
	     "non esistente, verrà creato automaticamente durante "
	     "l'installazione.\n\nSeleziona PROCEDI per iniziare l'installazione.\n\n"
	)
)

(set #bad-kick
	("Devi avere un Kickstart 2.04+ per installare PowerData in questo modo!")
)

(set #copying-reqtools  "Sto copiando la reqtools.library in LIBS:")
(set #copying-pplib     "Sto copiando la powerpacker.library in LIBS:")
(set #copying-powerdata "Sto copiando PowerData...")

(set #which-language ("Quali lingue devono essere installate?"))

(set #which-language-help
	(cat "\nAmiga può utilizzare molte lingue diverse. "
	     "Se vuoi che PowerData utilizzi la stessa lingua "
	     "del Workbench del tuo Amiga allora bisogna "
	     "copiare un apposito file  sul tuo disco di "
	     "sistema per ogni lingua che vuoi usare.\n\n"
	     "Per ridurre al minimo lo spazio occupato dai "
	     "file delle lingue, puoi scegliere quali vuoi "
	     "che siano installate e quali no.\n\n"
	     "Basta che selezioni solo le lingue che vuoi "
	     "rendere disponibili sul tuo sistema.\n\n"
	     @askoptions-help
	)
)

))

;=============================================================================
; Danish strings

(if (= @language "dansk")
(

(set default_lang 2)

(set #targetstr ("I hvilket katalog skal PowerData installeres?"))
(set #targetsel
	(cat "\nVælg det katalog eller den partition som PowerData ønskes "
	     "installeret på. De kan indtaste navnet på et katalog som "
	     "endnu ikke eksisterer. Det vil blive oprettet når installationen "
	     "fortsætter\n\nTryk på PROCEED for at starte installeringen.\n\n"
	)
)

(set #bad-kick
	(cat "De har brug for Kickstart 2.04+ for at kunne installere "
	     "PowerData med dette installationsprogram"
	)
)

(set #copying-reqtools  "Kopierer reqtools.library til LIBS:")
(set #copying-pplib     "Kopierer powerpacker.library til LIBS:")
(set #copying-powerdata "Kopierer PowerData...")

(set #which-language	("\nHvilke(t) sprog ønsker De at installere?"))
(set #what-versions ("\nHvilke(n) version(er) ønsker De at installere?"))
(set #what-versions-help
	(cat "\nARexx er et specielt kommandosprog som bruges til at "
	      "styre programmer automatisk.\n\nI denne distribution vil "
	      "De finde to seperate versioner af PowerData. Den ene med et "
	      "ARexx interface, den anden uden. Hvis De ikke benytter ARexx, "
	      "så bør De vælge kun at installere ikke-ARexx versionen, eftersom "
	      "denne er en smule kortere end sit ARexx modstykke. På denne måde "
	      "kan De spare et par KB hukommelse når PowerData kører (og på "
	      "Deres disk, også).\n\nDe kan installere begge versioner hvis De "
	      "ønsker.\n\n"
	      @askoptions-help
))

(set #pd-without-arexx ("PowerData uden ARexx"))
(set #pd-with-arexx ("PowerData med ARexx"))

(set #which-language-help
(cat "\nAmigaen kan benyttes i mange forskellige sprog.\n"
     "Hvis De ønsker at PowerData skal benytte samme sprog "
     "som Amiga Workbench, så skal der kopieres en katalogfil "
     "til Deres systemdisk for hvert sprog.\n\n"
     "For at reducere sprogfilernes pladsforbrug kan De vælge "
     "kun at installere det eller de sprog installeret som "
     "De har brug for.\n\n"
     "Klik i kasserne ud for de sprog De ønsker at have tilgængelige "
     "på Deres system.\n\n"
     @askoptions-help
))

))

;=============================================================================
; Make sure we are running under a 2.04 ROM
;
(if (< (/ (getversion) 65536) 37)
(
    (abort #bad-kick)
))

;=============================================================================

; Ask user where he wants the PowerData executable
;
(set @target-dir
	(askdir
		(prompt #targetstr)
		(help #targetsel @askdir-help)
		(default "SYS:Tools/Commodities")
	)
)

; Ask user which versions of PowerData to install
;
(user 2)
(set whatvers (askoptions
	(prompt #what-versions)
	(help #what-versions-help)
	(choices
		#pd-without-arexx
		#pd-with-arexx
	)
	(default 2)
))
(user old_level)

; Copy reqtools.library to LIBS:
;
(copylib
	(prompt "\n" #copying-reqtools)
	(help @copylib-help)
	(source reqtoolslib)
	(dest "LIBS:")
	(confirm)
)

; Copy powerpacker.library to LIBS:
;
(copylib
	(prompt "\n" #copying-pplib)
	(help @copylib-help)
	(source pplib)
	(dest "LIBS:")
	(confirm)
)

; Copy the PowerData executable(s) (and its/their icon(s))  :-)
;
(set n 0)
(while
	(set copyver
		(select n
			powerdata
			powerdatarx
			""
		)
	)
(
	(if (IN whatvers n)
	(
		(copyfiles
			(prompt @copying-powerdata)
			(help @copypowerdata-help)
			(source copyver)
			(dest @target-dir)
			(infos)
		)
	))

	(set n (+ n 1))
))

; Copy catalog files (only relevant on v38+ machines)
;
(if (exists "LOCALE:")
(
	(user 2)
	(set lang (askoptions
			(prompt #which-language)
			(help #which-language-help)
			(choices
				"English"
				"Dansk"
				"Deutsch"
				"Français"
				"Italiano"
			)
			(default default_lang)
		  )
	)
	(user old_level)

	(set n 0)
	(while
		(set language
			(select n
				"English"
				"Dansk"
				"Deutsch"
				"Français"
				"Italiano"
				""
			)
		)
	(
		(if (IN lang n)
		(
			(if (<> 0 n)
			(
				(makedir (cat "LOCALE:Catalogs/" language))
				(copyfiles
					(source (cat catalogdir language))
					(dest (cat "LOCALE:Catalogs/" language))
					(all)
				)
			))
		))

		(set n (+ n 1))
	))
))