config!S
------------------------------------------------------------------------------
Commands for spelling
..<rAmiga-u:             Start spell-checking mode by loading in the dictionary table.
..<rAmiga-c:             Find first misspelled word, starting at cursor.  Abort with Amiga-ESC.
..<virtual-z:            Click word in msg line (buf54), select word to replace word before cursor.
..<rAmiga-m:             Spell-check from cursor fwd.  Mark bad words with "@".
..<104:                  Force file saving to finish so buffer is unlocked
..<rAmiga-l:             Load supplemental dictionary & spell from cursor fwd.  Add to supplement.
..<rAmiga-d:             Merge dict supplement with Uedit/Spell/dict.A-Z files.
..<rAmiga-e:             Remove words from Uedit/Spell/dict.A-Z files.
..<rAmiga-f:             Stop spell-checking mode.  (Frees up about 12k of memory.)
..<rAmiga-t:             Search for THe capitalization errors.
..<rAmiga-space:         Search for end. Start spacing errors.
------------------------------------------------------------------------------
buf41
buf51
buf52
buf53
buf54
buf[n54]
n1
n2
n3
n4
n47
n48
n49
n50
n53
n54
n98
n99
------------------------------------------------------------------------------

Start spell-checking mode by loading in the dictionary table.
<rAmiga-u:  
   if (spellerUp)
         putMsg("Speller is up")
      else 
         if (startSpell("Uedit/Spell/Udtable", "Uedit/Spell/Udict",1))
               putMsg("Speller is up")
            else {
               putMsg("No memory or dictionary not found")
               returnFalse } 
   >Thursday 13-Dec-90 18:16:10

Find first misspelled word, starting at cursor.  Abort with Amiga-ESC.
<rAmiga-c:
   if (not spellerUp) runKey(rAmiga-u)
   putMsg(" ")
   while (not spell(buf54,curFile,buf41)) runKey(virtual-z) 
   >Thursday 13-Dec-90 18:16:10

Click word in msg line (buf54), select word to replace word before cursor.
<virtual-z:
   if (isEmpty(buf54)) return
   insertRgn(buf54,efile," ***",all)
   putMsg(buf54)
   vscroll(atCursor)
   updateDisplay
   getKeyVal(n3,n4)
   if (eqNum(n3,normal-esc)) abort
   mousexy(n1,n2)
   while (inputKey(n54)) nothing
   if (mouseDown) while (not inputWaiting) {
       if (not mouseDown) goto label(0)
       inputKey(n54)
   }
   label(0)
   if (geNum(n3,normal-gadget1) 
          & geNum(normal-gadget4,n3)
          & gtNum(n2,10) 
          & gtNum(20,n2)) {
       div(n1,n1,8)
       incNum(n1)
       moveCursor(buf54,sfile)
       moveCursor(buf54,eword)
       locToIndex(buf54,n54,atcursor)
       if (gtNum(n1,n54)) {
           indexToLoc(buf54,atCursor,n1)
           if (is(buf54,alpha)) {
               movecursor(buf54,eword)
               movecursor(buf54,sword)
               movecursor(curfile,sword)
               if (is(curfile,upperCase)) toUpper(buf54)
               clearRgn(curfile,word)
               insertrgn(curfile,atcursor,buf54,word)
               updateDisplay
           }
       }
   }
   putMsg(" ")
   freeBuf(buf54)
   while (inputKey(n54)) nothing
   if (mouseDown) while (not inputWaiting) {
       if (not mouseDown) return
       inputKey(n54)
   }
   >Thursday 13-Dec-90 18:16:11

Spell-check from cursor fwd.  Mark bad words with "@".
<rAmiga-m:
   if (not runKey(rAmiga-u)) returnFalse
   putMsg("Spell checking ... abort with Amiga-ESC")
   while (not spell(" ",curFile,buf41)) insertChar(curFile,"@") 
   >Thursday 13-Dec-90 18:16:12

Force file saving to finish so buffer is unlocked
<104: 
   while (getStackSize(n99,n99,n98) & gtNum(n98,0)) delay(5) 
   >Thursday 13-Dec-90 18:16:12

