/* Centrage de la référence et de la valeur d'un composant.
Version 1.00: 11 août 1998
Version 1.01: 13 avril 2000 (modif gestion SAVEALL, OBJECTS)
$VER: Centrer.AmiCAD 1.01, © R.Florac, 13 avril 2000 */

options results

signal on error
signal on syntax

nc=0; objet=1
'SAVEALL:OBJECTS'; objets=result
do while objet>0
    'O=FINDOBJ('objet',1,-1,-1)'; objet=result
    if objet>0 then do
	'TEST(O)'
	if result>0 then do
	    nc=nc+1
	    call centrer(objet)
	end
	objet=objet+1
	if objet>objets then objet=0
    end
end

if nc=0 then do
    'PICKOBJ("Cliquez sur l''objet à arranger")'
    objet=result
    if objet <= 0 then exit
    call centrer(objet)
end

exit

centrer: procedure
    parse arg o
    'GETPOS(O='o')'; p=result
    'R=GETREF(O)'
    if result>0 then do
	if p=1 | p=3 then do
	    'MOVE(R,0,LINE(O)-LINE(R)+(HEIGHT(O)+HEIGHT(R))/2)'
	end
	else do
	    'MOVE(R,COL(O)-COL(R)+(WIDTH(O)-WIDTH(R))/2,0)'
	end
    end
    'V=GETVAL(O)'
    if result>0 then do
	if p=1 | p=3 then do
	    'MOVE(V,0,LINE(O)-LINE(V)+(HEIGHT(O)+HEIGHT(V))/2)'
	end
	else do
	    'MOVE(V,COL(O)-COL(V)+(WIDTH(O)-WIDTH(V))/2,0)'
	end
    end
return

/* Traitement des erreurs, interruption du programme */
syntax:
erreur=RC
'MESSAGE("Script Centrer.AmiCAD"+CHR(10)+"Erreur de syntaxe"+CHR(10)+"en ligne 'SIGL'"+CHR(10)+"'errortext(erreur)'")'
exit

error:
'MESSAGE("Script Centrer.AmiCAD"+CHR(10)+"Erreur en ligne 'SIGL'")'
exit