;
; DepthMenu install script
; Copyright © 2001-2002 Arkadiusz [Yak] Wahlig
;
; $VER: DepthMenu_Install 1.18 (08.07.2002) Arkadiusz [Yak] Wahlig
;

(set #app-ver "2.36")
(set #copyright "Copyright © 2001-2002 Arkadiusz [Yak] Wahlig")

(IF (= @LANGUAGE "polski")
(
 (set #hello (cat "\n\n\n" @app-name " " #app-ver "\n" #copyright "\n\n\n\nTen skrypt zainstaluje program DepthMenu\nna twoim dysku twardym.") )

 (set #dir-question1 "Gdzie mam zainstalowaź program?")
 (set #dir-question2 "Zostanie tam stworzony katalog 'DepthMenu'.")
 (set #dir-help "Wybierz katalog, w którym ma byź zainstalowany program. W katalogu, który wybierzesz stworzony zostanie podkatalog 'DepthMenu' a do niego zostanā skopiowane wszystkie potrzebne pliki.")

 (set #languages-question "Które katalogi jėzykowe chcesz zainstalowaź?")
 (set #languages-help "Program posiada wbudowany jėzyk angielski. Jeōli chcesz aby uūywaī innego jėzyka, zaznacz go na tym ekranie a póśniej ustaw jėzyk go jako preferowany w systemowych ustawieniach Locale.")

 (set #docs-question "Które wersje dokumentacji chcesz zainstalowaź?")
 (set #docs-help "Program posiada róūne wersje jėzykowe dokumentacji. Na tym ekranie moūesz wybraź, które z nich majā byź zainstalowane.")

 (set #wbstartup-question "\n\nCzy chcesz uruchamiaź program przy starcie systemu?")
 (set #wbstartup-positive "Tak (zalecane)")
 (set #wbstartup-negative "Nie")
 (set #wbstartup-help "Jeōli wybierzesz 'Tak', DepthMenu bėdzie uruchamiany przy kaūdym starcie systemu. Z moūliwoōci tej moūna w kaūdej chwili zrezygnowaź poprzez poprzez wyrzucenie lub przeniesienie pliku START_DepthMenu.info z katalogu WBStartup.\n\nJeōli wybierzesz 'Nie' plik START_DepthMenu.info bėdzie skopiowany do katalogu z programem. Jeōli wiėc zdecydujesz siė na uruchamianie przy starcie systemu to musisz tylko przenieōź jen plik do katalogu WBStartup.")

 (set #start-question "\n\nCzy chcesz uruchomiź program teraz?")
 (set #start-help "Jeōli wybierzesz 'Tak', DepthMenu bėdzie uruchomiony i gotowy do pracy w tej chwili.")

 (set #bye-install "\n\nInstalacja zakoļczona pomyōlnie!")
 (set #bye-update "\n\nUpdate zakoļczony pomyōlnie!")
 (set #bye-thanks "\n\nDziėkujė za zainstalowanie programu.")
))
(IF (= @LANGUAGE "english")
(
 (set #hello (cat "\n\n\n" @app-name " " #app-ver "\n" #copyright "\n\n\n\nThis script will install DepthMenu program\non your hard-disk.") )

 (set #dir-question1 "Where should I install the program?")
 (set #dir-question2 "A directory called 'DepthMenu' will be created there.")
 (set #dir-help "Choose a directory, where the DepthMenu program should be installed. The installer will create a directory called 'DepthMenu', where all needed files will be copied.")

 (set #languages-question "Which catalogs should be installed?")
 (set #languages-help "DepthMenu's built-in language in english. If you want it to use some other languale you got to choose it now and set it as prefered in your Locale preferences program after installation.")

 (set #docs-question "Which documentations should be installed?")
 (set #docs-help "Program documentations are available in different languages. On this screen you can choose, which of them should be installed.")

 (set #wbstartup-question "\n\nDo you want to start DepthMenu at system startup?")
 (set #wbstartup-positive "Yes (recomended)")
 (set #wbstartup-negative "No")
 (set #wbstartup-help "If you choose 'Yes', DepthMenu will be started at every system startup. You can always disable it by removing file START_DepthMenu.info from SYS:WBStartup drawer.\n\nIf you choose 'No' you can always enable this feature by placing file START_DepthMenu.info in SYS:WBStartup drawer. In this case you will find this file in DepthMenu's directory.")

 (set #start-question "\n\nDo you want to start DepthMenu now?")
 (set #start-help "If you choose 'Yes', DepthMenu will be started and ready to work NOW.")

 (set #bye-install "\n\nInstallation successful finished!")
 (set #bye-update "\n\nUpdate successful finished!")
 (set #bye-thanks "\n\nThank you for installing DepthMenu.")
))

; powitanie
(complete 0)
(message #hello)

; gdzie instalowac?
(set #_dir
 (askdir
  (prompt (cat #dir-question1 " ") #dir-question2)
  (help #dir-help)
  (default "Work:")
  (disk)
 )
)

; tworzenie katalogu, rozpoznanie czy jest stara wersja (update)
(complete 10)
(set #_instdir (tackon #_dir "DepthMenu"))
(set #_update 0)
(if (exists #_instdir) (set #_update 1) (makedir #_instdir) )

; kopiujemy ikone katalogu
(copyfiles
 (source "/DepthMenu.info")
 (dest #_dir)
)

; kopiujemy pliki lokalizacyjne (z pytaniem ktore)
(complete 20)
(copyfiles
 (source "Catalogs")
 (dest (tackon #_instdir "Catalogs"))
 (infos)
 (pattern "~(#?.cd)")
 (prompt #languages-question)
 (help #languages-help)
 (confirm)
)
(copyfiles (source "Catalogs") (dest (tackon #_instdir "Catalogs")) (pattern "#?.cd#?"))
(copyfiles (source "Catalogs.info") (dest #_instdir))

; kopiujemy dokumentacje (z pytaniem ktore)
(complete 30)
(copyfiles
 (source "Docs")
 (dest (tackon #_instdir "Docs"))
 (infos)
 (all)
 (prompt #docs-question)
 (help #docs-help)
 (confirm)
)
(copyfiles (source "Docs.info") (dest #_instdir))

; kopiujemy program (bez ikony)
(complete 40)
(copyfiles (source "DepthMenu") (dest #_instdir))

; kopiujemy katalog modulow
(complete 50)
(copyfiles (source "Modules") (dest (tackon #_instdir "Modules")) (all))
(copyfiles (source "Modules.info") (dest #_instdir))

; ustawiamy defaulttool ikonki START_DepthMenu na wczesniej wybrana lokacje programu
(complete 60)
(tooltype (dest "InstallData/START_DepthMenu") (setdefaulttool (tackon #_instdir "DepthMenu")))

; usuwamy bardzo stara wersje (kiedys DepthMenu bylo umieszczane w WBStartup)
(complete 70)
(if(exists "SYS:WBStartup/DepthMenu")
(
 (delete "SYS:WBStartup/DepthMenu")
 (delete "SYS:WBStartup/DepthMenu.info")
))

; tu wchodzimy jesli instalujemy pierwszy raz
(if (= #_update 0)
(

; nie powinno tam tego byc, ale noz widelec
(complete 75)
(if(exists "SYS:WBStartup/START_DepthMenu.info")
(
 (delete "SYS:WBStartup/START_DepthMenu.info")
))

; kopiujemy ikone programu
(complete 80)
(copyfiles (source "DepthMenu.info") (dest #_instdir))

; pytamy sie o odpalanie z WBStartup i jesli tak to kopiujemy ikone
; jesli nie to kopiujemy ja do katalogu z programem (z plikiem readme)
(complete 85)
(if(askbool
 (prompt #wbstartup-question)
 (choices #wbstartup-positive #wbstartup-negative)
 (help #wbstartup-help)
 )
(copyfiles (source "InstallData/START_DepthMenu.info") (dest "SYS:WBStartup"))
(copyfiles (source "InstallData") (dest #_instdir) (infos) (pattern "START_DepthMenu#?"))
)

))

; pytamy sie o odpalenie programu teraz i odpalamy jesli tak
(complete 90)
(if(askbool
 (prompt #start-question)
 (help #start-help)
 )
(
 (run "InstallData/BreakDM")
 (run (cat "Run <>NIL: " (tackon #_instdir "DepthMenu")))
))

; kilka slow na pozegnanie z installerem
(complete 100)
(if (= #_update 0)
 (exit (cat #bye-install #bye-thanks) (quiet) )
 (exit (cat #bye-update #bye-thanks) (quiet) )
)