'                             ***  ROUSER  ***
'
'                             Louis F. Sander
'                             153 Mayer Drive
'                          Pittsburgh, PA  15237
'                             (412)  367-1376
'
' Rousing melodies arranged for QuickBASIC 4.5, 12/91 - 1/92
'
DECLARE SUB Alouette ()
DECLARE SUB America ()
DECLARE SUB AnchorsAweigh ()
DECLARE SUB Assembly ()
DECLARE SUB Attention ()
DECLARE SUB BlowTheManDown ()
DECLARE SUB BritishGrenadiers ()
DECLARE SUB Caissons ()
DECLARE SUB CallToTheColors ()
DECLARE SUB CarryOn ()
DECLARE SUB Charge ()
DECLARE SUB Columbia ()
DECLARE SUB Dixie ()
DECLARE SUB DrunkenSailor ()
DECLARE SUB FirstCall ()
DECLARE SUB Flourishes ()
DECLARE SUB FuneralMarch ()
DECLARE SUB GeneralQuarters ()
DECLARE SUB HailToTheChief ()
DECLARE SUB HappyDays ()
DECLARE SUB Help ()
DECLARE SUB HotTime ()
DECLARE SUB LaMarseillaise ()
DECLARE SUB MarinesHymn ()
DECLARE SUB MessCall ()
DECLARE SUB NobodyKnows ()
DECLARE SUB Onward ()
DECLARE SUB Reveille ()
DECLARE SUB ShaveAndHaircut ()
DECLARE SUB Taps ()
DECLARE SUB TaRaRaBoomDe ()
DECLARE SUB USAirForce ()
DECLARE SUB WaltzingMatilda ()
DECLARE SUB WhenTheSaints ()
DECLARE SUB YankeeDoodle ()
DECLARE SUB YoureInTheArmyNow ()

ON ERROR GOTO NoColor  'For Hercules video, which chokes on COLOR statements

'*** CHECK FOR COMMAND LINE

IF LEN(COMMAND$) = 1 THEN A$ = COMMAND$
IF A$ >= "0" AND A$ <= "9" OR A$ >= "A" AND A$ <= "Z" THEN
  CommandFlag = 1
  GOTO PlayFromCommandLine:
END IF

'*** PRINT THE MENU

T$ = "Rousing Songs and Military Melodies - Louis F. Sander - (412) 367-1376"

CLS
COLOR 2
PRINT "É"; STRING$(78, "Í"); "»";
PRINT "º"; TAB(80); "º"
PRINT "Ì"; STRING$(78, "Í"); "¹";
FOR J = 4 TO 21: PRINT "º"; TAB(80); "º"; : NEXT J
PRINT "Ì"; STRING$(78, "Í"); "¹";
PRINT "º"; TAB(80); "º";
PRINT "È"; STRING$(78, "Í"); "¼";
LOCATE 3, 40: PRINT "Ë";
FOR J = 4 TO 21: LOCATE J, 40: PRINT "º"; : NEXT J
LOCATE 22, 40: PRINT "Ê"
LOCATE 10, 40: PRINT "ÌÍÍÍÍÍÍÍÍÍÍÍÍ  BUGLE CALLS  ÍÍÍÍÍÍÍÍÍÍÍ͹"
COLOR 14
LOCATE 2, 2 + (77 - LEN(T$)) / 2: PRINT T$
COLOR 15
LOCATE 4, 3: PRINT "1 - Alouette"
LOCATE 5, 3: PRINT "2 - America (My Country 'Tis of Thee)"
LOCATE 6, 3: PRINT "3 - Anchors Aweigh"
LOCATE 7, 3: PRINT "4 - Blow the Man Down"
LOCATE 8, 3: PRINT "5 - British Grenadiers"
LOCATE 9, 3: PRINT "6 - Caissons Go Rolling Along"
LOCATE 10, 3: PRINT "7 - Columbia the Gem of the Ocean"
LOCATE 11, 3: PRINT "8 - Dixie"
LOCATE 12, 3: PRINT "9 - Drunken Sailor"
LOCATE 13, 3: PRINT "A - Funeral March"
LOCATE 14, 3: PRINT "B - Hail to the Chief"
LOCATE 15, 3: PRINT "C - Happy Days Are Here Again"
LOCATE 16, 3: PRINT "D - Hot Time in the Old Town Tonight"
LOCATE 17, 3: PRINT "E - La Marseillaise"
LOCATE 18, 3: PRINT "F - Marines' Hymn"
LOCATE 19, 3: PRINT "G - Nobody Knows the Trouble I Seen"
LOCATE 20, 3: PRINT "H - Onward Christian Soldiers"
LOCATE 21, 3: PRINT "I - Shave and a Haircut, Ten Cents"
LOCATE 4, 42: PRINT "J - Ta Ra Ra Boom De Ay"
LOCATE 5, 42: PRINT "K - U.S. Air Force (Wild Blue Yonder)"
LOCATE 6, 42: PRINT "L - Waltzing Matilda"
LOCATE 7, 42: PRINT "M - When the Saints Go Marching In"
LOCATE 8, 42: PRINT "N - Yankee Doodle"
LOCATE 9, 42: PRINT "O - You're In the Army Now"
LOCATE 11, 42: PRINT "P - Assembly"
LOCATE 12, 42: PRINT "Q - Attention"
LOCATE 13, 42: PRINT "R - Carry On"
LOCATE 14, 42: PRINT "S - Call to the Colors"
LOCATE 15, 42: PRINT "T - Charge"
LOCATE 16, 42: PRINT "U - First Call"
LOCATE 17, 42: PRINT "V - Flourishes (Honors)"
LOCATE 18, 42: PRINT "W - General Quarters"
LOCATE 19, 42: PRINT "X - Mess Call"
LOCATE 20, 42: PRINT "Y - Reveille"
LOCATE 21, 42: PRINT "Z - Taps"

