/*****************************************************************************

         Amiga E - Example door converted from Shadow-W Rexx Door
                   Which was coded by Shadow Man/S8. The layout  
                   isn't 100% correct tho, but I didn't take the 
                   time to correct this, because this is only    
                   ment as an example!

         Author  - SiNTAX/WøT in 1993

         NOTE    - You *MUST* have a directory called DOORS:Names
                   otherwise this door won't function correctly

*****************************************************************************/

MODULE 'AEDoor','dos/dos'

CONST MAX_PWLEN=20,MAX_FLAGLEN=1

DEF res,slen,d,handle,strf:LONG,slot[5]:STRING,filename[256]:STRING,
	pw[MAX_PWLEN]:STRING,flag[MAX_FLAGLEN]:STRING,command[80]:STRING,
	c,temp[80]:STRING


PROC main()
	IF aedoorbase:=OpenLibrary('AEDoor.library',1)

		d:=CreateComm(arg[])
		strf:=GetString(d)

		GetDT(d,DT_SLOTNUMBER,0)
		StrCopy(slot,strf,ALL)

		StrCopy(filename,'DOORS:Names/',ALL)
		StrAdd(filename,slot,ALL)
		slen:=FileLength(filename)
		handle:= Open(filename,MODE_OLDFILE)
		IF (handle=NIL) OR (slen=0)
			IF slen=0
				Close(handle)
			ENDIF
			newuser()
		ELSE
			Read(handle,pw,MAX_PWLEN)
			IF Read(handle,flag,MAX_FLAGLEN)=0
				StrCopy(flag,'N',ALL)
			ENDIF
			GetDT(d,BB_MAINLINE,0)
			StrCopy(temp,strf,ALL)
			RightStr(command,temp,2)
			Close(handle)
			IF StrCmp(flag,'N',1)
				insertflag()
			ENDIF

			c:= flag[]
			SELECT c
			 CASE "x"
				IF StrCmp(command,'-x',2)
					alreadyoff()
				ELSE
				     IF StrCmp(command,'-X',2)
					turnpwon()
				     ELSE
					UpperStr(command)
					IF StrCmp(command,'-C',2)
						changepw()
					ELSE
					     IF StrCmp(command,' ?',2)
						listoptions()
					     ELSE
						SetDT(d,RETURNCOMMAND,'W')
					     ENDIF
					ENDIF
				     ENDIF
				ENDIF

			 CASE "X"
				IF StrCmp(command,'-x',2)
					turnpwoff()
				ELSE
				     IF StrCmp(command,'-X',2)
					alreadyon()
				     ELSE
					UpperStr(command)
					IF StrCmp(command,'-C',2)
						changepw()
					ELSE
					     IF StrCmp(command,' ?',2)
						listoptions()
					     ELSE
						askpw()
					     ENDIF
					ENDIF
				     ENDIF
				ENDIF

			ENDSELECT
		ENDIF			
		
		DeleteComm(d)
		CloseLibrary(aedoorbase)
	ELSE
		WriteF('Could not open AEDoor.library V1!\n')
	ENDIF
ENDPROC


PROC newuser()
	handle:= Open(filename,MODE_NEWFILE)

	WriteStr(d,'\ec',NOLF)
	header()
	WriteStr(d,'You have started Shadow-W the first time ! You must enter now your',LF)
	WriteStr(d,'personal W-Password ! You have to enter this password, if you want to',LF)
	WriteStr(d,'change anything in your personal BBS-Settings (Like Changing PW, Location...)',LF)
	WriteStr(d,'If you want to change your own W-Password you must enter `W -C` (`C`hange) !',LF)
	WriteStr(d,'After this the door asks for the *OLD* PW. You *MUST* enter it and then you',LF)
	WriteStr(d,'can enter your *NEW* PW !',LF)
	WriteStr(d,'Type W ? to see all options !',LF)
	WriteStr(d,'Ok,let`s start...',LF)
	aufbau('WELCOME !!!           |')

	res:=Prompt(d,20,'')
	IF (res<>NIL)
		StrCopy(pw,res,ALL)
		UpperStr(pw)
		WriteStr(d,'',LF)
		WriteStr(d,'                       .----------------------------------.',LF)
		WriteStr(d,'                       | LAST MSG.: PW OK! WRITING DATA!  |',LF)
		WriteStr(d,'                       `----------------------------------\a',LF)
		Write(handle,pw,MAX_PWLEN)
		SetDT(d,RETURNCOMMAND,'W')
		Delay(100)
	ENDIF
	Close(handle)
ENDPROC


PROC header()
	WriteStr(d,'\n                      SHADOW-W V1.3 BY SHADOW MAN/S8 IN 1993',LF)
	WriteStr(d,'                     ----------------------------------------\n',LF)
ENDPROC


PROC aufbau(mesg)
	WriteStr(d,'\n',LF)
	WriteStr(d,'                       .----------------------------------.',LF)
	WriteStr(d,'                       | ENTER W-PW:                      |',LF)
	WriteStr(d,'                       `----------------------------------\a',LF)
	WriteStr(d,'                       .----------------------------------.',LF)
	WriteStr(d,'                       | LAST MSG.: ',NOLF)
	WriteStr(d,mesg,LF)
	WriteStr(d,'                       `----------------------------------\a',LF)