Load supplemental dictionary & spell from cursor fwd.  Add to supplement.
<rAmiga-l:
    if (not runKey(rAmiga-u)) returnFalse
    equateNum(n54,curFile)
    putMsg("Dict supplement to use (pmESC = UdSupplement)")
    freebuf(buf54)
    equateNum(n99,0)
    if (inputString(buf54))  {
       if (not loadFile(buf54)) goto label(3)
    } else {
label(3)
        if (not loadFile("Uedit/Spell/UdSupplement")) {
            if (not newFile) {
                putMsg("Close a file for me!")
                returnFalse
            }
            setFileName(curfile,"Uedit/Spell/UdSupplement")
        }
    }
    putMsg("Spell checking ... abort with Amiga-ESC")
    if (getFlag(curFile,searchCaps)) flipFlag(curFile,searchCaps)
label(0)
    while (not spell(" ",buf[n54],curFile)) {
        moveCursor(buf[n54],sWord)
        freeBuf(buf54)
        insertRgn(buf54,eFile,buf[n54],word)
        moveCursor(buf[n54],eWord)
        moveCursor(buf54,sFile)
        if (not is(buf54,"'") & not is(buf54,alpha)) goto label(0)
        moveCursor(buf54,eFile)
        putMsg(buf54)                              .. remove for faster speed

        ..  this sect for speed
        moveCursor(buf54,sFile)
        copyChar(buf54,n47)                          .. copy 1st char of word
        freeBuf(buf52)
        insertChar(buf52,eLine)                      .. load in eline-1stchar
        insertChar(buf52,n47)
        moveCursor(curFile,eFile)                .. search for starting place
        setSearch(buf52)
        search(curfile,locA,locB,-1)
        moveCursor(curFile,eWord)                 .. move fwd, so sWord works
        if (is(curFile,sFile)) goto label(1)
        while (nothing) {
            moveCursor(curFile,sWord)
            freeBuf(buf53)
            insertRgn(buf53,eFile,curFile,word)
            stringComp(n53,buf54,buf53,1)                      .. ignore case
            if (eqNum(n53,0)) goto label(0)             .. found it, continue
            if (gtNum(n53,0)) {
 label(1)
                moveCursor(curFile,eWord)
                moveCursor(curFile,eChar)
 label(2)
                insertRgn(curFile,atCursor,buf54,all)
                insertChar(curFile,eLine)
                updateDisplay                      .. remove for faster speed
                incNum(n99)
                if (gtNum(n99,19)) {
                    fileSize(curFile,n99)             .. force buffer packing
                    equateNum(n99,0)
                }
                goto label(0)
            }
            if (is(curFile,sFile)) goto label(2)
        }
    }
    moveCursor(curFile,sFile)
    putMsg("These words weren't in dictionary")
    .. stopSpell                               .. use if want speller removed
  >Thursday 13-Dec-90 18:16:13

Merge dict supplement with Uedit/Spell/dict.A-Z files.
<rAmiga-d:
    if (isEmpty(curFile)) returnFalse
    moveCursor(curFile,sFile)
    freeBuf(buf52)
    freeBuf(buf54)
    insertRgn(buf54,eFile,"Uedit/Spell/dict. ",all)
    if (getFlag(curFile,searchCaps)) flipFlag(curFile,searchCaps)
    equateNum(n50,0)
    while (nothing) {
        moveCursor(curFile,eWord)
        moveCursor(curFile,sWord)
        freeBuf(buf53)
        if (not insertRgn(buf53,eFile,curFile,word)) {
label(6)    if (getFlag(buf52,changed)) saveFile(buf52)
            runKey(104)                             .. force save to complete
            goto label(0)
        }
        moveCursor(buf53,sFile)
        toUpper(buf53)
        copyChar(buf53,n54)                    .. copy 1st letter of word A-Z
        toLower(buf53)
        if (eqNum(n54,39)) equateNum(n54,65)             .. apost becomes 'A'
        else {
            if (gtNum(n54,90)) goto label(1)                   .. must be A-Z
            if (gtNum(65,n54)) goto label(1)
        }
        moveCursor(buf54,eFile)
        moveCursor(buf54,sChar)
        swapChar(buf54,n54)                          .. make it "dict.A" etc.

        if (not eqNum(n54,n50)) {
            if (not eqNum(n50,0)
                & getFlag(buf52,changed)) saveFile(buf52)
            runKey(104)                             .. force save to complete
            clearRgn(buf52,all)
            fileSize(buf52,n49)                        .. make it pack buffer
            if (not insertFile(buf52,eFile,buf54)) {
                putMsg("Can't find dict.A-Z!")
                returnFalse
            }
            setFileName(buf52,buf54)
            if (getFlag(buf52,changed)) flipFlag(buf52,changed)
            equateNum(n50,n54)                            .. save dict-letter
        }
        .. put word in dict.
        moveCursor(buf53,eFile)
        putMsg(buf53)
        insertChar(buf53,eLine)
        moveCursor(buf52,eFile)
label(2)
        setSearch(buf53)
        if (search(buf52,locA,locB,-1)) {
            if (is(buf52,sWord)) goto label(1)
            goto label(2)                               .. continue searching
        }
        .. didn't find it.  Do the slow scan & insert the word.
        moveCursor(buf53,eFile)
        moveCursor(buf53,sChar)
        clearChar(buf53)                                      .. remove eLine
        moveCursor(buf52,eFile)
        equateNum(n49,1)
label(4)
        while (nothing) {
            if (eqNum(n49,1)) do(n48,1,40) moveCursor(buf52,sWord)
            moveCursor(buf52,sWord)
            freeBuf(buf51)
            insertRgn(buf51,eFile,buf52,word)
            stringComp(n53,buf53,buf51,1)                      .. ignore case
            if (eqNum(n53,0)) goto label(1)             .. found it, continue
            if (gtNum(n53,0)) {
                if (eqNum(n49,1)) goto label(5)
                moveCursor(buf52,eWord)
                moveCursor(buf52,eChar)
label(3)
                insertRgn(buf52,atCursor,buf53,all)
                insertChar(buf52,eLine)
                goto label(1)
            }
            if (is(buf52,sFile)) {
                if (eqNum(n49,1)) {
label(5)
                    equateNum(n49,0)
                    do (n48,1,41) moveCursor(buf52,eWord)
                    goto label(4)
                }
                goto label(3)
            }
        }

label(1) .. next word
        moveCursor(curFile,eLine)
        moveCursor(curFile,eChar)
        updateDisplay
        if (is(curFile,eFile)) goto label(6)
    }