'*** CHOOSE FROM THE MENU

DO
  COLOR 7: LOCATE 23, 3: PRINT "F1-Help";
  COLOR 14: LOCATE 23, 21: PRINT "*** PRESS THE KEY FOR YOUR SELECTION ***";
  COLOR 7: LOCATE 23, 71: PRINT "Esc-QUIT";
  A$ = UCASE$(INKEY$)
  IF A$ >= "0" AND A$ <= "9" OR A$ >= "A" AND A$ <= "Z" OR A$ = "-" THEN
      COLOR 11
      LOCATE 23, 2: PRINT SPACE$(78)
      LOCATE 23, 29: PRINT "Now Playing Selection "; A$
      COLOR 7
  END IF
PlayFromCommandLine:
  SELECT CASE A$
    CASE CHR$(0) + CHR$(59) 'F1
      CALL Help: RUN
    CASE "1"
      Alouette
    CASE "2"
      America
    CASE "3"
      AnchorsAweigh
    CASE "4"
      BlowTheManDown
    CASE "5"
      BritishGrenadiers
    CASE "6"
      Caissons
    CASE "7"
      Columbia
    CASE "8"
      Dixie
    CASE "9"
      DrunkenSailor
    CASE "A"
      FuneralMarch
    CASE "B"
      HailToTheChief
    CASE "C"
      HappyDays
    CASE "D"
      HotTime
    CASE "E"
      LaMarseillaise
    CASE "F"
      MarinesHymn
    CASE "G"
      NobodyKnows
    CASE "H"
      Onward
    CASE "I"
      ShaveAndHaircut
    CASE "J"
      TaRaRaBoomDe
    CASE "K"
      USAirForce
    CASE "L"
      WaltzingMatilda
    CASE "M"
      WhenTheSaints
    CASE "N"
      YankeeDoodle
    CASE "O", "0"
      YoureInTheArmyNow
    CASE "P"
      Assembly
    CASE "Q"
      Attention
    CASE "R"
      CarryOn
    CASE "S"
      CallToTheColors
    CASE "T"
      Charge
    CASE "U"
      FirstCall
    CASE "V"
      Flourishes
    CASE "W"
      GeneralQuarters
    CASE "X"
      MessCall
    CASE "Y"
      Reveille
    CASE "Z"
      Taps
  END SELECT
  IF CommandFlag THEN PLAY "P4": END
  IF A$ >= "0" AND A$ <= "9" OR A$ >= "A" AND A$ <= "Z" THEN
      PLAY "P4"
      FOR J = 1 TO 50: A$ = INKEY$: NEXT
      LOCATE 23, 2: PRINT SPACE$(78)
  END IF
LOOP UNTIL A$ = CHR$(27)

CLS
COLOR 7
PRINT
PRINT "Rousing Songs and Military Melodies was created by:"
PRINT
N = 16
PRINT TAB(N); "Louis F. Sander"
PRINT TAB(N); "153 Mayer Drive"
PRINT TAB(N); "Pittsburgh, PA  15237"
PRINT TAB(N); "(412) 367-1376"
PRINT
PRINT "If you've enjoyed it, he'd like to hear from you."
PRINT
PRINT

END

NoColor:
RESUME NEXT

SUB Alouette

'Alouette - French Canadian Folk Song
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T90 mn"
'     Set Music Parameters

Verses = 2
'The verses, being parts of the alouette/lark that are dressed for a feast:
'1-la tˆte  2-le bec  3-le nez  4-le dos  5-les pieds  6-les pattes  7-le cou
'  (head)     (beak)    (nose)    (back)    (feet)       (claws)       (neck)

PLAY "G8. ms A16 B8 B8 mn A16. G32 A16. B32 G8 D8"
'     Alouette, gentille Alouette,

PLAY "G8. ms A16 B8 B8 mn A16. G32 A16. B32 G4"
'     Alouette, je te plumerai.

PLAY "G16. G32 G16. B32 >D16. D32 D8"
'     Je te plumerai la tˆte (or whatever),

PLAY "D16. E32 D16. C32 <B16. A32 G8"
'     Je te plumerai la tˆte (or whatever),

FOR Verse = 1 TO Verses
  PLAY ">D16. D32 D8 <D16. D32 D8"
  '     Et la tˆte, Et la tˆte, (or whatever)
NEXT Verse

PLAY ">D8 C8 <B8 A8"
'     Oh . . .

PLAY "G8. A16 B8 B8 A16. G32 A16. B32 G8 D8"
'     Alouette, gentille Alouette,

PLAY "G8. A16 B8 B8 A16. G32 A16. B32 G4"
'     Alouette, je te plumerai.

END SUB

SUB America

'America (My Country 'Tis of Thee) - Traditional - Words: S. F. Smith, 1831
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T72 mn"
'     Set music parameters

PLAY "D8 D8 E8 C#8. D16 E8"
'     My country, 'tis of thee,

PLAY "F#8 F#8 G8 F#8. E16 D8"
'     Sweet land of liberty,

PLAY "E8 D8 C#8 D4."
'     Of thee I sing;

PLAY "A8 A8 A8 A8. G16 F#8"
'     Land where my fathers died,

PLAY "G8 G8 G8 G8. F#16 E8"
'     Land of the pilgrims' pride,

PLAY "F#8 ml G16 mn F#16 ml E16 mn D16 F#8. G16 A8"
'     From every mountainside

PLAY "ml B16 mn G16 F#8 E8 D4."
'     Let freedom ring.

END SUB

SUB AnchorsAweigh

'Anchors Aweigh - Charles A. Zimmerman, 1906
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T90 mn"
'     Set music parameters

PLAY "C4 E8 G8 A8. E16 A4"
'     Anchors aweigh, my boys,

