From:             Graham/Oxyron <j.selck@flensburg.netsurf.de>
Send reply to:    j.selck@flensburg.netsurf.de
To:               amycoders@ibm.net
Date sent:        Sat, 29 Nov 1997 12:44:57 +0500
Subject:          AZZZZZUUUUREEE


; ################################################
; ###                                          ###
; ###   short water routine by Graham/Oxyron   ###
; ###                                          ###
; ###  written for the #amycoders competition  ###
; ###                                          ###
; ###  based on a water routine I did on c64!  ###
; ###                                          ###
; ################################################


 section "water",code	; the fun begins

Water_do:
		lea	data-260,a1
		moveq	#0,d7
		lea	([a1],a1.l,260.w),a2
		bchg	d7,1(a1)
		add.l	(a1)+,a1
.yo
		move.b	255(a1),d0
		add.b	257(a1),d0
		add.b	512(a1),d0
		add.b	(a1)+,d0
		asr.b	#1,d0
		sub.b	(a2),d0
		smi	d1
		sub.b	d1,d0
		move.b	d0,(a2)+
		add.b	#$20,d0
		move.b	d0,(a0)+
		addq.w	#1,d7
		bne.b	.yo
		rts

Water_Init:	; ...

		rts

Water_Drop:
		lea	data-260,a0
		move.l	(a0),d2
		move.b	d1,d2
		lsl.w	#8,d2
		move.b	d0,d2
		move.b	#$e8,(a0,d2.l,260.w)
		rts

 section "waterbss",bss
		ds.b	512
data:		ds.l	65536