;
; $VER: IconLink installation 1.1 (04.9.2002)
;
; Copyright (c) 2000 Tom Granger and Christoph Gutjahr
;

;-------------------------------------------------
;
; Localization
;
(if (= @language "deutsch")
  (
    ;
    ; Deutsche Texte
    ;

    (set #bad-wb "AmigaOS 3.5 ist Vorraussetzung für die Nutzung von IconLink.rexx!")
    (set #bad-wblib "Das externe Programm \"CopyIcons\" benötigt workbench.library V 44+ (Bestandteil des BoingBag1 Archives)!")
    (set #welcome "Willkommen zur Installation von IconLink.rexx!")
    (set #whichversion "Welche Version von IconLink möchten Sie installieren?\nBitte beachten Sie die Hinweise im Kapitel \"Installation\" des Handbuchs.")
    (set #option1 "IconLink (OS 3.5 version)")
    (set #option2 "IconLink (OS 3.9 version)")
    (set #option3 "IconLink (OS 3.9 + reqtools.library version)")
    (set #warntooltype "Sie sind im Begriff, die normale OS 3.9 Version von IconLink zu installieren. Bitte lesen Sie unbedingt die Hinweise im Handbuch (Kapitel \"Installation\") zu dieser Version!")
    (set #selectdir "Bitte wählen Sie das Verzeichnis, in das IconLink.rexx kopiert werden soll!\nDefault ist REXX:")
    (set #selecttoolsdir "Bitte legen Sie fest, wohin die benötigten CLI-Tools kopiert werden sollen.\nDefault ist C:")
    (set #selectdocsdir "Bitte legen Sie fest, wohin die Anleitung (Amigaguide) kopiert werden soll.\nDefault ist HELP:")
    (set #askstarter "Wollen Sie 'LinkStarter.rexx' installieren?\n\n Dieses Skript wird benötigt, um dem 'Tools' Menü der Workbench zwei neue Menüpunkte hinzuzufügen. Sie benötigen 'Linkstarter.rexx' NICHT, wenn Sie Toolmanager, Toolsdaemon o.ä. installiert haben.\n\nDieses Skript wird in das Verzeichnis 'WBStartup' kopiert.")
    (set #copyrexx "Kopiere 'IconLink.rexx'...")
    (set #copydocs "Kopiere Anleitung...")
    (set #copycicon "Kopiere 'CopyIcon'...")
    (set #copywbrun "Kopiere 'WBRun'...")
    (set #copyicon "Kopiere Schublade 'Icons'...")
    (set #copystarter "Kopiere 'LinkStarter.rexx'")
    (set #yes "Ja")
    (set #no "Nein")
  )
  (
    ;
    ; English texts
    ;

    (set #bad-wb "You must have AmigaOS 3.5 or newer to be able to use IconLink!")
    (set #bad-wblib "You need workbench.library V 44+!\nto be able to use copyicons !\n(Get it from the BoingBag1 package on Amiga.com)")
    (set #welcome "Welcome to IconLink's Installation script !")
    (set #whichversion "Which version of IconLink would you like to install?\nPlease refer to the 'Installation' chapter of the manual for more information.")
    (set #option1 "IconLink (OS 3.5 version)")
    (set #option2 "IconLink (OS 3.9 version)")
    (set #option3 "IconLink (OS 3.9 + reqtools.library version)")
    (set #warntooltype "You're going to install the standard OS 3.9 version of IconLink. Please make sure you read the notes about this version (chapter 'installation' of the manual)!")
    (set #selectdir "Please select where to install IconLink.rexx.\nDefault is REXX:")
    (set #selecttoolsdir "Please select where to install the required CLI tools.\nDefault is C:")
    (set #selectdocsdir "Please select where to install the doc files.\nDefault is HELP:")
    (set #askstarter "Do you want to install 'LinkStarter.rexx' ?\n\n This script is needed to add two new menu items to Workbench's 'Tools' menu. You don't need 'LinkStarter' if you have Toolmanager, Toolsdaemon or similar installed!\n\nThis script will be installed in your 'WBStartup' drawer.")
    (set #copyrexx "Copying IconLink.rexx...")
    (set #copydocs "Copying docs...")
    (set #copycicon "Copying 'Copyicon'...")
    (set #copywbrun "Copying 'WBRun'...")
    (set #copyicon "Copying 'Icons' drawer...")
    (set #copystarter "Copying 'LinkStarter.rexx'")
    (set #yes "Yes")
    (set #no "No")
  )
)

;---------------------------------------------------------------------------
;
; Setup
;

(complete 0)

(if (< (getversion "SYS:c/loadwb") (* 44 65536))
  (abort #bad-wb)
)

(if (< (getversion "LIBS:workbench.library") (* 44 65536))
  (
  (abort #bad-wblib)
  )
  (
  (set #osver 44)
  (set #defaultversion 0)
  )
)

(if (> (getversion "LIBS:workbench.library") (* 44 65536))
  (
  (set #osver 45)
  (set #defaultversion 1)
  )
)

(set @rexx-dest "REXX:")
(set @tool-dest "C:")
(set @docs-dest "HELP:")
(set @icon-dest "SYS:Prefs/Presets/icons")
(set @wbstartup "SYS:WBStartup")

;----------------------------------------------------------------------------
;
; Welcome
;

(welcome #welcome)
(complete 5)

;----------------------------------------------------------------------------
;
; Setup target directories
;

(set #default-level @user-level)
(user 2)

(set #wanted_version
  (askchoice
    (prompt #whichversion)
    (help @askchoice-help)
    (choices #option1 #option2 #option3)
    (default #defaultversion)
  )
)
(if (= #wanted_version 1)
  (
  (message #warntooltype)
  )
)
(complete 10)

(set #copy_linkstarter
  (askbool
    (prompt #askstarter)
    (help @askbool-help)
    (choices #yes #no)
  )
)
(complete 15)

(set #docsdir
  (askdir
    (prompt #selectdocsdir)
    (help @askdir-help)
    (default @docs-dest)
  )
)

(user #default-level)
(complete 20)

(set #destdir
  (askdir
    (prompt #selectdir)
    (help @askdir-help)
    (default @rexx-dest)
  )
)
(complete 25)

(set #tooldir
  (askdir
    (prompt #selecttoolsdir)
    (help @askdir-help)
    (default @tool-dest)
  )
)
(complete 30)

(set @docs-dest #docsdir)
(set @default-dest #destdir)
(set @tool-dest #tooldir)

(makedir @icon-dest
  (help @makedir-help)
  (infos)
)
(complete 35)

;---------------------------------------------
;
; Copying IconLink.rexx
;

(if (= #wanted_version 0)
  (
  (set #sourcename "IconLink35.rexx")
  )
  (
  (if (= #wanted_version 1)
    (
    (set #sourcename "IconLink39.rexx")
    )
    (
    (set #sourcename "IconLink39RT.rexx")
    )
  )
  )
)
(complete 40)

(delete (tackon @default-dest "IconLink.rexx"))
(copyfiles
  (prompt #copyrexx)
  (help @copyfiles-help)
  (source (tackon "rexx/" #sourcename))
  (dest @default-dest)
  (infos)
  (confirm)
)
(rename (tackon @default-dest #sourcename) (tackon @default-dest "IconLink.rexx"))
(complete 50)

;------------------------------
;
; Copying all the other files
;

(copyfiles
  (prompt #copydocs)
  (help @copyfiles-help)
  (source "")
  (pattern "#?.guide")
  (dest @docs-dest)
  (infos)
  (confirm)
)
(complete 60)

(if (= #copy_linkstarter 1)
  (
  (copyfiles
    (prompt #copystarter)
    (help @copyfiles-help)
    (source "WBStartup/LinkStarter.rexx")
    (dest @wbstartup)
    (infos)
    (confirm)
  )
  )
)
(complete 70)

(copyfiles
  (help @copyfiles-help)
  (prompt #copycicon)
  (source "c/copyicon")
  (dest @tool-dest)
  (confirm)
)
(complete 80)

(if (= #osver 44)
  (
  (copyfiles
    (help @copyfiles-help)
    (prompt #copywbrun)
    (source "c/wbrun")
    (dest @tool-dest)
    (confirm)
  )
  )
)
(complete 90)

(copyfiles
  (help @copyfiles-help)
  (prompt #copyicon)
  (source "icons/")
  (pattern "def_#?")
  (dest @icon-dest)
  (confirm)
)
(complete 100)

;----------------------
;
; End
;

(exit)