/* Here you get an overview about your fonts
 © Heiko Schröder / 08/07/97 / Mail: age@thepentagon.com */

Address='FinalW'
Options results

STATUS PORTNAME
FW = result
address = FW

SIGNAL ON BREAK_C

'ShowMessage 2 0 "FontLook - Auto V2.80" "for Font-Directories..." "(©) Heiko Schröder - 08/07/97" ":-)" "Ok" "(-:"'
'ShowMessage 1 1 "A T T E N T I O N !" "The macro needs an empty document." "Clear the document?" "Yes" "Abort" ""'
if result=2 then call BREAK_C
Cleardoc Force

'ShowMessage 2 0 "codes or layout" "" "" "codes" "layout" ""'
cl=result
'ShowMessage 2 0 "Screen output?" "" "" "normal" "speed" ""'
ba=result

/*----- REXXREQTOOLS -----*/

Temp = "ram:fonts.info"
if ~show('L',"rexxreqtools.library") then do
   if ~addlib('rexxreqtools.library',0,-30,0) then do
      'ShowMessage 1 1 "Error...." "I need the RexxReqTools.library" " E N D ! !" "Okay" "" ""'
      exit
   end
end

dir=rtfilerequest("FWFonts/SWOLFonts/",,"Select a directory...",,"rt_pubscrname=FinalWriterPubScreen rtfi_flags = freqf_nofiles")
if dir="" then do
   'ShowMessage 1 1 "No directory selected!" " E N D ! !" "" "Okay" "" ""'
   exit
end
dir=d2c(34)||dir||d2c(34)
address command 'list ' dir || ' to=' Temp || ' files lformat "%s%s"'

if OPEN('file',Temp,"R") then
If Seek("file",0,"E")=0 then do
   'ShowMessage 1 1 "Directory is empty!" " E N D ! !" "" "Okay" "" ""'
   address "REXX"
   close("file")
   EXIT
end

address "REXX"
close("file")
address command 'sort ' Temp Temp
OPEN('file',Temp, "R")

address(FW)
'ShowMessage 1 0 "Do you need perforation signs?" "" "" "Yes" "No" ""'
lm=result
'ShowMessage 1 0 "Whats next?" "" "" "save" "save + print" "print"'
wgw=result

/*Minimize window*/
IF ba=2 THEN DO
   status WINDOW
   parse VAR result links oben breite hoehe minbreite minhoehe . /**/
   sizewindow minbreite minhoehe /**/
End

/*---------------------------*/

