;* $VER: BEKUNA_install 1.5 (04.06.2002) Kuno Naumann
;*************************************************
; Script to install Bekuna1.9 Update

(complete 0)

;***** Texte Deutsch *****

(set msg_was "Installation für Bekuna 1.9 R4\n\nWas möchtst Du installieren?")
(set washilfe "Wähle, was Du installieren möchtest.\nNur das Programm oder die Anleitung, oder beides.")

(set msg_anl "Wohin soll die Anleitung kopiert werden?")
(set dokhilfe "Wähle eine beliebige Schublade, in die die Anleitung kopiert werden soll.")

(set msg_ende4 "Das Begrüßungsprogramm-Update ist jetzt installiert.")
(set msg_ende2 "Für eine Antwort, einen Fehlerbericht\noder bei Problemen, schreibe bitte an:\n\nkuno-n@freenet.de")
(set msg_ende3 "Bekuna konnte nicht installiert werden.\nBitte System überprüfen!\nStarte auch das Programm System-Test!\n\nBrauchst Du Hilfe?\nSo schreibe an:\n\nkuno-n@freenet.de")

;*****************************************************************
;***** FRAGEN *****

(complete 10)

(set var_was
   (askoptions
      (prompt msg_was)
      (help washilfe)
      (choices "BEKUNA.rexx (Update)" "Anleitung (Bekuna.guide)")
      (default 3)
   )
)

(complete 15)

(set pdir "REXX:")

(complete 16)
(if (= 0 (exists pdir))(
   (message "REXX: existiert nicht!\nBitte Startup-Sequence überprüfen!")
   (exit msg_ende3)
))
(complete 17)
(if (= 0 (exists "Sys:rexxc/rx"))(
   (message "Der AREXX-Startbefehl RX befindet sich nicht im Verzeichnis Sys:Rexxc !\nBitte System überprüfen!")
   (exit msg_ende3)
))
(complete 18)
(if (= 0 (exists "Sys:System/RexxMast"))(
   (message "Der AREXX-Interpreter RexxMast befindet sich nicht im Verzeichnis Sys:System !\nBitte System überprüfen!")
   (exit msg_ende3)
))
(complete 19)

(set @default-dest pdir)

(complete 20)

(set adir "Work:")

(if (bitand var_was 2)(
   (set adir
      (askdir
         (default "Work:")
         (help dokhilfe)
         (prompt (cat msg_anl))
      )
   )
   (set adir (tackon adir ""))
   (set @default-dest adir)
))

(if (bitand var_was 3)(
      (set @default-dest pdir)
))


;***** INSTALL BEKUNA *****

(complete 60)

(if (bitand var_was 1)(
   (copyfiles
      (source "BEKUNA.rexx")
      (dest pdir)
   )
   (copyfiles
      (source "Pikto.info")
      (dest "Rexx:Daten")
   )
))

;***** INSTALL ANLEITUNG *****

(complete 80)

(if (bitand var_was 2)(
   (copyfiles
      (source "Bekuna.guide")
      (choices "Bekuna.guide")
      (dest adir)
   )
   (if (= 0 (exists (tackon adir "Bekuna.guide.info")))
      (copyfiles
         (source "Bekuna.guide.info")
         (dest adir)
      )
   )
))

;***** ANLEITUNG LESEN *****

(complete 95)

(if (= 1 (exists "SYS:Utilities/Multiview"))
   (run "SYS:Utilities/Multiview Bekuna.guide" (safe))
)

;***** FERTIG *****

(complete 99)

(if (bitand var_was 1)(
   (complete 100)
   (exit (cat msg_ende4 "\n\n" msg_ende2))
))

(complete 100)
(exit)