PLAY ">C8 C8 D8 <G8 ml >C4 mn C4"
'     Anchors aweigh.

PLAY "<A4 >C8 <A8 G8 A8 B8"
'     Farewell to college joys,

PLAY ">C8 <F#8 A8 >D8 C8 <B8 G8 F8 D8"
'     We sail at break of day-ay-ay-ay.

PLAY "C4 E8 G8 A8. E16 A4"
'     Through our last night on shore,

PLAY ">C4 D8 <G8 ml >C4 mn C4"
'     Drink to the foam.

PLAY "<A4 >C8 <A8 G8 A8 B8"
'     Until we meet again,

PLAY ">C8 ms E16 mn <G16 F#16 G16 ms >D16 mn <G16 F#16 G16 ml >C4 mn C4"
'     Here's wishing you a happy voyage home.

END SUB

SUB Assembly

'Assembly - Navy Bugler's Manual
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T100 mn G16. G32 >C16. <G32 >C16. E32 C8 C16 C32 E16. C32 E16. G32 "
PLAY "E8 C16. E32 G8 E16. C32 <G8 G16. G32 >C8 C16. C32 C8."

END SUB

SUB Attention

'Attention - Navy Bugler's Manual
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O3 T100 mn C16 E4.. <G16 >E4.."

END SUB

SUB BlowTheManDown

'Blow the Man Down - American Sea Chantey
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T150 mn"
'     Set music parameters

PLAY "G8 G8 A8 G8 E8 C8 E8 G8 A8 G8 E4"
'     I'll sing you a song, a good song of the sea,

PLAY "ml C16 mn E16 G4. A4. F8. E16 F8 D4"
'     To me way, aye, blow the man down;

PLAY "E8 F8 E8 F8 D8 <B8 >D8 F8 E8 F8 D4."
'     And trust that you'll join in the chorus with me,

PLAY "G8 G8 G8 G4 F8 E8. D16 E8 C4"
'     Give me some time to blow the man down.

END SUB

SUB BritishGrenadiers

'The British Grenadiers - 16th-century Tune
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T120 mn"
'     Set music parameters

FOR J = 1 TO 2
  PLAY "C8 F8 C8 F8 G8 A4 G8"
  '1:   Some talk of Alexander,
  '2:   Of Hector and Lysander,

  PLAY "mn A16 ml B-16 >C8 <F8 ml A16 mn G16 ml F16 mn E16 F4."
  '1:   And some of Hercules,
  '2:   And such great names as these.
NEXT J
PLAY "ml A16 mn B-16 >C8. D16 C8 <B-8 ml A8. mn B-16 >C8"
'     But of all the world's brave heroes,

PLAY "<F8 >D8 D8 ml C16 mn <B-16 ml A16 mn G16 ml F4 mn E8"
'     There's none that can compare

PLAY "C16 C16 F8 C8 F8 G8 A8 B-16 A16 G8"
'     With a tow, row, row, row, row, row,

PLAY "ml A16 mn B-16 >C8 <F8 ml A16 mn G16 ml F16 mn E16 F4."
'     To the British Grenadier.

END SUB

SUB Caissons

'The Caissons Go Rolling Along - Brig. Gen. E. L. Gruber, 1908
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T75 mn"
'     Set music parameters

PLAY "G16 E16 G8 G16 E16 G8 G16 E16 G16. A32 G16 E16 G8"
'     Over hill, over dale, we have hit the dusty trail,

PLAY "E16 F16 G16 F8 D16 G16 F8 D16 ml C4 mn P16"
'     And those caissons go rolling along.

PLAY "G16 E16 G8 G16 E16 G8 G16 E16 G16. A32 G16 E16 G8"
'     In and out, hear them shout, counter march and right about,

PLAY "E16 F16 G16 F8 D16 G16 F8 D16 ml C4 mn P16"
'     And those caissons go rolling along.

PLAY "G16 G16 >C8 C8 <G8 G16 G16 A16 B16 >C16 <A16 G4"
'     For it's Hi! Hi! Hee! in the Field Artillery,

PLAY ">C16 C8 <B16 A16 B16 >C16 <A16 ml >D4 mn D8"
'     Shout out your numbers loud and strong!

PLAY "<G16 G16 >C8 C8 <B4 A16 B16 >C16 <A16 G8"
'     For where e'er you go, you will always know

PLAY "E16 F16 G16 F8 D16 G16 F8 D16 C16 P16"
'     That those caissons are rolling along;

PLAY "G16. G32 G16 G16"
'     (Keep 'em rolling!)

PLAY "E16 F16 G16 F8 D16 G16 F8 D16 ml C4 mn C16 P16"
'     And those caissons go rolling along.

END SUB

SUB CallToTheColors

'Call to the Colors - Navy Bugler's Manual
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***
         
PLAY "O3 T72 mn E16. E32 G8 C16. C32 E8 <G16."
PLAY "G32 >C8 C16. C32 C8 C16. E32 G8 G16. G32"
PLAY "E8 C16. E32 G4 <G8 >E16. E32 G8 C16."
PLAY "C32 E8 <G16. G32 >C8 C16. C32 C8 C16."
PLAY "E32 G16 E16 C16 <G16 >G16 E16 C16 <G16 >C8 C16. C32 C8"
PLAY "<G16. G32 >C4 C16 C32 C32 C16 C16 E4 E16 E32"
PLAY "E32 E16 E16 G4 G16 G32 G32 G16 G16 E16 G16 E32 C32 <G16"
PLAY ">E16 G16 E32 C32 <G16 >G16 G32 G32 G16 G16 G8"
PLAY "E16. E32 G8 C16. C32 E8 <G16."
PLAY "G32 >C8 C16. C32 C8 C16. E32 G8 G16. G32"
PLAY "E8 C16. E32 G4 <G8 >E16. E32 G8 C16."
PLAY "C32 E8 <G16. G32 >C8 C16. C32 C8 C16."
PLAY "E32 G16 E16 C16 <G16 >G16 E16 C16 <G16 >C8 C16. C32 C8"

