/*
$VER: AmFTP2ATC Profilesconverter 1.3 (25.03.00)

** AmFTP-Profiles 2 ATC-Profiles
**
** 06.08.1999 (gelb) - Check auf anonymous eingebaut
**
** 20.02.2000 (ingo) - An neues .profiles format angepaßt
**
** 25.03.2000 (ingo) - VERSION 3 und ACTIVESERVER 0 eingefügt
**
*/


OPTIONS RESULTS

 tab=d2c(9)

 IF show('P','AMFTP.1') THEN
  DO
    ADDRESS 'AMFTP.1'
    GETHOSTS host
  END
 ELSE DO
  Say "AmFTP.1 not found!"
  Exit 10
 END

 DO I=1 TO 500
  IF POS('HOST.',host.i)~=0 THEN LEAVE
 END

 IF ~Open(NEW,'ram:ATC.Profiles',W) THEN
  DO
   Say 'Failed to open file!'
   Exit 10
  END

 WriteLn(NEW,'VERSION 3')
 WriteLn(NEW,'ACTIVESERVER 0')

 DO X=0 TO I-1
  GETPROFILE X OLD

  IF OLD.ANON=1 THEN /* 06.08.1999 */
    MODE=1
  ELSE IF OLD.ADT=1 THEN
    MODE=2
  ELSE
    MODE=0

  WriteLn(NEW,'SERVER '||OLD.HOST||tab||OLD.USERNAME||tab||OLD.PASSWORD||tab||OLD.PORT||tab||OLD.LABEL||tab||MODE||tab||3||tab||200||tab||OLD.LOCALDIR||tab||1||tab||OLD.DEFDIR||tab||1||tab||tab||0||tab||0||tab||0||tab||0||tab||0||tab||1||tab||0||tab||0)
 END

Close(NEW)

/*
0 host
1 login
2 password
3 port
4 comment
5 mode         0=l/p 1=anon 2=adt
6 tries
7 cpslimit     set to 200 (full speed)
8 localdir
9 savelocal    0=off 1=on
10 remotedir
11 saveremote  0=off 1=on
12 firstlogin  seconds since 01.01.1978
13 lastlogin   seconds since 01.01.1978
14 connects
15 logins
16 received
17 sent
18 adtmode
19 delay
20 adtdate    seconds since 01.01.1978
21 keepalive  0=off 1=on
22 files received
23 files sent
24 onlinetime seconds
25 usecache   0=off 1=on
26 max cps current
27 max cps average
28 use PASV   0=off 1=on
29 singlelist 0=off 1=on
30 dropcps    0 means off
31 dropsecs
32 droptries
33 dropignore
34 ADT keepdirtree  0=off 1=on
35 suppressadtlogin 0=off 1=on
36 showmotd         0=off 1=on
37 ADT getreadme    0=off 1=on
38 last ADT-MOTD date
*/