; Install PFConverrt
; $VER: Install-PFConvert V1.0 (3.5.2000)
; © 2000 Steeple Software

(set #catalog 0) ; english language is default

; Find the current language
(set #i 0)
(while (set #thisfile (select #i
		"english" "italiano" "deutsch" "español" "czech" "français" "català" "dansk"
		"hrvatski" "nederlands" "norsk" "polski" "português"
		"russian" "srpski" "suomi" "svenska" "ÃeÓtina"
		""))
	(
		(if (= @language #thisfile)
			(
				(set #catalog #i)
				(set #catalogname #thisfile)
			)
		)
		(set #i (+ #i 1))
	)
)

; Query user for their language, using system as default
(set #catalog
	(askchoice
		(prompt "Select your native language (language for installer)")
		(help @askoptions-help)
		(choices "English" "Italiano" "Deutsch" "Español" "Czech")
		(default #catalog)
	)
)

; Reset #catalogname as the user may have changed the language above
(if (< #catalog 5)
	(
		(set #catalogname (select #catalog "english" "italiano" "deutsch" "español" "czech"))
	)
)

; Some string defaults common for all languages
(set #HOMEPAGE "http://mafeking.scouts.org.au/photofolio")
(set #BLANK "\n")


; ************************** English texts ******************************
(set #INITIAL_MESSAGE
  (cat "\nWelcome to the PFConvert installer\n\n\n"
	"You can obtain updates and other information\nabout PFConvert from the homepage\n\n"
	#HOMEPAGE)
)
(set #WRONG_INSTALLER_VERSION "\n\n\n\nYou need at least version 42.9 of Installer\nto install PFConvert")
(set #WRONG_CPU "\n\n\n\nYou need a 68020 CPU or better\nto use PFConvert")
(set #WRONG_OS_VERSION "\n\n\n\nYou need at least AmigaOS V2.0\nto use PFConvert")
(set #INSTALLING_PROGRAM "\n\n\n\nInstalling PFConvert program")
(set #PROMPT_INSTALL_DOCS "\nInstall PFConvert documentation?")
(set #INSTALLING_DOCS "\nInstalling PFConvert documentation")
(set #PROMPT_INSTALL_CATALOG "\nWhich language catalogs would you like to install?")
(set #INSTALLING_CATALOG "\nInstalling catalog")
(set #UPDATES_AVAILABLE "\nYou can get the latest version\nof PFConvert from the homepage")
(set #YES "Yes")
(set #NO "No")

; ************************** Italiano texts *****************************
(if (= #catalog 1)
(
(set #INITIAL_MESSAGE
  (cat "\nBenvenuto nell'installazione di PFConvert\n\n\n"
     "Puoi ottenere gli aggiornamenti, la mailing list e altre informazioni\nsu PFConvert alla homepage\n"
     #HOMEPAGE)
)
(set #WRONG_INSTALLER_VERSION "\n\n\n\nNecessiti almeno della versione 42.9 dell'Installer\nper installare PFConvert")
(set #WRONG_CPU "\n\n\n\nNecessiti di una CPU 68020 o superiore\nper usare PFConvert")
(set #WRONG_OS_VERSION "\n\n\n\nNecessiti almeno di AmigaOS V2.0\nper usare PFConvert")
(set #INSTALLING_PROGRAM "\n\n\n\nInstallazione programma PFConvert in corso")
(set #PROMPT_INSTALL_DOCS "\nInstalla documentazione PFConvert?")
(set #INSTALLING_DOCS "\nInstallazione documentazione PFConvert in corso")
(set #PROMPT_INSTALL_CATALOG "\nQuale catalogo della lingua desideri installare?")
(set #INSTALLING_CATALOG "\nInstallazione catalogo ImageIOLibraryPrefs")
(set #UPDATES_AVAILABLE "\nAggiornamenti di PFConvert e le librarie richieste\n\nsono disponibili sulla home page")
(set #YES "Sì")
(set #NO "No")
)
)

; ************************** Deutsch texts ******************************
(if (= #catalog 2)
(
(set #INITIAL_MESSAGE
  (cat "\nWillkommen zur Installation von PFConvert\n\n\n"
    "Updates, und weitere Information\nüber PFConvert gibt es auf der Homepage\n"
    #HOMEPAGE)
)
(set #WRONG_INSTALLER_VERSION "\n\n\n\nSie benötigen mind. Version 42.9 des Installers\num PFConvert zu installieren")
(set #WRONG_CPU "\n\n\n\nSie benötigen einen 68020 oder höher\num PFConvert ausführen zu können")
(set #WRONG_OS_VERSION "\n\n\n\nSie benötigen mind. AmigaOS V2.0\num PFConvert ausführen zu können")
(set #INSTALLING_PROGRAM "\n\n\n\nPFConvert Programm wird installiert")
(set #PROMPT_INSTALL_DOCS "\nPFConvert Dokumentation installieren?")
(set #INSTALLING_DOCS "\nPFConvert Dokumentation wird installiert")
(set #PROMPT_INSTALL_CATALOG "\nWelche Sprachen wollen Sie installieren?")
(set #INSTALLING_CATALOG "\nImageIOLibraryPrefs Sprachdatei wird installiert")
(set #UPDATES_AVAILABLE "\nUpdates für PFConvert und den dazugehörigen libraries\n\ngibt es auf der Homepage")
(set #YES "Ja")
(set #NO "Nein")
)
)

; ************************** Español texts ******************************
(if (= #catalog 3)
(
(set #INITIAL_MESSAGE
  (cat "\nBienvenido a la instalación de PFConvert\n\n\n"
	"Podrás obtener actualizaciones, acceder a listas de correo y tener más información\nsobre PFConvert en la página web de Homepage\n"
	#HOMEPAGE)
)
(set #WRONG_INSTALLER_VERSION "\n\n\n\nNecesitas al menos la versión 42.9 del Installer\npara instalar PFConvert")
(set #WRONG_CPU "\n\n\n\nNecesitas un 68020 o superior\npara utilizar PFConvert")
(set #WRONG_OS_VERSION "\n\n\n\nNecesitas al menos AmigaOS V2.0\npara utilizar PFConvert")
(set #INSTALLING_PROGRAM "\n\n\n\nInstalando el programa PFConvert")
(set #PROMPT_INSTALL_DOCS "\n¿Instalo la documentación de PFConvert?")
(set #INSTALLING_DOCS "\nInstalando la documentación de PFConvert")
(set #PROMPT_INSTALL_CATALOG "\n¿Qué catalogos (lenguajes) quieres instalar?")
(set #INSTALLING_CATALOG "\nInstalando catálogo de ImageIOLibraryPrefs")
(set #UPDATES_AVAILABLE "\nLas actualizaciones de PFConvert y librerías necesarias\n\nestán disponibles en la página web de homepage")
(set #YES "Sí")
(set #NO "No")
)
)

; ************************** Czech texts ******************************
(if (= #catalog 4)
(
(set #INITIAL_MESSAGE
  (cat "\nVítejte pêi instalaci programu PFConvert!\n\n\n"
	"Dalîí informace, kontakt na ostatní uùivatele a aktualizace\nmûùete zdarma získat staùením z domovské stránky\n"
	#HOMEPAGE)
)
(set #WRONG_INSTALLER_VERSION "\n\n\n\nK instalaci programu PFConvert\npotêebujete Installer V42.9 nebo vyîîí")
(set #WRONG_CPU "\n\n\n\nKe spuîtëní programu PFConvert\npotêebujete alespoñ CPU68020 nebo lepîí")
(set #WRONG_OS_VERSION "\n\n\n\nProgram PFConvert vyùaduje\nke spuîtëní AmigaOS V2.0")
(set #INSTALLING_PROGRAM "\n\n\n\nInstalace programu PFConvert")
(set #PROMPT_INSTALL_DOCS "\n\n\n\nChcete nainstalovat dokumentaci?\n\n(Amigaguide)")
(set #INSTALLING_DOCS "\n\n\n\nInstalace dokumentace programu PFConvert")
(set #PROMPT_INSTALL_CATALOG "\nKterý z pêekladû chcete nainstalovat?")
(set #INSTALLING_CATALOG "\nInstalace pêekladu programu ImageIOLibraryPrefs")
(set #UPDATES_AVAILABLE "\n\nAktualizace programu PFConvert a pêísluîných\n\nknihoven jsou dostupné z domovské stránky")
(set #YES "Ano")
(set #NO "Ne")
)
)


; *********************** PFConvert install

(if (< @installer-version (+ (* 65536 42) 9))
	(abort #WRONG_INSTALLER_VERSION)
)

(if (< (database "cpu") 68020 )
	(abort #WRONG_CPU)
)

(set os_version (/ (getversion "exec.library" (resident)) 65536))
(if (< os_version 37)
	(abort #WRONG_OS_VERSION)
)

; All essential version numbers are correct, continue installation
(message #INITIAL_MESSAGE)

; *********************** Set destination directory

; Set destination directory for install
(set destination
	(askdir
		(prompt #SELECT_INSTALL_DIRECTORY)
		(help @askdir-help)
		(default @default-dest)
	)
)

(set @default-dest destination)


(complete 0)

; *********************** Install main program and icon

; Install executable and icon
(copyfiles
	(prompt #INSTALLING_PROGRAM)
	(source "")
	(choices "PFConvert" "PFConvert.info")
	(help @copyfiles-help)
	(dest @default-dest)
	(files)
	(noposition)
	(optional askuser)
)

(complete 30)

; *********************** Install documentation

(if (=
	(askchoice
		(help @askchoice-help)
		(prompt #PROMPT_INSTALL_DOCS)
		(choices #YES #NO)
		(default 0)
	)	0 )
	(
		(set #doclangfound -1) ; Flags if the docs were found in their language

		(set #i 0)
		(while (set #thiscat (select #i "English" "-" "Deutsch" "-" "-" ""))
			(
				(if (= #i #catalog)
					(
						(if (<> #thiscat "-")
							(
								(set #doclangfound #catalog)
							)
						)
					)
				)
				(set #i (+ #i 1))
			)
		)

		(if (<> #doclangfound -1)
			(
				(set #docs (tackon "Documentation" (select #catalog "English" "Italiano" "Deutsch" "Español")))
				(copyfiles
					(prompt #INSTALLING_DOCS)
					(choices "PFConvert.guide" "PFConvert.guide.info")
					(source #docs)
			    (help @copyfiles-help)
					(dest @default-dest)
					(files)
					(noposition)
					(optional askuser)
					(confirm)
				)
			)
			(
				; Havent got their language, install English instead
				(copyfiles
					(prompt #INSTALLING_DOCS)
					(choices "PFConvertguide" "PFConvert.guide.info")
					(source "Documentation/English")
			    (help @copyfiles-help)
					(dest @default-dest)
					(files)
					(noposition)
					(optional askuser)
					(confirm)
				)
			)
		)
	)
)


(complete 60)

; *********************** Install locale catalog

(set #localedest "LOCALE:Catalogs")

(if (<> #catalog 0)
	(
		(set #localesrc 1) ; Defaults to first entry
		(set #i 0)
		(while (set #thiscat (select #i "italiano" "deutsch" "español" "czech" ""))
			(
				(if (= #catalogname #thiscat)
					(
						(set #x #i)
						(while (> #x 0)
							(set #localesrc (* #localesrc 2))

							(set #x (- #x 1))
						)
					)
				)

				(set #i (+ #i 1))
			)
		)
	)
	(
		(set #localesrc 0)
	)
)

(set #installcat
	(askoptions
		(prompt #PROMPT_INSTALL_CATALOG)
		(choices "Italiano" "Deutsch" "Español" "Czech" "Français")
		(default #localesrc)
		(help @askoptions-help)
	)
)

(set #i 0)
(while (< #i 5)
	(set #x #i)
	(set #y 1)

	(while (> #x 0)
		(set #y (* #y 2))

		(set #x (- #x 1))
	)

	(if (bitand #installcat #y)
		(
			(set #localecat (select #i "Italiano" "Deutsch" "Español" "Czech" "Français"))

			(copyfiles
				(prompt (cat (cat #INSTALLING_CATALOG " " ) #localecat))
				(help @copyfiles-help)
				(source (tackon "catalogs" #localecat))
				(choices "PFConvert.catalog")
				(dest (tackon #localedest #localecat))
				(confirm)
				(optional askuser)
				(files)
			)
		)
	)

	(set #i (+ #i 1))
)

(complete 100)

; *********************** Finished installation

(message (cat #UPDATES_AVAILABLE #BLANK #BLANK #HOMEPAGE))