END SUB

SUB CarryOn

'Carry On - U.S. Navy
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T120 mn G16 >C16 E16 G16 G16 G16 <G16 G16 G16 >C8"

END SUB

SUB Charge

'Charge - Navy Bugler's Manual
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O3 T100 mn C16. C32 C16. C32 C16. C32 C16. C32 C16. C32 C16. E32 "
PLAY "G16. E32 G16. E32 G16. E32 C16. C32 C16. C32 C16. "
PLAY "E32 G16. E32 G16. E32 G16. E32 ml C4 C16 mn P16"

END SUB

SUB Columbia

'Columbia, the Gem of the Ocean - Disputed Origin - Published in 1843
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T75 mn"
'     Set music parameters

PLAY "C16. C32 F8 F16. F32 G8 >C16. <B-32 A16 F8. P8"
'     Columbia, the gem of the ocean,

PLAY "C8 D8 ml >D16 mn C16 ml <B-16 A16 G16 mn F16 ml F4 mn E8 P16"
'     The home of the brave and the free.

PLAY "G16 G8 G16. G32 G8 ml A16 mn B16 ml >C16 mn <G8 P16 P8"
'     The shrine of each patriot's devotion,

PLAY ">C8 ml <B16 A16 G16 mn F16 ml E16 D16 G16 mn <B16 >C4 P8."
'     A world offers homage to thee.

PLAY "C16 G8 G16. G32 ml F16 E16 D16 mn C16 C16 F8. P8"
'     Thy mandates make heroes assemble

PLAY "ml F16 mn G16 A8 A16 A16 ml B-16 A16 G16 mn F16 G8 P8 P8"
'     When liberty's form stands in view;

PLAY "G8 >C16 C8 C16 ml <B-16 A16 G16 mn F16 E16 D8 P16 P8"
'     Thy banners make tyranny tremble

PLAY "ml >D16 mn C16 mL <B-16 A16 G16 mn F16 E8 ml D16 mn E16 F8 P8 P8"
'     When borne by the red, white and blue.

PLAY "ml E16 mn F16 G8 G16. G32 G8 ml >C16. <B-32 A8 P8 P8"
'     When borne by the red, white and blue.

PLAY "ml E16 mn F16 G8 G16. G32 G8 ml >C16. <B-32 A8 P8 P8"
'     When borne by the red, white and blue.

PLAY "ml F16 mn A16 >C8 C16 C16 <B-16 A16 G16 mn F16 E16 D8 P16 P8"
'     Thy banners make tyrrany tremble

PLAY "ml >D16 mn C16 mL <B-16 A16 G16 mn F16 E8 ml D16 mn E16 F4 P8"
'     When borne by the red, white and blue.

END SUB

SUB Dixie

'Dixie - Daniel Decatur Emmett, 1859
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T120 mn"
'     Set music parameters

FOR J = 1 TO 2
 
  PLAY "ml F16 mn D16 <B-8 B-8 ml B-16 >C16 D16 E-16 mn F8 F8 F8 D8"
  '1:   Oh I wish I was in the land of cotton,
  '2:   In Dixie Land where I was born in,

  PLAY "G8 G8 ml G8. mn F16 ml G8. mn F16 ml G16 A16"
  '1:   Old times there are not forgotten,
  '2:   Early on one frosty mornin'

  PLAY "B-16 mn >C16 D4. ml <B-16 mn F16 B-4. ml"
  '1&2: Look away! Look away!

  PLAY "F16 mn D16 F4. ml C16 mn D16 <B-4. >"
  '1&2: Look away Dixie Land.

NEXT J

PLAY "F16 F16 ml B-8 mn >D8 ml C8 mn <B-8 G8 B-4  G8 >C4. <G8 >C4."
'     Oh, I wish I was in Dixie, Hooray! Hooray!

PLAY "<F8 ml B-8 mn >D8 ml C8 mn <B-8 ml G8 mn A8 ml B-8. mn"
'     In Dixie Land I'll take my stand

PLAY "G16 ml F8 mn D8 ml B-8. mn D16 D8 C8. P16"
'     To live and die in Dixie.

PLAY "D8 <B-4. >D8 C4. G8 ml F8 mn D8 ml B-8. mn >D16 C8 <B-8. P16"
'     Away, away, away down south in Dixie,

PLAY "D8 <B-4. >D8 C4. G8 ml F8 mn D8 ml >D8. <B-16 >C8 <B-4."
'     Away, away, away down south in Dixie.

END SUB

SUB DrunkenSailor

'The Drunken Sailor - Traditional Sea Shanty
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T120 mn"
'     Set music parameters

PLAY "A8 A16 A16 A8 A16 A16 A8 D8 F8 A8"
'     What shall we do with the drunken sailor?

PLAY "G8 G16 G16 G8 G16 G16 G8 C8 E8 G8"
'     What shall we do with the drunken sailor?

PLAY "A8 A16 A16 A8 A16 A16 A8 B8 >C8 D8"
'     What shall we do with the drunken sailor,

PLAY "C8 <A8 G8 E8 D4 D4"
'     Earlye in the morning?

PLAY "A4 A8. A16 A8 D8 F8 A8"
'     Hoo-ray and up she rises,

PLAY "G4 G8. G16 G8 C8 E8 G8"
'     Hoo-ray and up she rises,

PLAY "A4 A8. A16 A8 B8 >C8 D8"
'     Hoo-ray and up she rises,

PLAY "C8 <A8 G8 E8 D4 D4"
'     Earlye in the morning.

END SUB

SUB FirstCall

