; Installation script for MFormat 1.8a
; $VER:Install_MFormat 1.1 (21.5.95)
; By Eric Sauvageau.
;
; 1.1: now able to deal with already existing format.old (in case it wasn't
;      removed since last Install)
;      Wasn't copying the icon with the backup.

ECHO ""
ECHO "*e[1m*e[4mMFormat 1.8a Installation script*e[22;24m"
ECHO ""

ASK "Do you wish to install it over the original Commodore Format *e[1m[y/N]*e[22m ?"

IF WARN
   Set MFormatName "Format"

   IF EXISTS SYS:System/Format
      
      ECHO ""
      ECHO "*e[1mDoing a backup of SYS:System/Format as SYS:System/Format.old..." NOLINE

      IF EXISTS SYS:System/Format
         Copy >NIL: SYS:System/Format SYS:System/Format.old
      ENDIF

      IF EXISTS SYS:System/Format.info
         Copy >NIL: SYS:System/Format.info SYS:System/Format.old.info
      ENDIF

      ECHO " done.*e[22m"
   ENDIF
ELSE
   ECHO ""
   Set MFormatName "MFormat"
ENDIF

ECHO "*e[1mInstalling MFormat as 'SYS:System/$MFormatName'..." NOLINE

Copy MFormat SYS:System/$MFormatName QUIET

ECHO " done.*e[22m"

IF $MFormatName EQ "Format"
   ECHO ""
   ASK "Keep your current Format icon *e[1m[y/N]*e[22m ?"
   IF WARN
      SKIP End
   ENDIF
ENDIF

ECHO ""
ECHO "Do you wish to use the supplied 8 colors icon instead of"

ASK  "the 4 colors icon *e[1m[y/N]*e[22m ?"

IF WARN
   ECHO ""
   ECHO "*e[1mCopying 8_colors_icon/MFormat.info icon..." NOLINE
   Copy 8_colors_icon/MFormat.info SYS:System/$MFormatName.info
ELSE
   ECHO ""
   ECHO "*e[1mCopying MFormat.info icon..." NOLINE
   Copy MFormat.info SYS:System/$MFormatName.info
ENDIF

ECHO " done.*e[22m"

LAB end

ECHO ""
ECHO ""
ECHO "*e[1mInstallation completed!*e[22m"
ECHO ""
ECHO "MFormat is now in the '*e[1mSystem/*e[22m' drawer of your boot partition as *e[1m$MFormatName*e[22m."
ECHO ""

unset MFormatName