;$VER: RunArgs-Install 1.1 (13.1.2002) #INSTALL © Roger Hågensen <rescator@emsai.net> and Patrik Wikström <patrik.wikstrom@stonesoft.com>

;*****************************************************************************
;Install settings

(set @app-name "RunArgs")
(set @pretend 0)

(set @default-dest "")
(set #default-prognum (getversion (cat @app-name ".rexx")))
(set #default-progver (/ #default-prognum 65536))
(set #default-progrev (- #default-prognum (* #default-progver 65536)))
(set #default-progversion (" v%ld.%ld" #default-progver #default-progrev))

(set #default-language FALSE); Language Fallback variable

;*****************************************************************************
;Installer Language translations!

;Norwegian translation by Roger Hågensen <rescator@emsai.net>
(if (= @language "norsk")
 (
  (set #default-language TRUE)
  (set #wrongversion
   (cat "Du har en gammel versjon av programmet 'Installer' på din Amiga!\n\n"
        "Du er rådet til å bruke Installer V43!\n\n"
        "Vennligst sjekk din konfigurasjon!"
   )
  )
  (set #wrongwbversion
   (cat "Denne software installasjonen krever WB 3.5 eller høyere!\n\n"
        "Hvorfor ikke gå og kjøpe AmigaOS3.9? Det er verdt det...\n"
   )
  )
  (set #welcome
   (cat "Velkommen til Installasjonen av\n\n"
        @app-name ".rexx" #default-progversion
        "\n\n© Roger Hågensen 2001-2002, Freely Distributable.\n"
        "og Patrik Wikström.\n"
   )
  )
  (set #guide-prompt "Vennligst velg hvor AmigaGuide dokumentet\nskal installeres.\n")
  (set #guide-help "Det er altid lurt å lagre dokumentet for senere referanse.")
  (set #no-diskspace
   (cat "For å installere" @app-name "til " #default-path
        ", trenger du minst %ld bytes med ledig harddisk plass!"
   )
  )
 )
)

;*****************************************************************************
;English text... (default) DO NOT TOUCH!

(if (= #default-language FALSE)
 (
  (set #wrongversion
   (cat "You have an old version of the program 'Installer' on your Amiga!\n\n"
        "It is highly advised you use Installer V43!\n\n"
        "Please check your configuration!"
   )
  )
  (set #wrongwbversion
   (cat "This software installation require WB 3.5 or higher!\n\n"
        "Why don't you go and buy AmigaOS3.9? It's worth it...\n"
   )
  )
  (set #welcome
   (cat "Welcome to the Installation of\n\n"
        @app-name ".rexx" #default-progversion
        "\n\n© Roger Hågensen 2001-2002, Freely Distributable.\n"
        "Additional coding by Patrik Wikström.\n"
   )
  )
  (set #guide-prompt "Please select where the AmigaGuide document\nshould be installed.\n")
  (set #guide-help "It is always wise to store the documentation for later reference.")
  (set #no-diskspace
   (cat "To install" @app-name "into " #default-path
        ", you need at least %ld bytes of free harddrive space!"
   )
  )
 )
)

;*****************************************************************************

;Check if it is Installer 43 or higher!
(if (< (/ @installer-version 65536) 43)
 (
  (message #wrongversion)
  (exit (quiet))
 )
)         

;Check if it the user have WB 3.5/3.9 or higher!
(if (< (/ (getversion "LIBS:workbench.library") 65536) 44)
 (
  (message #wrongwbversion)
  (exit (quiet))
 )
)

;Welcome message!
(message #welcome)
(complete 0)

;*****************************************************************************
;Installing program...

(copylib
 (source "RunArgs.rexx")
 (dest "REXX:")
 (optional oknodelete "force" "askuser")
)
(complete 25)

;*****************************************************************************
;Installing system/support files...

(copylib
 (source "libs/rexxdossupport.library")
 (dest "LIBS:")
 (optional oknodelete "force" "askuser")
)
(complete 50)

;*****************************************************************************
;Installing WBStartEmu stuff...

(copylib
 (source "c/wbrun")
 (dest "C:")
 (optional oknodelete "force" "askuser")
)
(copylib
 (source "libs/wbstart.library")
 (dest "LIBS:")
 (optional oknodelete "force" "askuser")
)
(copylib
 (source "l/WBStart-handler")
 (dest "L:")
 (optional oknodelete "force" "askuser")
)
(complete 75)

;*****************************************************************************
;Install documentation

(set docs (askdir
           (prompt #guide-prompt)
           (help #guide-help)
           (default "HELP:")
           (disk)
          )
)
(copylib
 (source (cat @app-name ".Guide"))
 (dest docs)
 (optional oknodelete "force" "askuser")
)
(copyfiles
 (source (cat @app-name ".Guide.info"))
 (dest docs)
 (optional oknodelete "force" "askuser")
)
(complete 90)

(copyfiles
 (source (cat @app-name ".ilbm"))
 (dest docs)
 (optional oknodelete "force" "askuser")
)
(complete 100)

;*****************************************************************************
;That's it!
(exit)

(welcome) ;A trick to lure the installer, get's rid of the auto welcome
          ;message and no log/print questions etc :D
;*****************************************************************************
;END of Install