@Goto Start

                             ___________________

                                TETRIS DELUXE
                             ___________________


If you are smart enough to view this batch file, you are probably smart enough
to run the real executable file.  However, please do not do this.  The game
assumes the presense of an EGA display, and further assumes that the vertical
retrace signal is not trapped by, say, Microsoft Windows.

After verifying that MS-Windows is not running, this batch file coaxes your VGA
into EGA emulation mode with the little foofoo program MODE_EGA.COM.  When the
game is finished running, VGA native mode is restored with opposite program
MODE_VGA.COM.  (If you have a real EGA, the mode switching programs will pose
no threat.)

For the curious, EGA mode is necessary on a VGA because EGA text mode uses
8-pixel wide characters, while VGA text modes use 9-pixel wide chracters.  Why
does that matter?  Because the game runs in 80x25 text mode with a custom
character set to simulate shaded blocks.  It's pretty neat, really.  The EGA's
8x14 character cells work really super neato with custom-defined characters,
but the VGA's 9x14 cells do not, as the 9th column is either blank or a repeat
of the 8th column.  Pretty broken if you ask me.  Anyway...

The reason the actual executable file is named TETRIS.XEX is to keep dumb
users (I assume you are a smart user) from running it directly, which could
cause strange results.  The file is renamed here on the fly to TETRIS.EXE and
back to TETRIS.XEX after the program exits.

                                                                       --TSL

_______________________________________________________________________________


:Start
@Echo Off

If Exist TETRIS_.EXE Ren TETRIS_.EXE TETRIS.XEX


:Components

   If not Exist  README.COM    Echo Component file README.COM is missing!
   If not Exist  TETRIS.DOC    Echo Component file TETRIS.DOC is missing!
   If not Exist  TETRIS.BAT    Echo Component file TETRIS.BAT is missing!
   If not Exist  TETRIS.FNT    Echo Component file TETRIS.FNT is missing!
   If not Exist  TETRIS.SCR    Echo Component file TETRIS.SCR is missing!
   If not Exist  TETRIS.XEX    Echo Component file TETRIS.XEX is missing!
   If not Exist  MODE_EGA.COM  Echo Component file MODE_EGA.COM is missing!
   If not Exist  MODE_VGA.COM  Echo Component file MODE_VGA.COM is missing!
   If not Exist  WINCHECK.COM  Echo Component file WINCHECK.COM is missing!

   If not Exist  README.COM    Goto End
   If not Exist  TETRIS.DOC    Goto End
   If not Exist  TETRIS.FNT    Goto End
   If not Exist  TETRIS.SCR    Goto End
   If not Exist  TETRIS.XEX    Goto End
   If not Exist  MODE_EGA.COM  Goto End
   If not Exist  MODE_VGA.COM  Goto End
   If not Exist  WINCHECK.COM  Goto End


:WinCheck

   WINCHECK

   If not ErrorLevel 1 Goto ReadMe

      Cls
      Echo.
      Echo Sorry, this program will not run reliably under Windows.
      Echo Please exit to DOS and try again.
      Echo.

      Goto End


:ReadMe

   If Exist README.CFG Goto Run

      Cls
      Echo.
      Echo You have not yet viewed the Tetris README file.  In a moment it will
      Echo automatically be displayed on your screen for your perusal.  You may
      Echo use the arrow keys to motor up and down through the file.  Home, End,
      Echo PageUp, PageDown, + and - are also available.  You can press Esc at
      Echo any time to exit the viewer.
      Echo.
      Echo.
      Pause
      README.COM TETRIS.DOC
      Cls
      Echo.
      Echo If you ever need to get back to the README file, just type "README"
      Echo at the DOS prompt from this directory.
      Echo.
      Echo Now that you have viewed the README file (and hopefully read it),
      Echo you are prepared to run the game!
      Echo.
      Echo.
      Pause

      Goto Run


:Run

   MODE_EGA
   Ren TETRIS.XEX TETRIS_.EXE >Nul
   TETRIS_.EXE
   Ren TETRIS_.EXE TETRIS.XEX >Nul
   MODE_VGA

   Cls
   Echo.
   Echo.
   Echo Tank smudge for playing!
   Echo.
   Echo.


:End