שתשת                                        
		INCDIR	INCLUDES:
		INCLUDE	intuition/intuition.i


		INCLUDE	exec.offs
		INCLUDE	intuition.offs
		INCLUDE	graphics.offs

ActiveScreen	equ	56
ExecBase	equ	4


Intuition_Base	equ	4
Graphics_Base	equ	8
Window_Base	equ	12

		lea	bazy(pc),a5
		lea	IntuitionName(pc),a1
		bsr	OpenLibrary
		move.l	d0,Intuition_Base(a5)
		beq	exit
		lea	GraphicsName(pc),a1
		bsr	OpenLibrary
		move.l	d0,Graphics_Base(a5)
		beq	exit1
		lea	windowdef(pc),a0
		move.l	Intuition_Base(a5),a6
		move.l	ActiveScreen(a6),nw_Screen(a0)
		jsr	_LVOOpenWindow(a6)
		move.l	d0,Window_Base(a5)		
		beq	exit2

		move.l	d0,a0
		move.l	wd_RPort(a0),a0
		lea	RD01_R(pc),a1
		moveq	#8,d0
		moveq	#13,d1
		jsr	_LVODrawBorder(a6)		


		move.l	Window_Base(a5),a0
		move.l	wd_UserPort(a0),a0
		move.b	MP_SIGBIT(a0),d1
		moveq	#1,d0
		lsl.l	d1,d0
		move.l	[ExecBase].w,a6
		jsr	_LVOWait(a6)	
		move.l	Window_Base(a5),a0
		move.l	Intuition_Base(a5),a6
		jsr	_LVOCloseWindow(a6)
exit2		move.l	Graphics_Base(a5),a1
		bsr	CloseLibrary
exit1		move.l	Intuition_Base(a5),a1
		bsr	CloseLibrary
exit		rts		

OpenLibrary	moveq	#0,d0
		move.l	[ExecBase].w,a6
		jmp	_LVOOpenLibrary(a6)
CloseLibrary	move.l	[ExecBase].w,a6
		jmp	_LVOCloseLibrary(a6)
;
bazy		blk.l	10,0

IntuitionName	dc.b	'intuition.library',0
		even
GraphicsName	dc.b	'graphics.library',0
		even

windowdef	dc.w	0,0			;LeftEdge/TopEdge
		dc.w	236,66			;Width/Height
		dc.b	0,1			;DetailPen/BlockPen
		dc.l	CLOSEWINDOW		;IDCMPFlags
		dc.l	WINDOWDRAG!WINDOWDEPTH!WINDOWCLOSE!SIZEBBOTTOM!NOCAREREFRESH
			;Flags
		dc.l	STRGadget_00,0			;FirstGadget/CheckMark
		dc.l	windowname		;Title	
		dc.l	0,0			;Screen/BitMap
		dc.w	0,0			;MinWidth/MinHeight
		dc.w	0,0			;MaxWidth/MaxHeight
		dc.w	$f			;Type

windowname	dc.b	'Login Window',0,0		

SG01_SX		equ	96
SG01_SY		equ	8

STRGadget_00	dc.l	STRGadget_01
		dc.w	20,19,SG01_SX,SG01_SY
		dc.w	GFLG_GADGHCOMP+GFLG_STRINGEXTEND
		dc.w	GACT_IMMEDIATE+GACT_RELVERIFY+GACT_ALTKEYMAP
		dc.w	GTYP_STRGADGET
		dc.l	SG01_R,0,SG00_IT,0,SG01_SI
		dc.w	0
		dc.l	0

STRGadget_01	dc.l	BUTGadget_00
		dc.w	20,19+SG01_SY+7,SG01_SX,SG01_SY
		dc.w	GFLG_GADGHCOMP+GFLG_STRINGEXTEND
		dc.w	GACT_IMMEDIATE+GACT_RELVERIFY+GACT_ALTKEYMAP
		dc.w	GTYP_STRGADGET
		dc.l	SG01_R,0,SG01_IT,0,SG01_SI
		dc.w	0
		dc.l	0

BUTGadget_00	dc.l	BUTGadget_01
		dc.w	8,20+(SG01_SY+7)*2,BG01_SX,BG01_SY
		dc.w	GFLG_GADGHCOMP
		dc.w	GACT_RELVERIFY+GACT_IMMEDIATE
		dc.w	GTYP_BOOLGADGET
		dc.l	BG01_R,0,BG00_IT,0,0
		dc.w	0
		dc.l	0
