; Denna script installerar Lexikon med hjälp av installer.

; Kopiera Lexikon till valfri plats
; Kopiera Words till valfri plats
; Välja hur man anger katalog:
; från WB, från CLI eller med assign.

(complete 0)

(set lex_dest
	(askdir
		(prompt "Välj var Lexikon ska installeras\n"
		        "Katalogen 'Lexikon' skapas automatiskt här.")
		(help @askdir-help)
		(default @default-dest)
	)
)

(complete 10)

(set lex_dir (tackon lex_dest "Lexikon"))
(set @deafult-dest lex_dir)

; Skapa katalogen. kolla om den redan finns

(set extype (exists lex_dir))
(if (= extype 1) (abort "Filen \"Lexikon\" finns redan, ta bort den och försök igen."))
(if (= extype 2)
    (
        (if (exists (tackon lex_dir "Lexikon"))
            (
                (message
                    (cat "En kopia av 'Lexikon' finns redan."
                         " Om du fortsätter, kommer denna att updateras."
                         " Vissa filer blir överskrivna."
                    )
                )
            )
        )
    )
    (makedir lex_dir (infos))
)

(complete 20)

(copyfiles
	(prompt "Installerar Lexikon.")
	(help @copyfiles-help)
	(source "Lexikon")
	(dest lex_dir)
	(infos)
)

(complete 30)

(set word_dest
	(askdir
		(prompt "I vilken katalog ska ordlistan (Katalogen Words) installeras?")
		(help @askdir-help)
		(default lex_dir)
	)
)

(set worddrw
	(tackon
		(word_dest) ("words"))
)

(complete 40)
	
(copyfiles
	(prompt "Installerar ordlistan")
	(help @copyfiles-help)
	(source "Words")
	(dest worddrw)
	(all)
)

(complete 50)

(set Guidedir
	(askdir
		(prompt "Installerar onlinehjälp")
		(help (cat "När Lexikon.guide installerats finns online hjälp "
			   "i programmet på HELP-tangenten."))
		(default lex_dir)
	)
)

(complete 60)

(copyfiles
	(source "help/Svenska/Lexikon.guide")
	(dest Guidedir)
	(infos)
)

(complete 70)

(set start
	(askchoice
		(prompt "Hur vill du ange katalog för ordlistan?")
		(help @askchoice-help)
		(choices "Från WorkBench" "Från CLI" "Med assign LEXIKON:")
	)
)

(complete 80)

(copyfiles
        (prompt "Installera registreringsfil...")
        (source "Registrering")
        (dest lex_dir)
        (infos)
        (help @copyfiles-help)
)

(complete 90)

(if (= start 1)
	(tooltype
		(prompt "Lägger in katalogen i tooltype")
		(help "Lägger in katalogen för ordlistan som tooltype.\n"
		      "Dvs du behöver bara klicka på ikonen för att starta Lexikon.")
		(dest (tackon lex_dest "Lexikon"))
		(noposition)
		(settooltype "KATALOG" lex_dest)
		(confirm)
	)
)

(complete 95)

(if (= start 2)
	(if(askbool
			(prompt "Vill du göra en scriptfil för att starta Lexikon med de rätta parametrarna ?")
			(help "Om du svarar nej får du skriva in katalogen själv i CLI.\n"
			      "Annars behöver du bara starta en scriptfil i S: för start av Lexikon.")
			(default 1)
			(choices "Ja" "Nej")
		)

		(
		(set kommando
			(tackon lex_dest "Lexikon "))
		(set kommando
			(cat kommando word_dest))

		(set batchfile
			(askstring
				(prompt "Skriv namnet på filen för uppstart av Lexikon!")
				(help "Filen ifråga innehåller kommandon för att starta Lexikon med de rätta argumenten.")
				(default "Lex"))
		)
		(textfile
			(dest (tackon "S:" batchfile))
			(append kommando)
		)
		(protect
			(tackon "S:" batchfile) 64)
		)
	)
)

(if (= start 3)
	(startup "Lexikon"
		(prompt "En assign görs i S:Userstartup")
		(help @startup-help)
		(command "Assign LEXIKON: \"" word_dest "\"\n")
	)
)

(complete 100)