(welcome (message '\n\n\n\n\MAILDEMON 4.2 [SHAREWARE]\n\nCopyright © 18-Jan-1996 by\nMaik "BLiZZeR" Schreiber'))

(set #installmode
  (askchoice
    (prompt 'Welchen Installationsmodus wünschen Sie?')
    (choices 'Neuinstallation' 'Update von Version 4.1')
    (help @askchoice-help)
  )
)

(if (= #installmode 0)
  (
    (set #dummy @default-dest)
    (set #dest
      (askdir
        (prompt 'Wohin soll der MAILDEMON installiert werden? Ein Unterverzeichnis "MAILDEMON" wird automatisch erzeugt.')
        (help @askdir-help)
        (default #dummy)
        (disk)
      )
    )
    (set #dest (tackon #dest 'MAILDEMON'))
    (makedir #dest
      (prompt '\n\n\n\n\n\nMAILDEMON-Unterverzeichnis wird angelegt.')
      (infos)
      (confirm)
      (help @makedir-help)
    )
  )
  (set #dest 'MAILDEMON:')
)

(set #cpu
  (askchoice
    (prompt 'Welchen Prozessortyp benutzen Sie?')
    (choices '68000' '68020 oder höher')
    (help @askchoice-help)
  )
)

(run (cat 'Copy >NIL: MAILDEMON.guide ' #dest))

(if (= #installmode 0)
  (
    (makedir (tackon #dest 'Konfiguration')
      (prompt '\n\n\n\n\n\nUnterverzeichnis "Konfiguration" wird angelegt.')
      (confirm)
      (help @makedir-help)
    )
    (run (cat 'Copy >NIL: (Register.txt(|.info)|MAILDEMON.guide.info) ' #dest))
    (if (= #cpu 0)
      (run (cat 'Copy >NIL: 000/#? ' #dest))
      (
        (run (cat 'Copy >NIL: 000/#?.info ' #dest))
        (run (cat 'SPatch -o' (tackon #dest 'MAILDEMON') ' -p020+/MAILDEMON_020+.pch 000/MAILDEMON'))
        (run (cat 'SPatch -o' (tackon #dest 'MAILDEMON-Prefs') ' -p020+/MAILDEMON-Prefs_020+.pch 000/MAILDEMON-Prefs'))
        (run (cat 'SPatch -o' (tackon #dest 'Konfigkonverter') ' -p020+/Konfigkonverter_020+.pch 000/Konfigkonverter'))

      )
    )
    (startup 'MAILDEMON'
      (prompt '\n\n\n\n\nIn die User-Startup muß noch ein Assign eingefügt werden.')
      (command (cat 'Assign MAILDEMON: ' #dest))
      (help @startup-help)
    )
  )
  (
    (if (= #cpu 0)
      (run (cat 'Copy >NIL: 000/~(#?.info) ' #dest))
      (
        (run (cat 'SPatch -o' (tackon #dest 'MAILDEMON') ' -p020+/MAILDEMON_020+.pch 000/MAILDEMON'))
        (run (cat 'SPatch -o' (tackon #dest 'MAILDEMON-Prefs') ' -p020+/MAILDEMON-Prefs_020+.pch 000/MAILDEMON-Prefs'))
        (run (cat 'SPatch -o' (tackon #dest 'Konfigkonverter') ' -p020+/Konfigkonverter_020+.pch 000/Konfigkonverter'))

      )
    )
    (run (tackon #dest 'Konfigkonverter'))
  )
)

(message
  (cat 'ACHTUNG: Sollte der MAILDEMON oder der MAILDEMON-Prefs bei '
       'Ihnen sofort mit einer Systemmeldung abstürzen, probieren Sie '
       'bitte zuerst die andere Version (000/020+) aus, bevor Sie mich '
       'kontaktieren! Dies gilt für MAILDEMON und MAILDEMON-Prefs '
       '*unabhängig*!'
  )
)