'First Call - Navy Bugler's Manual
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T132 mn G24 >C24 E24 G8 G24 G24 G24 G8 E8 E24 E24 E24 E8"
PLAY "C8 E8 C8 <G8 P8 G24 >C24 E24 G8 G24 G24 G24 G8"
PLAY "G8 E8 C8 <G8 G24 G24 G24 G8 >C2"

END SUB

SUB Flourishes

'Flourishes (4) - Navy Bugler's Manual
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

FOR J = 1 TO 3
  PLAY "O2 T140 ms G8 G16 G16 G8 G16 G16 ml >C4. <P8"
NEXT
PLAY "ms G8 G16 G16 G8 G16 G16 ml >C2 C8 mn P4 P8"

END SUB

SUB FuneralMarch

'Funeral March (Marche FunŠbre) - Fr‚deric Chopin, Op. 35, 1840
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O1 T75 mn B-4 B-8. B-16 B-4 >D-8. C16 C8. <B-16 B-8. B-16 B-2"

END SUB

SUB GeneralQuarters

'General Quarters - Navy Bugler's Manual
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O3 T90 ms C16 C16 ml C16 <G16 ms >E16 E16 ml E16 C16"
PLAY "ms G16 G16 ml G16 mn E16 ms E16 C16 <G8"
PLAY "ms >C16 C16 ml C16 <G16 ms >E16 E16 ml E16 C16"
PLAY "ms G16 G16 ml G16 E16 ms C16 <G16 >C8 mn"

END SUB

SUB HailToTheChief

'Hail to the Chief - James Sanderson, London, Circa 1812
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T150 mn"
'     Set music parameters

PLAY "A4 B8 >C#8 D4 C#8 <B8 ml A8. mn B16 A8 F#8 E4 D4"
'     Hail to the Chief, who in triumph advances,

PLAY "A4 >D8. E16 F#4 E8 D8 E8 D8 ml E8 mn F#8 E4 P4"
'     Honored and blessed be the evergreen pine.

PLAY "<A4 B8. >C#16 D4 C#8 <B8 ml A8. mn B16 A8 F#8 E4 D4"
'     Long may the tree in his banner that glances

PLAY "A4 >D8 C#8 ml <B8 mn >D8 <A8 F#8 A4 >D8. E16 D4 P4"
'     Flourish, the shelter and grace of our line. (Same words repeat below)

PLAY "F#4 F#8.. F#32 F#4 G8 F#8 ml E8. mn D16 E8 F#8 E4 <A4"
PLAY ">F#4 F#8. F#16 F#4 E8 D8 E8 A8 A4 A4 P4"
PLAY "D4 D8. C#16 <B4 >D8 <B8 ml A8 mn >D8 D8 E8 F#4 D4"
PLAY "<B4 >D8 <B8 ml A8. mn B16 A8 F#8 A4 >D8. E16 D4 P4"
              
END SUB

SUB HappyDays

'Happy Days are Here Again - American Political Song
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T120 mn"
'     Set music parameters

PLAY "C8 E16 E8 G8. G8 >C16 C8"
'     Happy days are here again!

PLAY "E8. E8 C16 C8 <G8. G8 E16 E8"
'     The skies above are clear again.

PLAY ">E8 E-16 D8 <B16 B8 G8. G8 F16 F8"
'     Let us sing a song of cheer again,

PLAY ">D8 E16 C8 C8 C8 C8 ml C4 C16 mn < P16"
'     Happy days are here again!

END SUB

SUB Help

CLS
COLOR 14
PRINT TAB(23); "INSTRUCTIONS AND HELP FOR ROUSER"
PRINT
COLOR 15
PRINT "  1. When a song is playing, the only way to stop it is to break out of the"
PRINT "     program by simultaneously pressing the CTRL and BREAK keys."
PRINT
PRINT "  2. You can play any song from the DOS prompt without putting the menu on"
PRINT "     the screen. Just type ROUSER, then a space, then the letter or number of"
PRINT "     the song you want to play. Press ENTER and your song will load and start"
PRINT "     to play. (You can also do this from a batch file)."
PRINT
PRINT "  3. To make a listing of the songs and their selection keys, put the menu"
PRINT "     on the screen, then use the PRINT SCREEN key to print it out."
PRINT
PRINT "     (If the menu borders don't print properly, you can usually correct the"
PRINT "     situation by changing one of the DIP switches on your printer. Look for"
PRINT "     a setting that prints IBM graphic characters; set it, then turn the"
PRINT "     printer off and back on to register the setting)."
PRINT
PRINT "  4. You can also use PRINT SCREEN to print out these instructions."
LOCATE 23, 6
COLOR 7
PRINT "Press Enter to continue...";
INPUT ; " ", A$
CLS
COLOR 14
PRINT TAB(27); "ABOUT THE ROUSER SOFTWARE"
PRINT
COLOR 15
PRINT "  1. ROUSER.EXE is the executable version of the program. It lets you play"
PRINT "     ROUSER's music through the loudspeaker of any IBM compatible machine,"
PRINT "     without using any version of the BASIC programming language."
PRINT
PRINT "  2. To modify the program and/or the songs, you need a second version,"
PRINT "     ROUSER.BAS. This is the QuickBASIC 4.5 source code, which you should be"
PRINT "     able to download from the same place you got ROUSER.EXE. ";
PRINT CHR$(34); "Source code"; CHR$(34)
PRINT "     is a plain text listing of the original BASIC program, showing all the"
PRINT "     BASIC statements, comments, etc."
PRINT
PRINT "     Even if you're a beginning programmer with a near zero amount of musical"
PRINT "     knowledge, you can do wonderful things with ROUSER.BAS. If you have QBASIC"
PRINT "     or QuickBASIC, you can modify ROUSER.BAS to change the music's pitch and"
PRINT "     tempo, to add or delete songs or parts of songs, etc. If you have Quick-"
PRINT "     BASIC, you can use it to make a modified version of ROUSER.EXE."
PRINT
PRINT "  3. ROUSER.BAS also lets you add ROUSER songs to BASIC programs of your own,"
PRINT "     whether they are written in QuickBASIC, GWBASIC, QBASIC, BASICA or any"
PRINT "     other version that uses the PLAY statement."
LOCATE 23, 6
COLOR 7
PRINT "Press Enter to continue...";
INPUT ; " ", A$
CLS
COLOR 14
PRINT TAB(15); "THEY LAUGHED WHEN I SAT DOWN AT THE COMPUTER..."
PRINT
COLOR 15
PRINT "     All but one of ROUSER's songs started out as sheet music that I got"
PRINT "     at my public library. Though I have only elementary knowledge of"
PRINT "     musical notation, I easily converted the music to BASIC statements."
PRINT
PRINT "     After only a few hours of practice, I could convert a big song like"
PRINT "     "; CHR$(34); "Dixie"; CHR$(34); " in 4O minutes or less. I also ";
PRINT "learned how to optimize the"
PRINT "     music for the computer's capabilities."
PRINT
PRINT "     With a little time and effort, you can do the same."
PRINT
PRINT "     I've written a very thorough instruction manual on making sheet "
PRINT "     music conversions, working with the PLAY statement, and making the "
PRINT "     music sound as you want it to sound. If you send me $12, I'll mail "
PRINT "     you a disk including the manual, the latest version of ROUSER.BAS, "
PRINT "     and additional music, sounds, and programs, all with a money back"
PRINT "     guarantee. Be sure to specify 5¬ or 3« inch disks."
PRINT
COLOR 11
PRINT "       Louis F. Sander  -  153 Mayer Drive  -  Pittsburgh, PA  15237"
LOCATE 23, 6
COLOR 7
PRINT "Press Enter to continue...";
INPUT ; " ", A$