label(0)
    putMsg("Done.  Run Udbuild to rebuild working dict & table")
    freeBuf(buf52)
   >Thursday 13-Dec-90 18:16:14

Remove words from Uedit/Spell/dict.A-Z files.
<rAmiga-e:
    if (isEmpty(curFile)) returnFalse
    moveCursor(curFile,sFile)
    freeBuf(buf52)
    freeBuf(buf54)
    insertRgn(buf54,eFile,"Uedit/Spell/dict. ",all)
    if (getFlag(curFile,searchCaps)) flipFlag(curFile,searchCaps)
    equateNum(n50,0)
    while (nothing) {
        moveCursor(curFile,eWord)
        moveCursor(curFile,sWord)
        freeBuf(buf53)
        if (not insertRgn(buf53,eFile,curFile,word)) {
label(6)
                if (getFlag(buf52,changed)) saveFile(buf52)
                runKey(104)                         .. force save to complete
                goto label(0)
        }
        moveCursor(buf53,sFile)
        toUpper(buf53)
        copyChar(buf53,n54)                    .. copy 1st letter of word A-Z
        toLower(buf53)
        if (eqNum(n54,"'")) equateNum(n54,"A")           .. apost becomes 'A'
        else {
            if (gtNum(n54,"Z")) goto label(1)                  .. must be A-Z
            if (gtNum(65,n54)) goto label(1)
        }
        moveCursor(buf54,eFile)
        moveCursor(buf54,sChar)
        swapChar(buf54,n54)                          .. make it "dict.A" etc.

        if (not eqNum(n54,n50)) {
            if (not eqNum(n50,0) & getFlag(buf52,changed)) saveFile(buf52)
            runKey(104)                             .. force save to complete
            clearRgn(buf52,all)
            fileSize(buf52,n49)                        .. make it pack buffer
            if (not insertFile(buf52,eFile,buf54)) {
                putMsg("Can't find Uedit/Spell/dict.A-Z!")
                returnFalse
            }
            setFileName(buf52,buf54)
            if (getFlag(buf52,changed)) flipFlag(buf52,changed)
            equateNum(n50,n54)                            .. save dict-letter
        }
        .. remove word from dict.
        moveCursor(buf53,eFile)
        putMsg(buf53)
        insertChar(buf53,eLine)
        moveCursor(buf52,eFile)
label(2)
        setSearch(buf53)
        if (search(buf52,locA,locB,-1)) {
            if (is(buf52,sWord)) {
                clearRgn(buf52,loc)
                goto label(1)                                    .. next word
            }
            goto label(2)                               .. continue searching
        }

label(1) .. next word
        moveCursor(curFile,eLine)
        moveCursor(curFile,eChar)
        if (is(curFile,eFile)) goto label(6)
        updateDisplay
    }