DO WHILE 1
	FullFontName=ReadLn('file')
	IF EOF('file') THEN do
      address "REXX"
      close('file')
      call Ende
   End

 If (Lastpos(".info",FullFontName)=0 & Lastpos(".otag",FullFontName)=0 & Lastpos(".type",FullFontName)=0 & Lastpos(".afm",FullFontName)=0 & Lastpos(".lib",FullFontName)=0) then do

   GetDocItemPrefs Decimal
   Punkt=Result
   If Punkt="Comma" then DocItemPrefs Decimal Period

   TextTool
   Font FullFontName
   a=RC
   If a=0 then do                  /* Font?*/
      Type d2c(32)
      BackSpace
      status FontPath
      FullFontName=result

      pos = max(index(FullFontName,':'),lastpos('/',FullFontName))
      IF (pos~=0) THEN ShortFontName=RIGHT(FullFontName, LENGTH(FullFontName)-pos)
      else ShortFontName=FullFontName

      IF ba=2 THEN View 20

      GraphicTool

      Pagesetup Pagetype A4 Orient Tall Top 0 Bottom 2.54 Left 0 Right 0
      SectionSetup Top 2.54 Bottom 2.54 Inside 2 Outside 1
      LinePrefs LineWt .5
      DrawLine 1 2 3.5 20 3.5
      DrawLine 1 2 26 20 26
      If lm=1 then DrawLine 1 0.5 14.85 1 14.85

      TextTool
      If cl=1 then do

         Do i=0 to 13
            SetTab i*1.3+0.8 Right
         End
   
         NameFont="FWDocs/Codes-" || ShortFontName
         Justify Center
         Font Softsans
         FontSize 18
         Type FullFontName; NewParagraph; NewParagraph

         DO a=33 BY 14 FOR 16

            Font Softsans
            FontSize 8
            zeile = ""
            DO x = a TO a + 13 WHILE x < 256
               zeile = zeile || d2c( 9 ) || x || d2c( 32 ) || d2c( x )
            END

            If x = 256 then zeile = zeile || d2c( 9 )
            Type zeile; NewParagraph

            Font FullFontName
            FontSize 24
            zeile = ""
            DO x = a TO a + 13 WHILE x < 256
               zeile = zeile || d2c( 9 ) || d2c( x )
            END

            If x = 256 then zeile = zeile || d2c( 9 )
            Type zeile; NewParagraph

         END

         FontSize 12
         Type d2c(9); NewParagraph
         Font Softsans

         FontSize 8
         Justify Right
         Type Date(O)" - "FullFontName

      END

      If cl=2 then do

         Justify Center
         NameFont="FWDocs/Layout-" || ShortFontName
         Font Softsans
         FontSize 18
         Type ShortFontName; NewParagraph

         Justify Left
         Font FullFontName
         FontSize 8
         NewParagraph; Type "This is 8-point type - not easy to read!"; NewParagraph

         FontSize 9
         Type "9-Point type is about the smallest readable size."; NewParagraph

         FontSize 10
         Type "With 10-point type, we have a normal text size."; NewParagraph

         FontSize 12
         Type "With some fonts, 12-point type is easier to read."; NewParagraph

         FontSize 14
         Type "14-point type is good for subheadings."; NewParagraph

         FontSize 16
         Type "For larger subheadings, try 16-point type."; NewParagraph

         FontSize 18
         Type "18-point type makes nice small headlines."; NewParagraph

         FontSize 24
         Type "24-point type is for medium headlines."; NewParagraph

         FontSize 36
         Type "36-point is for larger ones."; NewParagraph

         FontSize 48
         Type "48-point almost shouts!"; NewParagraph

         FontSize 60
         Type "60-point is huge!"; NewParagraph

         FontSize 12
         Font SoftSans
         Type d2c( 32 ); NewParagraph
         NewParagraph; Type "NORMAL"; NewParagraph

         FontSize 10
         Font FullFontName
         Type "ABCDEFGHIJKLMNOPQRSTUVWXYZ"; NewParagraph
         Type "abcdefghijklmnopqrstuvwxyz 1234567890 !@#$%^&*()-+=[]{}/:;,.?"; NewParagraph
         Type "The quick brown fox jumps over the lazy dog."; NewParagraph; NewParagraph; NewParagraph

         Font SoftSans
         Type "EXTENDED CHARACTERS"; NewParagraph

         FontSize 10
         Font FullFontName
         DO j = 128 BY 32 FOR 4 /* MiK */
            Type XRange( d2c( j ), d2c( j + 31 ) ); NewParagraph /* MiK */
         End
         Status BodyTextHeight
         th=result
         FG=26.24-2.113-th
         FG=Trunc(FG*8/0.34)
         FontSize FG
         Type d2c(9)
         Font SoftSans
         FontSize 8
         NewParagraph
         Justify Right
         Type Date(O)" - "FullFontName
      End

      call VH

      /* save */
      If wgw~=3 then 
         Save NameFont

      /* Save+print */
      If wgw=2 then 
         Print

      /* Nur print */
      If wgw=3 then
         Print

      Cleardoc force
   END
   else do
      call VH
      'ShowMessage 1 1 "FW cant display this font..." "Its a non-FW-font..." "" "Okay" "" ""'
   end
 end
END

Ende:
   address(FW)
   Call VH

   If cl=1 then 'ShowMessage 2 1 "You can find the documents in the FWDocs-Drawer." "Recognizable on «Codes-.....«" "Thanx for use." "@-`-" "Please" ":-))"'
   If cl=2 then 'ShowMessage 2 1 "You can find the documents in the FWDocs-Drawer." "Recognizable on «Layout-.....«" "Thanx for use." "@-`-" "Please" ":-))"'
   'ShowMessage 2 1 "© Heiko Schröder" "email: age@thepentagon.com" "http://yi.com/home/SchroederHeiko" "Okay" "Yes" ":-))"'
   Call SH

   Address command "delete ram:fonts.info QUIET"

   EXIT

BREAK_C:
   call VH

   'ShowMessage 1 1 "Macro aborted..." "" "" "I know..." "" ""'

   call SH
   address "REXX"
   CLOSE("file")
   Address command "delete ram:fonts.info QUIET"
   EXIT

VH:
If ba=2 then View
Return

SH:
If ba=2 then do
   SizeWindow breite hoehe
   If Punkt="Comma" then DocItemPrefs DECIMAL Comma
end
Return