;======================================================================
;
;
; script d'installation pour TEXTIMAGES 4.03
;
;
; crée systématiquement un nouveau répertoire Textimages_4.03
; pour y copier le contenu de la disquette originale
; si un précédent tiroir Textimages_4.03 existe, la permission
; d'effacer sera demandée
;
; les tooltypes DEFTOOL des icônes PEINDRE et CONVERT24 voient enfin
; leur valeur modifiée
;
;
;================ nouveau tiroir et copie des fichiers ===============


(set @app-name     "Textimages_4.03")
(set @default-dest "Work:")

(set @default-dest
     (askdir (prompt  "")
             (help    @askdir-help)
             (default @default-dest)))

(set #outputdir (tackon @default-dest @app-name))


(if (exists #outputdir)
    (
      (set #deletion
            (askbool (prompt ("\n%s already exists.\n\nOK to erase it ?" @app-name))
                     (default 0)
                     (help ("\n%s is already installed." @app-name)
                            "\nClick 'Yes' to continue and erase it."
                            "\nClick 'No' to abandon installation."
                     )
            )
      )

      (if (= #deletion 0)
          (exit (quiet))
      )

      (set #commande
            (cat ('Delete >NIL: <NIL: "%s"' #outputdir)
                 (' all')
            )
      )

      (run #commande)
    )
)


(makedir #outputdir
         (infos))


; copie excluant : install, install.info, disk.info


(copyfiles (source (pathonly @icon))
           (dest   #outputdir)
           (pattern "~(disk|install)#?")
           (infos))


;================== tooltypes DEFTOOL modifiés ===================


(set #deftool (tackon #outputdir "voir/voir"))
(transcript "Updating tooltypes DEFTOOL.")

(tooltype (dest          (tackon #outputdir "peindre/peindre"))
          (settooltype "DEFTOOL" #deftool))

(tooltype (dest          (tackon #outputdir "util/convert24"))
          (settooltype "DEFTOOL" #deftool))