!
! Logon script for ReadCIX upload
!
    INFO "CIX Logon"
    SETUP (
     Baud=19200:
     Stop=1 :
     Parity=none :
     Handshake=xonxoff,rtscts
     Fail=None :
     Timeout=20 :
     Echo=off :
     Data=8 )
    ON send fail goto bad
    SET c1=4
rAlive:
		SEND "ATZ"
    WAIT 20 ( ON reply "OK<$d><$a>" GOTO alive )
    ON c1 GOTO rAlive
    GOTO merror
alive:
    SET C1=3
    GOTO reDial   
wait100:
    INFO "Waiting to redial"
    WAIT 60
reDial:
    SEND "ATDT<CixNumber>"
    WAIT 120 (
	ON reply "CONNECT" GOTO letsgo
	ON reply "NO DIALTONE" GOTO tele
	ON reply "NO CARRIER" GOTO nocar
	ON reply "ERROR" GOTO black
	ON reply "BUSY" GOTO again )
    GOTO merror
again:
    ON c1 GOTO wait100
    ALERT "Line busy" : EXIT
letsGo:
    INFO "CONNECTED..."
    SENDWAIT 160 "<$d>";,"login:" GOTO noLog
    SENDWAIT 160 "qix<$d>";,"new user)" GOTO noUser
    SENDWAIT 130 "<CixUserName>","Password:" GOTO noPass
    SEND "<CixPassword>"
tryAgain:
    WAIT 40 (
	ON REPLY "Main:" GOTO gotMain
	ON REPLY "More" GOTO gotMore )
    ALERT "SOMETHING STRANGE"
gotMain:
		SEND "OPTION DOWNLOAD X Q"
		SEND "OPTION UPLOAD X Q"
		INFO "Starting Upload"
		SEND "UPLOAD"
		WAIT 5
		TRANSMIT "loc::m:\cix\reply.txt","XMDM"
		SEND "SCPUT SCRIPT"
		WAIT 1
		INFO "Running Script"
		SEND "SCRIPT"
		WAIT 1
		WAIT 10 (ON REPLY "Main:" GOTO swoff
		         ON REPLY "y/n"   GOTO yorn)
		INFO "Problem! Disconecting"
swoff:
		INFO "Sending LOGOFF"
		SENDWAIT 20 "BYE","y/n" GOTO cont1
		SEND "Y"
cont1:
		INFO "Hanging UP!!"
		HANGUP
    INFO "Finished"
    EXIT
gotMore:
    WAIT 1
    SEND "n"
    GOTO tryAgain
yorn:
		SEND "Y<$d>"
		GOTO swoff
black:
    ALERT "Number dialled too many times" : EXIT
nocar:
    ALERT "No connection made" : EXIT
tele:
    ALERT "Check connected to telephone" : EXIT
merror:
    ALERT "Check modem connected" : EXIT
bad:
    ALERT "Check RS232 lead connected" : EXIT
noLog:
    ALERT "No Login received" : EXIT
noUser:
    ALERT "No user name" : EXIT
noPass:
    ALERT "No password" : EXIT
noMain:
    ALERT "No main"
    EXIT