BUTGadget_01	dc.l	0
		dc.w	26+BG01_SX+74,20+(SG01_SY+7)*2,BG01_SX,BG01_SY
		dc.w	GFLG_GADGHCOMP
		dc.w	GACT_RELVERIFY+GACT_IMMEDIATE
		dc.w	GTYP_BOOLGADGET
		dc.l	BG01_R,0,BG01_IT,0,0
		dc.w	0
		dc.l	0


SG01_SI		dc.l	SI_B
		dc.l	0,31,0,0,0,SI_E,0,0

SI_B		blk.b	40,0

SI_E		dc.l	0
		dc.b	1,0
		dc.b	1,0
		blk.b	28,0

SG01_R		dc.w	0,0
		dc.b	$02,00,RP_JAM1,10
		dc.l	SG01_RXYW,SG01_RB

SG01_RB		dc.w	0,0
		dc.b	$01,00,RP_JAM1,10
		dc.l	SG01_RXYB,0

SG01_RXYB	dc.w	-5,SG01_SY+2,SG01_SX+5,SG01_SY+2,SG01_SX+5,-3,SG01_SX+4,-2
		dc.w	SG01_SX+4,SG01_SY+2,-4,SG01_SY+2,-4,-2,SG01_SX+2,-2,-3,-2
		dc.w	-3,SG01_SY

SG01_RXYW	dc.w	SG01_SX+4,-3,-6,-3,-6,SG01_SY+2,-5,SG01_SY+1,-5,-3
		dc.w	SG01_SX+3,-3,SG01_SX+3,SG01_SY+1,-3,SG01_SY+1,SG01_SX+2,SG01_SY+1
		dc.w	SG01_SX+2,-1
BG01_SX		equ	64
BG01_SY		equ	12


BG01_R		dc.w	0,0
		dc.b	$01,00,RP_JAM1,5
		dc.l	BG01_XYW,BG01_RB

BG01_RB		dc.w	0,0
		dc.b	$02,00,RP_JAM1,5
		dc.l	BG01_XYB,0

RD01_R		dc.w	0,0
		dc.b	$02,00,RP_JAM1,5
		dc.l	RD01_XYW,RD01_RB

RD01_RB		dc.w	0,0
		dc.b	$01,00,RP_JAM1,5
		dc.l	RD01_XYB,0


BG01_XYB	dc.w	0,BG01_SY-1,0,0,BG01_SX-2,0,1,0,1,BG01_SY-2

BG01_XYW	dc.w	BG01_SX-1,0,BG01_SX-1,BG01_SY-1,1,BG01_SY-1
		dc.w	BG01_SX-2,BG01_SY-1,BG01_SX-2,1


RD01_SY		equ	35
RD01_SX		equ	220

RD01_XYB	dc.w	0,RD01_SY-1,0,0,RD01_SX-2,0,1,0,1,RD01_SY-2

RD01_XYW	dc.w	RD01_SX-1,0,RD01_SX-1,RD01_SY-1,1,RD01_SY-1
		dc.w	RD01_SX-2,RD01_SY-1,RD01_SX-2,1



BG00_IT		dc.b	01,00,RP_JAM2,00
		dc.w	12,3-1
		dc.l	fontatr,BGIT00_S,0

BG01_IT		dc.b	01,00,RP_JAM2,00
		dc.w	8,3-1
		dc.l	fontatr,BGIT01_S,0

SG00_IT		dc.b	01,00,RP_JAM2,00
		dc.w	SG01_SX+9,0
		dc.l	fontatr,SGIT00_S,0

SG01_IT		dc.b	01,00,RP_JAM2,00
		dc.w	SG01_SX+9,0
		dc.l	fontatr,SGIT01_S,0


fontatr		dc.l	FN_S
		dc.w	8
		dc.b	FSF_UNDERLINED
		dc.b	FPF_DISKFONT+FPF_DESIGNED


BGIT00_S	dc.b	'Login',0
BGIT01_S	dc.b	'Cancel',0
SGIT00_S	dc.b	'User Name',0
SGIT01_S	dc.b	'Password',0
FN_S		dc.b	'topaz',0

