dnl Process this file with autoconf to produce a configure script.

dnl initialization

AC_PREREQ(2.13)

AC_INIT(glElite/FrontCamera.h)
AC_CONFIG_HEADER(config.h)
AC_SUBST(SHELL)

dnl Detect the canonical host and target build environment.
AC_CANONICAL_HOST
AC_CANONICAL_TARGET

dnl Checks for programs.
AC_PROG_CXX
AC_PROG_CC
AC_PROG_RANLIB

dnl Figure out which OpenGL library to use
case "$target" in
  *-*-cygwin* | *-*-mingw32*)
    LIBS="-lopengl32 $LIBS"
    ;;
  *-*-beos*)
    LIBS="-lGL $LIBS"
    ;;
  *)
    AC_PATH_X
    AC_PATH_XTRA
    if test x$have_x = xyes; then
      CXXFLAGS="$CXXFLAGS $X_CFLAGS"
      LIBS="$X_LIBS -lGL $LIBS"
    else
      LIBS="-lGL $LIBS"
    fi
    ;;
esac


dnl Check for SDL
SDL_VERSION=1.2.2
AM_PATH_SDL($SDL_VERSION, , AC_MSG_ERROR([*** SDL version $SDL_VERSION not found!]))


dnl Check for OpenGL.
AC_MSG_CHECKING(for OpenGL support)
have_open_gl=no
AC_TRY_COMPILE([
	#include <GL/gl.h>
],[
],[
have_open_gl=yes
])
AC_MSG_RESULT($have_open_gl)
if test x$have_open_gl = xyes; then
	AC_DEFINE(HAVE_OPEN_GL)
else
	AC_MSG_WARN([Could not find OpenGL! - Using TinyGL software OpenGL subset rendering])
	AC_DEFINE(USE_TINY_GL)
fi
AC_SUBST(SYS_GL_LIBS)


dnl Checks for libraries.

dnl Check for libjpg library
AC_CHECK_LIB(jpeg, jpeg_CreateDecompress, [have_libjpeg=yes])
if test x$have_libjpeg = xyes; then
	LIBS="$LIBS -ljpeg"
	AC_DEFINE(HAVE_LIB_JPEG)
else
	AC_MSG_WARN([*** Unable to find JPEG library (http://www.ijg.org/)])
fi

dnl Check for libpng library
AC_CHECK_LIB(png, png_create_read_struct, [have_libpng=yes], , -lz)
if test x$have_libpng = xyes; then
	AC_DEFINE(HAVE_LIB_PNG)
	LIBS="$LIBS -lpng"
else
	AC_MSG_WARN([*** Unable to find PNG library (http://www.cdrom.com/pub/png/)])
fi

dnl Check for libz library
AC_CHECK_LIB(z, uncompress, [have_libz=yes])
if test x$have_libz = xyes; then
	AC_DEFINE(HAVE_LIB_Z)
	LIBS="$LIBS -lz"
else
	AC_MSG_WARN([*** Unable to find Zlib library (http://www.cdrom.com/pub/infozip/zlib/)])
fi

dnl Check for SDL_image library
AC_CHECK_LIB(SDL_image, IMG_Load, [have_SDL_image=yes], , $SDL_LIBS)
if test x$have_SDL_image = xyes; then
	LIBS="$LIBS -lSDL_image"
	AC_DEFINE(HAVE_LIB_SDL_IMAGE)
else
	AC_MSG_WARN([*** Unable to find SDL_image library (http://www.libsdl.org/projects/SDL_image/index.html)])
fi

dnl Check for SDL_mixer library
AC_CHECK_LIB(SDL_mixer, Mix_OpenAudio, [have_SDL_mixer=yes], , $SDL_LIBS)
if test x$have_SDL_mixer = xyes; then
	LIBS="$LIBS -lSDL_mixer"
	AC_DEFINE(HAVE_LIB_SDL_MIXER)
else
	AC_MSG_WARN([*** Unable to find SDL_mixer library (http://www.libsdl.org/projects/SDL_mixer/index.html)])
fi


dnl Generate Makefiles.
AC_OUTPUT(Makefile)

dnl Print summary.
echo "Configuration done. Now type \"make\"."