END SUB

SUB HotTime

'A Hot Time in the Old Town Tonight - Spanish-American War Song
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T90 mn"
'     Set music parameters

PLAY "B8 B8 B8. ml A#32. mn B64 >C16 <B16 A#16 B16 G8. P16"
PLAY ">D8 D8 D8. ml C#32. mn D64 E16 D16 C#16 D16 <B16"
PLAY "D16 E16 G16 B8 B8 B8. ml A#32. mn B64 >C16 <B16 A#16 B16 G16"
PLAY "G16 F#16 G16 B16 A8 D32 D32 B16 A8 D16 ml G4 mn G16"

END SUB

SUB LaMarseillaise

'La Marseillaise - French National Anthem, adopted 1795
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376

PLAY "O2 T150 mn"
'     Get music parameters

PLAY "F16 F8. F16 B-4 B-4 >C4 C4 ml F4. mn D8 <B-8 P16"
'     Arise, ye sons of France to glory!

PLAY "B-16 ml >D8. mn <B-16 G4 >E-2 ml C8. mn <A16 ml B-2 mn P8."
'     Your day of freedom bids you rise!

PLAY "B-16 B-8. >C16 D4 D4 D4 ml E-8. mn D16 D4 C4 P4"
'     Your children, wives and grandsires hoary

PLAY "C8. D16 E-4 E-4 E-4 ml F8. mn E-16 D2 P4"
'     See their tears, and hear their cries!

PLAY "F8. F16 ml F4 D8. mn <B-16 >F4 D8. <B-16 F2 P8."
'     Behold their tears, and hear their cries.

PLAY "F16 F8. A16 >C4 C4 E-4 ml C8. mn <A16 B-4 ms B-4 mn"
'     Shall hateful tyrants, mischief breeding,

PLAY "A-2 G4 B-8. B-16 B-4 A8. B-16 >C2. P8"
'     With hireling hosts, a ruffian band,

PLAY "C8 D-4. D-8 D-8 D-8 E-8 F8 C2."
'     Affright and desolate the land,

PLAY "ml D-8. mn C8 <B-4. B-8 B-8 >D-8 C8. <B-8 ml B-4 mn A8 P8 P4 P8."
'     While peace and liberty lie bleeding?

PLAY ">F16 ml F2 mn F8. F16 D8. <B-16 ml >C2 mn P8."
'     To arms, ye brave!

PLAY "F16 ml F2 mn F8. F16 D8. <B-16 ml >C2 mn C8 P8"
'     Th'avenging sword unsheathe!

PLAY "<F4 B-2 P4 >C4 D2 P2 E-2 F4 G4 ml C2 mn C8 P8"
'     March on, march on! All hearts resolved

PLAY "G4 ml F2 mn F8. D16 E-8. C16 ml <B-2 mn B-8."
'     On victory or death!

END SUB

SUB MarinesHymn

'The Marines' Hymn - Melody by Jacques Offenbach, Words by an Unknown Marine
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T75 mn"
'     Set music parameters

PLAY "ml C16. mn E32 G8 G8 G8 G8 ml G8. mn >C16 <G8"
'     From the halls of Montezuma

PLAY "ml E16 mn F16 G8 G8 F16 D8. C4."
'     to the shores of Tripoli,

PLAY "ml C16. mn E32 G8 G8 G8 G8 ml G8. mn >C16 <G8"
'     We have fought our country's battles

PLAY "ml E16 mn F16 G8 G8 F16 D8. C4."
'     in the air, on land and sea;

PLAY "ml >C16. mn <B32 A8 F8 A8 F8 ml G8. mn A16 G8"
'     First to fight for right and freedom,

PLAY "ml >C16. mn <B32 A8 F8 A16 >C8. <G4."
'     And to keep our honor clean,

PLAY "ml C16. mn E32 G8 G8 G8 G8 ml G8. mn >C16 <G8"
'     We are proud to claim the title

