;
; DepthMenu module install script
; Copyright © 2001 Arkadiusz [Yak] Wahlig
;
; $VER: DepthMenu_Module_Install 1.00 (21.06.2001) Arkadiusz [Yak] Wahlig
;

(set #app-ver "1.1")
(set #copyright "Copyright © 2001-2002 Arkadiusz [Yak] Wahlig")

(IF (= @LANGUAGE "polski")
(
 (set #msg-powitanie (cat "\n\n\n" @app-name " " #app-ver "\nModuī programu DepthMenu\n" #copyright "\n\n\n\nTen skrypt zainstaluje moduī " @app-name "\nna twoim dysku twardym.") )
 (set #msg-koniec "\n\nInstalacja zakoļczona pomyōlnie!\n\nDziėkujė za zainstalowanie moduīu.\n\n\n\nJeōli DepthMenu jest uruchomiony to\nmoduī znajduje siė juū w pamiėci.")

 (set #katalog-pytanie "Gdzie zainstalowano program DepthMenu?")
 (set #katalog-pomoc "Wybierz katalog, w którym zainstalowaīeō/aō program DepthMenu (w którym znajduje siė podkatalog 'DepthMenu'). Zostanie tam zainstalowany moduī wraz z potrzebnymi plikami.")

 (set #jezyk-pytanie "Które katalogi jėzykowe chcesz zainstalowaź?")
 (set #jezyk-pomoc "Moduī posiada wbudowany jėzyk angielski. Jeōli chcesz aby uūywaī innego jėzyka, zaznacz go na tym ekranie a póśniej ustaw jėzyk go jako preferowany w systemowych ustawieniach Locale.")
))
(IF (= @LANGUAGE "english")
(
 (set #msg-powitanie (cat "\n\n\n" @app-name " " #app-ver "\nDepthMenu external module\nCopyright © 2001-2002 Arkadiusz [Yak] Wahlig\n\n\n\nThis script will install " @app-name "\non your hard-disk.") )
 (set #msg-koniec "\n\nInstallation successful finished!\n\nThank you for installing module.\n\n\n\nIf DepthMenu is running then\nmodule is already in memory.")

 (set #katalog-pytanie "Where did you install the DepthMenu program?")
 (set #katalog-pomoc "Choose a directory, where the DepthMenu program was installed (where is a 'DepthMenu' directory). The installer will copy all needed files there.")

 (set #jezyk-pytanie "Which catalogs should be installed?")
 (set #jezyk-pomoc "Module's built-in language in english. If you want it to use some other languale you got to choose it now and set it as prefered in your Locale preferences program after installation.")
))

(user 2)

(complete 0)
(message #msg-powitanie)

(set katalog
 (askdir
  (prompt #katalog-pytanie)
  (help #katalog-pomoc)
  (default "Work:")
  (disk)
 )
)

(set instdir (tackon katalog "DepthMenu"))

(complete 25)
(if (exists "Catalogs")
 (
  (copyfiles
   (source "Catalogs")
   (dest (tackon instdir "Catalogs"))
   (infos)
   (pattern "~(#?.cd)")
   (prompt #jezyk-pytanie)
   (help #jezyk-pomoc)
   (confirm)
  )
  (copyfiles (source "Catalogs") (dest (tackon instdir "Catalogs")) (pattern "#?.cd#?"))
 )
)

(complete 50)
(copyfiles (source "Docs") (dest (tackon instdir "Docs")) (all))

(complete 75)
(copyfiles (source "Modules") (dest (tackon instdir "Modules")) (all))

(complete 100)
(exit #msg-koniec (quiet))
(welcome "")