ENDPROC


PROC askpw()
 DEF pass[MAX_PWLEN]:STRING
	WriteStr(d,'\ec',NOLF)
	header()
	aufbau('WELCOME !!!           |')
	res:=Prompt(d,20,'')
	IF (res<>NIL)
		StrCopy(pass,res,ALL)
		UpperStr(pass)
		WriteStr(d,'',LF)
		WriteStr(d,'                       .----------------------------------.',LF)
		IF StrCmp(pw,pass,ALL)
			WriteStr(d,'                       | LAST MSG.: PASSWORD OK! CU L8ER! |',LF)
			SetDT(d,RETURNCOMMAND,'W')
		ELSE
			WriteStr(d,'                       | LAST MSG.: PASSWORD FAIL!        |',LF)
			Delay(100)
		ENDIF
		WriteStr(d,'                       `----------------------------------\a',LF)
		Delay(50)
	ENDIF
ENDPROC


PROC changepw()
 DEF pass[MAX_PWLEN]:STRING
	WriteStr(d,'\ec',NOLF)
	header()
	aufbau('WELCOME !!!           |')
	res:=Prompt(d,20,'')
	IF (res<>NIL)
		StrCopy(pass,res,ALL)
		UpperStr(pass)
		IF StrCmp(pw,pass,ALL)
			aufbau('PASSWORD OK!          |')
			handle:=Open(filename,MODE_NEWFILE)
			res:=Prompt(d,20,'*NEW* ')
			IF (res<>NIL)
				StrCopy(pw,res,ALL)
				UpperStr(pw)
				WriteStr(d,'',LF)
				WriteStr(d,'                       .----------------------------------.',LF)
				WriteStr(d,'                       | LAST MSG.: PW OK! WRITING DATA!  |',LF)
				WriteStr(d,'                       `----------------------------------\a',LF)
				Write(handle,pw,MAX_PWLEN)
				Delay(100)
			ENDIF
			Close(handle)
		ELSE
			pwfail()
		ENDIF
	ENDIF
ENDPROC


PROC listoptions()
	WriteStr(d,'\ec',NOLF)
	header()
	WriteStr(d,'\n         .--------------------------------------------------------------.',LF)
	WriteStr(d,'         | List of avaible options:                                     |',LF)
	WriteStr(d,'         |                                                              |',LF)
	WriteStr(d,'         | W -c OR -C =-> CHANGE OWN W-PASSWORD (OLD PW NEEDED!)        |',LF)
	WriteStr(d,'         | W -x       =-> TURN PASSWORD PROTECTION OFF (OLD PW NEEDED!) |',LF)
	WriteStr(d,'         | W -X       =-> TURN PASSWORD PROTECTION ON, IF IT IS OFF!    |',LF)
	WriteStr(d,'         | W ?        =-> THIS PAGE!                                    |',LF)
	WriteStr(d,'         `--------------------------------------------------------------\a\n',LF)
ENDPROC


PROC insertflag()
	handle:= Open(filename,MODE_NEWFILE)
	Write(handle,pw,MAX_PWLEN)
	Write(handle,'X',1)
	Close(handle)
	StrCopy(flag,'X',ALL)
ENDPROC


PROC turnpwoff()
 DEF pass[MAX_PWLEN]:STRING
	WriteStr(d,'\ec',NOLF)
	header()
	aufbau('WELCOME !!!           |')
	res:=Prompt(d,20,'')
	IF (res<>NIL)
		StrCopy(pass,res,ALL)
		UpperStr(pass)
		WriteStr(d,'',LF)
		WriteStr(d,'                       .----------------------------------.',LF)
		IF StrCmp(pw,pass,ALL)
			WriteStr(d,'                       | LAST MSG.:PROTECTION TURNED OFF!|',LF)
			handle:= Open(filename,MODE_NEWFILE)
			Write(handle,pw,MAX_PWLEN)
			Write(handle,'x',1)
			Close(handle)
		ELSE
			WriteStr(d,'                       | LAST MSG.: PASSWORD FAIL!        |',LF)
			Delay(100)
		ENDIF
		WriteStr(d,'                       `----------------------------------\a',LF)
		Delay(50)
	ENDIF
ENDPROC


PROC turnpwon()
	WriteStr(d,'\ec',NOLF)
	header()
	aufbau('PROTECTION TURNED ON !|')
	handle:=Open(filename,MODE_NEWFILE)
	Write(handle,pw,MAX_PWLEN)
	Write(handle,'X',1)
	Close(handle)
ENDPROC


PROC alreadyoff()
	WriteStr(d,'\ec',NOLF)
	header()
	aufbau('PROTECT\aN ALREADY OFF!|')
ENDPROC


PROC alreadyon()
	WriteStr(d,'\ec',NOLF)
	header()
	aufbau('PROTECTION ALREADY ON!|')
ENDPROC


PROC pwfail()
	aufbau('PASSWORD FAIL!        |')
	Delay(100)
ENDPROC