PLAY "ml E16 mn F16 G8 G8 F8 D8 C4."
'     Of United States Marines.

END SUB

SUB MessCall

'Mess Call - Navy Bugler's Manual
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O3 T160 mn C8 E8 C8 E8 C4 C4"
PLAY "ms C8 mn C24 C24 C24 ms C8 E8 mn C4 P4"
PLAY "ms E8 G8 E8 G8 mn E4 E4"
PLAY "ms E8 mn E24 E24 E24 E8 ms G8 mn E4 P4"
PLAY "<G8 >C8 <G8 >C8 <G4 G4"
PLAY "ms G8 mn G24 G24 G24 G8 ms >C8 mn <G4. P8"

END SUB

SUB NobodyKnows

'Nobody Knows the Trouble I've Seen - American Negro Spiritual
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O1 T120 mn"
'     Set music parameters

PLAY "A8 C4 D8 F4. G8 A8 A8 A4 A2"
'     Nobody knows the trouble I've seen,

PLAY "A8 C4 D8 F4. F8 D4 C2."
'     Nobody knows but Jesus.

PLAY "A8 C4 D8 F4. G8 A8 A8 A4 A2"
'     Nobody knows the trouble I've seen,

PLAY ">C4. <A8 G4. A8 F4 F2 P4"
'     Glory Hallelujah!

PLAY "A4 >C4 C4 C4 <A4 >C4 C4 <A2"
'     Sometimes I'm up, sometimes I'm down,

PLAY ">C2 <A2 G2."
'     Oh, yes, Lord;

PLAY "A4 >C4 C4 C4 <A4 >C4 C4 <A2"
'     Sometimes I'm almost to the ground,

PLAY "A2 G2 F1"
'     Oh, yes, Lord!

'Repeat first 4 lines:
PLAY "A8 C4 D8 F4. G8 A8 A8 A4 A2"
PLAY "A8 C4 D8 F4. F8 D4 C2."
PLAY "A8 C4 D8 F4. G8 A8 A8 A4 A2"
PLAY ">C4. <A8 G4. A8 F2. P4"

END SUB

SUB Onward

'Onward, Christian Soldiers - Sullivan
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T90 mn"
'     Set music parameters

PLAY "C8 C8 C8 C8 ml C8. mn D16 C4 <G8 G8 F8 G8 A2"
'     Onward, Christian soldiers, marching as to war,

PLAY "F8 A8 >C8 F8 F4 E4 D8 D8 <A8 B8 >C2"
'     With the cross of Jesus going on before!

PLAY "<G8 G8 >C8 <G8 ml A8. mn B-16 A4 >C8 C8 F8 C8 D2"
'     Christ, the royal master, leads against the foe;

PLAY "D8 C8 <B-8 >C8 ml D8 mn C8 ml <B-8 >C8 mn D8 C8 <B-8 A8 G2"
'     Forward into battle, see His banners go.

PLAY "F8 F8 F8 F8 ml F8 E16 mn D16 ml E8 mn F8 G8 G8 G8 ml F16 mn G16 A2"
'     Onward, Christian soldiers, marching as to war,

PLAY ">C8 C8 F8 E8 F4 C4 <B-8 A8 G8. F16 F2"
'     With the cross of Jesus going on before!

END SUB

SUB Reveille

'Reveille - Navy Bugler's Manual
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T140 G8 ms >C8 mn E16 C16 <G8 ms >E8 C8 mn E16 C16 <G8 >E8"
PLAY "C8 E16 C16 <G8 ms >C8 mn E4 C8 ms <G8 mn"
PLAY ">C8 E16 C16 <G8 >E8 C8 E16 C16 <G8 >E8"
PLAY "C8 E16 C16 <G8 G8 >C4."
PLAY "E8 ms E8 E8 E8 E8 mn G4 E8 ms C8 E8 C8 E8 C8 mn E4 C8"
PLAY "ms E8 E8 E8 E8 E8 mn G4 E8 ms C8 E8 C8 <G8 G8 mn >C4.<"
PLAY "G8 ms >C8 mn E16 C16 <G8 ms >E8 C8 mn E16 C16 <G8 >E8"
PLAY "C8 E16 C16 <G8 ms >C8 mn E4 C8 ms <G8 mn"
PLAY ">C8 E16 C16 <G8 >E8 C8 E16 C16 <G8 >E8"
PLAY "C8 E16 C16 <G8 G8 >C4."

END SUB

SUB ShaveAndHaircut

'Shave and a Haircut, Two Bits - American Jingle
'Written and Arranged for QuickBASIC by Louis F. Sander, (412) 367-1376 ***

PLAY "O1 T60 mn G16 D32 D32 E16 ms D16 P16 F#16 G16 P16"

END SUB

SUB Taps

'Taps - Navy Bugler's Manual
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T90 mn G8. G16 ml >C2. mn <G8. >C16"
PLAY "ml E2. mn <G8 >C8 E4 <G8 >C8 E4 <G8 >C8"
PLAY "ml E2. mn C8. E16 G2 E4 C4"
PLAY "<G2. G8. G16 ml >C2. mn"

END SUB

SUB TaRaRaBoomDe

'Ta Ra Ra Boom De Ay - Traditional
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T75 mn P16 A16 G#16 A16 >D16. <A32 F#8."
PLAY "F#16 E16 F#16 A16. F#32 D8."
PLAY "F#16 E16 D16 E16. E32 E8."
PLAY "G16 F#16 E16 A16. F#32 D8."

END SUB

SUB USAirForce

'The U.S. Air Force (The Wild Blue Yonder) - Robert Crawford, 1939
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T120 mn"
'     Set music parameters

PLAY "<B8 >D16 ml D8. mn D8 P16 ml C16 <B16 mn A16 B8. >C8. C#8. D8."
'     Off we go, into the wild blue yonder