label(0)
    putMsg("Done.  Run Udbuild to rebuild working dict & table")
    freeBuf(buf52)
   >Thursday 13-Dec-90 18:16:15

Stop spell-checking mode.  (Frees up about 12k of memory.)
<rAmiga-f: 
   if (spellerUp) { stopSpell putMsg("Speller removed") } 
   >Thursday 13-Dec-90 18:16:15

Search for double cap (THe) errors.
<rAmiga-t:
   LABEL(0)
   putMsg("Searching for double caps, please wait....")
   while (!is(curFile,upperCase) & !is(curFile,eFile)) moveCursor(curFile,eChar)
   if (is(curFile,eFile)) {
      putMsg("Done")
      return }
   moveCursor(curFile,eChar)
   if (is(curFile,upperCase)) {
      putMsg(" ")
      if (askYesNo("Make lowerCase?    (NO=search for next)"))
            runKey(ctl-l)
      while(is(curFile,alpha) | is(curFile,digit)) 
         moveCursor(curFile,eChar) }
   goto label(0) 
   >Sunday 28-Jul-91 08:42:02

Search for sentence end spacing errors (single and triple space after ., ?, or !)
<rAmiga-space: 
   LABEL(0)  ..outer search loop
   putMsg("Searching for sentence ending errors, please wait....")
   LABEL(5)  ..inner search loop
   if (is(curFile,".") |
       is(curFile,"?") |
       is(curFile,"!")) goto label(6)
   if (is(curFile,eFile)) goto label(10)
   moveCursor(curFile,eChar)
   goto label(5)
   LABEL(6)  ..found .$?$!
   moveCursor(curFile,eChar)
   equateLoc(curFile,sHilite,atCursor)
   equateLoc(curFile,eHilite,atCursor)
   ..space, period, quote, right paren are okay
   ..alertUser("checking first char after .$?$!")..debug
   if (is(curFile,eLine)) goto label(0)
   if (is(curFile,eFile)) goto label(10)
   copyChar(curFile,n0)
   switch(n0) {
      case(" ") {                                                ..period-space
         moveCursor(curFile,eChar)
         ..space is okay
         ..alertUser("checking second char after .$?$!")..debug
         if (is(curFile,ctlChar) |
             is(curFile,eFile)) {                          ..period-space-eLine
            equateLoc(curFile,eHilite,atCursor)
            if (askYesNo("Delete hilighted space?    NO=skip")) {
                  runKey(normal-bs)
                  goto label(0) }
               else
                  goto label(0) }
         copyChar(curFile,n0)
         switch(n0) {
            case(" ") {                                    ..period-space-space
               moveCursor(curFile,eChar)
               equateLoc(curFile,locA,atCursor)
               ..only printable is okay
               while (is(curFile,space)) moveCursor(curFile,eChar)
               equateLoc(curFile,eHilite,atCursor)
               ..alertUser("checking nonspace char after .$?#!spaceSpace")..debug
               if (is(curFile,ctlChar)) {
                     ..alertUser("space-space-ctlChar")
                     if (askYesNo("Delete hilighed spaces    (NO=skip)"))
                         clearRgn(curFile,hilite) }
                  else {
                     ..alertUser("space-space-printable")
                     if (!eqLoc(curFile,locA,eHilite)) {
                        equateLoc(curFile,sHilite,locA)
                        if (askYesNo("Delete hilighed spaces    (NO=skip)"))
                            clearRgn(curFile,hilite) } } }
            default {                                  ..period-space-printable
               if (askYesNo("Insert a space here?    (NO=skip)")) {
                  insertRgn(curFile,atCursor," ",all)
                  if (askYesNo ("Stop to reformat paragraph?    (NO=skip)"))
                        returnTrue }
                     else
                        goto label(0) } } }
      case(".")                                                 ..period-period
      case("\"")                                                 ..period-quote
      case(")") {                                          ..period-close paren
         ..for any of these, treat as if just found a period
         goto label(6) }
      default {
         if(askYesNo("Insert two spaces here?    NO=skip")) {
            insertRgn(curFile,atCursor,"  ",all)
            if (askYesNo ("Stop to reformat paragraph?    (NO=skip)"))
                  returnTrue
               else
                  goto label(0) } } }
   goto label(0) 
   LABEL(10) ..end
   runKey(ctl-3)
   putMsg("Done")
   >Sunday 28-Jul-91 08:39:19