;
; DepthMenu install script
; Copyright © 2001 Arkadiusz [Yak] Wahlig
;
; $VER: DepthMenu_Install 1.12 (13.06.2001) Arkadiusz [Yak] Wahlig
;

(set #app-ver "2.30")
(set #copyright "Copyright © 2001-2002 Arkadiusz [Yak] Wahlig")

(IF (= @LANGUAGE "polski")
(
 (set #msg-powitanie (cat "\n\n\n" @app-name " " #app-ver "\n" #copyright "\n\n\n\nTen skrypt zainstaluje program DepthMenu\nna twoim dysku twardym.") )
 (set #msg-koniec "\n\nInstalacja zakoļczona pomyōlnie!\n\nDziėkujė za zainstalowanie programu.")

 (set #katalog-pytanie "Gdzie mam zainstalowaź program?")
 (set #katalog-stworzony "Zostanie tam stworzony katalog 'DepthMenu'.")
 (set #katalog-pomoc "Wybierz katalog, w którym ma byź zainstalowany program. W katalogu, który wybierzesz stworzony zostanie podkatalog 'DepthMenu' a do niego zostanā skopiowane wszystkie potrzebne pliki.")

 (set #jezyk-pytanie "Które katalogi jėzykowe chcesz zainstalowaź?")
 (set #jezyk-pomoc "Program posiada wbudowany jėzyk angielski. Jeōli chcesz aby uūywaī innego jėzyka, zaznacz go na tym ekranie a póśniej ustaw jėzyk go jako preferowany w systemowych ustawieniach Locale.")

 (set #wbstartup-pytanie "\n\nCzy chcesz uruchamiaź program przy starcie systemu?")
 (set #wbstartup-tak "Tak (zalecane)")
 (set #wbstartup-nie "Nie")
 (set #wbstartup-pomoc "Jeōli wybierzesz 'Tak', DepthMenu bėdzie uruchamiany przy kaūdym starcie systemu. Z moūliwoōci tej moūna w kaūdej chwili zrezygnowaź poprzez poprzez wyrzucenie lub przeniesienie pliku START_DepthMenu.info z katalogu WBStartup.\n\nJeōli wybierzesz 'Nie' plik START_DepthMenu.info bėdzie skopiowany do katalogu z programem. Jeōli wiėc zdecydujesz siė na uruchamianie przy starcie systemu to musisz tylko przenieōź jen plik do katalogu WBStartup.")

 (set #start-pytanie "\n\nCzy chcesz uruchomiź program teraz?")
 (set #start-pomoc "Jeōli wybierzesz 'Tak', DepthMenu bėdzie uruchomiony i gotowy do pracy w tej chwili.")
))
(IF (= @LANGUAGE "english")
(
 (set #msg-powitanie "\n\n\nDepthMenu 2.30\nCopyright © 2001-2002 Arkadiusz [Yak] Wahlig\n\n\n\nThis script will install DepthMenu program\non your hard-disk.")
 (set #msg-koniec "\n\nInstallation successful finished!\n\nThank you for installing DepthMenu.")

 (set #katalog-pytanie "Where should I install the program?")
 (set #katalog-stworzony "A directory called 'DepthMenu' will be created there.")
 (set #katalog-pomoc "Choose a directory, where the DepthMenu program should be installed. The installer will create a directory called 'DepthMenu', where all needed files will be copied.")

 (set #jezyk-pytanie "Which catalogs should be installed?")
 (set #jezyk-pomoc "DepthMenu's built-in language in english. If you want it to use some other languale you got to choose it now and set it as prefered in your Locale preferences program after installation.")

 (set #wbstartup-pytanie "\n\nDo you want to start DepthMenu at system startup?")
 (set #wbstartup-tak "Yes (recomended)")
 (set #wbstartup-nie "No")
 (set #wbstartup-pomoc "If you choose 'Yes', DepthMenu will be started at every system startup. You can always disable it by removing file START_DepthMenu.info from SYS:WBStartup drawer.\n\nIf you choose 'No' you can always enable this feature by placing file START_DepthMenu.info in SYS:WBStartup drawer. In this case you will find this file in DepthMenu's directory.")

 (set #start-pytanie "\n\nDo you want to start DepthMenu now?")
 (set #start-pomoc "If you choose 'Yes', DepthMenu will be started and ready to work NOW.")
))

(user 2)

(complete 0)
(message #msg-powitanie)

(set katalog
 (askdir
  (prompt (cat #katalog-pytanie " ") #katalog-stworzony)
  (help #katalog-pomoc)
  (default "Work:")
  (disk)
 )
)

(complete 10)
(set instdir (tackon katalog "DepthMenu"))
(if(NOT (exists instdir)) (makedir instdir))

(copyfiles
 (source "/DepthMenu.info")
 (dest katalog)
)

(complete 20)
(copyfiles
 (source "Catalogs")
 (dest (tackon instdir "Catalogs"))
 (infos)
 (pattern "~(#?.cd)")
 (prompt #jezyk-pytanie)
 (help #jezyk-pomoc)
 (confirm)
)
(copyfiles (source "Catalogs") (dest (tackon instdir "Catalogs")) (pattern "#?.cd#?"))
(copyfiles (source "Catalogs.info") (dest instdir))

(complete 30)
(copyfiles (source "Docs") (dest (tackon instdir "Docs")) (all))
(copyfiles (source "Docs.info") (dest instdir))

(complete 50)
(copyfiles (source "DepthMenu") (dest instdir) (infos))

(copyfiles (source "Modules") (dest (tackon instdir "Modules")) (all))
(copyfiles (source "Modules.info") (dest instdir))

(complete 60)
(copyfiles (source "DepthMenu_PL.readme") (dest instdir) (infos))
(copyfiles (source "DepthMenu_EN.readme") (dest instdir) (infos))

(tooltype (dest "InstallData/START_DepthMenu") (setdefaulttool (tackon instdir "DepthMenu")))

(complete 70)
(if(exists "SYS:WBStartup/DepthMenu")
(
 (delete "SYS:WBStartup/DepthMenu")
 (delete "SYS:WBStartup/DepthMenu.info")
))
(if(exists "SYS:WBStartup/START_DepthMenu.info")
(
 (delete "SYS:WBStartup/START_DepthMenu.info")
))

(if(askbool
 (prompt #wbstartup-pytanie)
 (choices #wbstartup-tak #wbstartup-nie)
 (help #wbstartup-pomoc)
 )
(copyfiles (source "InstallData/START_DepthMenu.info") (dest "SYS:WBStartup"))
(copyfiles (source "InstallData") (dest instdir) (infos) (all))
)

(complete 90)
(if(askbool
 (prompt #start-pytanie)
; (choices "Tak" "Nie")
 (help #start-pomoc)
 )
(run (cat "Run <>NIL: " (tackon instdir "DepthMenu")))
)

(complete 100)
(exit #msg-koniec (quiet))
(welcome "")