PLAY "E8 G16 ml G8. mn G8 P16 ml A16 G16 mn E16 ml D4. mn D8 P16 P8 P16"
'     Climbing high, into the sun;

PLAY "<B8 >D16 ml D8. mn D8 P16 ml C16 <B16 mn A16 B8. >C8. C#8. D8."
'     Here they come, zooming to meet our thunder,

PLAY "F#8 A16 ml A8. mn A8 P16 ml G16 F#16 mn E16 ml D4. mn D8 P16 P8 P16"
'     At 'em boys, give 'er the gun.

PLAY "<B8 >D16 ml D8. mn D8 P16 ml C16 <B16 mn A16 B8. >C8. C#8. D8."
'     Down we dive, spouting our flame from under,

PLAY "E8 G16 ml G8. mn G8 P16 ml E16 F#16 mn G16 ml F#4. mn F#8 P16"
'     Off with one hell of a roar!

PLAY "<B8. ml >G8. mn G8 G16 ml G#8. G#16 mn E16 E16 ml A8. mn A8 A16 B-8"
'     We live in fame, or go down in flame,

PLAY "P16 B-8 P16 ml B16 A16 mn G16 B8 G16 ml B16. mn G16. A8. ml G8. mn G8 P16"
'     Hey! Nothing can stop the Army Air Corps!

END SUB

SUB WaltzingMatilda

'Waltzing Matilda - Australian, early 20th century
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T66 mn"
'     Set music parameters

PLAY "F#16 F#16 F#16 F#16 E8 E8"
'     Once a jolly swagman

PLAY " ml D16 mn E16 ml F#16 mn D16 ml <B16 mn >C#16 D8"
'     camped by a billibong

PLAY "<A8 >ml D16 mn F#16 A8 A16 A16 A8 A16 A16 A8"
'     Under the shade of a coolibah tree

PLAY "ml D16 mn E16 F#8 F#16 F#16 E8 E8"
'     And he sang as he watched and

PLAY "ml D16 mn E16 ml F#16 mn D16 ml <B16 mn >C#16 D8"
'     waited till his billy boiled,

PLAY "<A8 ml >D16 mn F#16 A8 ml G16 mn F#16 E8 E16 E16 D8 P8"
'     You'll come a-waltzing Matilda with me!

PLAY "A8 A16 A16 A8 F#8 >D8 D16 D16 C#8 <B8"
'     Waltzing Matilda, waltzing Matilda,

PLAY "A8 A16 A16 B8 A16 A16 A8 ml G16 mn F#16 E8"
'     You'll come a-waltzing Matilda with me!

PLAY "ml D16 mn E16 F#8 F#16 F#16 E8 E8"
'     And he sang as he watched and

PLAY "ml D16 mn E16 ml F#16 mn D16 ml <B16 mn >C#16 D8"
'     waited till his billy boiled,

PLAY "<A8 ml >D16 mn F#16 A8 ml G16 mn F#16 E8 E16 E16 D8. P16"
'     You'll come a-waltzing Matilda with me!

END SUB

SUB WhenTheSaints

'When the Saints Go Marching In - American Negro Spiritual
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T75 mn"
'     Set music parameters

PLAY "C16 E16 F16 ml G4 mn G16"
'     Oh when the Saints

PLAY "C16 E16 F16 ml G4 mn G16"
'     Go marching in,

PLAY "C16 E16 F16 G8 E8 C8 E8 ml D4 mn D8"
'     Oh when the Saints go marching in,

PLAY "E16 E16 D16 C8. C16 E8 G16 G16 G16 ml F8. mn F8"
'     Lord, how I want to be in that number

PLAY "E16 F16 G8 E8 D8 D8 ml C4 mn C8"
'     When the Saints go marching in.

END SUB

SUB YankeeDoodle

'Yankee Doodle - Traditional American Tune
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T75 mn"
'     Set music parameters

PLAY "A16 A16 ml B16 mn >C#16 ml <A16 mn >C#16 ml <B16 mn"
'     Father and I went down to camp,

PLAY "E16 A16 A16 ml B16 mn >C#16 <A8 ml G#16. mn"
'     Along with Captain Goodwin,

PLAY "E32 A16 A16 ml B16 mn >C#16 ml D16 mn C#16 ml <B16 mn"
'     And there we saw the men and boys,

PLAY "A16 ml G#16 mn E16 ml F#16 mn G#16 A8 A8 ml"
'     As thick as hasty pudding.

PLAY "F#16. mn G#32 ml F#16 mn E16 ml F#16 mn G#16 A8 ml"
'     Yankee Doodle keep it up,

PLAY "E16. mn F#32 ml E16 mn D16 C#8 E8 ml"
'     Yankee Doodle dandy,

PLAY "F#16. mn G#32 ml F#16 mn E16 ml F#16 mn G#16 ml A16 mn"
'     Mind the music and the step,

PLAY "F#16 ml E16 mn A16 ml G#16 mn B16 A8 A16"
'     And with the girls be handy.

END SUB

SUB YoureInTheArmyNow

'You're In The Army Now - American Military Song
'QuickBASIC Arrangement by Louis F. Sander, (412) 367-1376 ***

PLAY "O2 T120 mn"
'     Set music parameters

PLAY "G16 >C8 C16 E8 <G16 >C8. P8"
'     You're in the Army now.

PLAY "<G16 ml >C16 E16 mn G16 E8 C16 <G8. P8"
'     You're not behind a plow.

PLAY "G16 >C16 C16 C16 C8"
'     You'll never get rich

PLAY "<G16 ms >C16 C16 mn C16 C8"
'     By digging a ditch,

PLAY "G16 E8 C16 <G8 G16 >C8. P8"
'     You're in the Army now.

END SUB