/* Convert to 8 colors, remap palette, cut body chunk
   ImageStudio script */

address command
options results
options failat 30

'echo Deleting old files'
'delete >nil: Ram:#?.body'
'echo Starting'
'list nohead lformat "%s%s" Util:Sfx/SongPlayer/Images >ram:b'
if ~open('names','ram:b','R') then do
 say 'File hiba'
end
else do
 address IMAGESTUDIO
 'pref_set previewredraw no'
 address
 do until eof('names')
  filename=readln('names')
  if filename~='' then do
   mf0=index(filename,'.mf0')
   if mf0~=0 then do
    savename=left(filename,mf0-1)'1.body'
   end
   mf1=index(filename,'.mf1')
   if mf1~=0 then do
    savename=left(filename,mf1-1)'2.body'
   end
   pa=lastpos('/',savename)
   if pa=0 then pa=lastpos(':',savename)
   savename='Ram:'delstr(savename,1,pa)
   'echo noline Processing 'filename'...'
   address IMAGESTUDIO
   'open 'filename
   'colours 8'
   'palette_load VSS:Sources/gfx/_remap-palette.ilbm'
   'save ram:a iff-ilbm nocompression force'
   address
   if ~open('file','ram:a','R') then do
    say 'Nem tudtam megnyitni'
   end
   else do
    xx=readch('file',250)
    pos=index(xx,'BODY')
    call seek('file',pos+7,'B')
    if ~open('out',savename,'W') then do
     say 'Nem tudtam uj fajlt letrehozni'
    end
    else do until eof('file')
     call writech('out',readch('file',10))
    end
    call close('out')
    call close('file')
   end
   'echo " Done"'
  end
 end
 call close('names')
 'delete >nil: ram:a ram:b'
 address IMAGESTUDIO 'pref_set previewredraw yes'
 'echo Exiting'
end