;* $VER: BEKUNA_install 1.0 (11.02.2002) Kuno Naumann
;*************************************************
; Script to install Begrüßung

(complete 0)

;***** Texte Deutsch *****

(set msg_was "Was möchten Sie installieren?")
(set msg_start "Wohin soll das Startprogramm (Begrüßung) für >BEKUNA.rexx< installiert werden?\nStandard ist das Verzeichnis SYS:WBStartup.")
(set msg_anl "Wohin soll die Anleitung kopiert werden?")
(set msg_hg "Sollen die Vorgabe-Hintergründe für die Programmfenster, installiert werden?\nSie werden in die Schublade >Sys:Prefs/Presets/Pattern/Einfarbig/< kopiert.")
(set msg_som "Welche Zeit haben wir jetzt?")
(set msg_us1 "Damit das Programm bei jedem Neustart gestartet wird, ist folgender Eintrag in die User-Startup notwendig.")
(set msg_us2 "Soll dies eingefügt werden?")

(set washilfe "Wählen Sie, was Sie installieren möchten. Nur das Programm oder die Anleitung, oder beides.")
(set starthilfe "Wählen Sie eine Schublade, in die das Start-Programm kopiert werden soll.\nStandard ist SYS:WBStartup, damit das Begrüßungsprogramm bei jedem Neustart gestartet wird.\nWird eine andere Schublade gewählt, so kann das Programm nur manuell, oder von der User-Startup aus, gestartet werden.")
(set dokhilfe "Wählen Sie eine beliebige Schublade, in die die Anleitung kopiert werden soll.")
(set somhilfe "Damit das Programm automatisch auf Sommerzeit umschalten kann, muss die Variable SUMMERTIME auf den richtigen Anfangswert gesetzt werden.\nGeben Sie an, ob wir zur Zeit, Mitteleuropäische Sommerzeit haben, oder nicht.")
(set hghilfe "Wenn Sie hier NEIN wählen, so werden alle zusätzlichen Fenster ohne Hintergrundmuster geöffnet. Sie haben dann die Möglichkeit, andere Hintergrundmuster im Programmmenü EINSTELLUNGEN auszuwählen.")
(set ushilfe "Damit das Programm bei jedem Neustart des Rechners automatisch gestartet wird, muss sich das Startprogramm Begrüßung in der Schublade WBStartup befinden, oder dieser Eintrag in die User-Startup erfolgen.")

(set msg_pstart "Das Programm BEKUNA wird jetzt gestartet. Sie können nun Ihre ersten Einstellungen vornehmen.")
(set msg_ende1 "Das Begrüßungsprogramm ist jetzt installiert und wird nach jedem Neustart ausgeführt.")
(set msg_ende2 "Für eine Antwort oder ein Fehlerbericht, schreiben Sie bitte an:\n\nkuno-n@freenet.de")

;*****************************************************************
;***** FRAGEN *****

(complete 10)

(set var_was
   (askoptions
      (prompt msg_was)
      (help washilfe)
      (choices "Begrüßungsprogramm (BEKUNA.rexx)" "Anleitung")
      (default 3)
   )
)

(complete 20)

(set sdir "SYS:WBStartup")

(if (bitand var_was 1)(
   (set sdir
      (askdir
         (default sdir)
         (help starthilfe)
         (prompt (cat msg_start))
      )
   )
   (set sdir (tackon sdir ""))
   (set @default-dest "REXX:")
))

(complete 30)

(set adir "Work:")

(if (bitand var_was 2)(
   (set adir
      (askdir
         (default "Work:")
         (help dokhilfe)
         (prompt (cat msg_anl))
      )
   )
   (set adir (tackon adir ""))
   (set @default-dest adir)
))

(if (= 0 (bitand var_what 3))
   (
      (set @default-dest "REXX:")
   )
)

(complete 40)

(if (bitand var_was 1)
   (set var_sz
      (askchoice
         (prompt msg_som)
         (help somhilfe)
         (choices "keine Sommerzeit" "Sommerzeit")
         (default 0)
      )
   )
)

(complete 50)

(if (bitand var_was 1)
   (set var_hg
      (askchoice
         (prompt msg_hg)
         (help hghilfe)
         (choices "JA" "NEIN")
         (default 0)
      )
   )
)

;***** INSTALL BEGRÜSSUNG *****

(complete 60)

(if (bitand var_was 1)(
   (copyfiles
         (source "Begrüßung")
         (dest sdir)
   )
   (if (= 0 (exists (tackon sdir "Begrüßung.info")))
      (copyfiles
         (source "Begrüßung.info")
         (dest sdir)
      )
   )
   (if (= 0 var_sz)
      (run "SetEnv summertime SAVE NO")
   )
   (if (= 1 var_sz)
      (run "SetEnv summertime SAVE YES")
   )
   (copyfiles
      (source "BEKUNA.rexx")
      (dest "REXX:")
   )
   (copyfiles
      (source "datumd")
      (dest "REXX:")
   )
   (copyfiles
      (source "showtx")
      (dest "REXX:")
   )
   (copyfiles
      (source "errord")
      (dest "REXX:")
   )
   (copyfiles
      (source "mond")
      (dest "REXX:")
   )
   (copyfiles
      (source "round")
      (dest "REXX:")
   )
   (makedir "REXX:Daten")
))

;***** INSTALL ANLEITUNG *****

(complete 70)

(if (bitand var_was 2)(
   (copyfiles
      (source "Anleitung")
      (choices "Anleitung")
      (dest adir)
   )
   (if (= 0 (exists (tackon adir "Anleitung.info")))
      (copyfiles
         (source "Anleitung.info")
         (dest adir)
      )
   )
))

;***** INSTALL HINTERGRUND *****

(complete 80)

(if (bitand var_was 1)(
   (if (= 0 var_hg)
      (copyfiles
         (source "Einfarbig")
         (dest "SYS:Prefs/Presets/Patterns/Einfarbig")
         (all)
      )
   )
))

;***** USER-STARTUP *****

(complete 90)

(if (bitand var_was 1)(
   (if (= 0 (patmatch "WBStartup" (fileonly (pathonly sdir))))(
      (set uscommandline (cat "Run > NIL: rx bekuna"))
      (startup "BEKUNA"
         (prompt msg_us1 "\n\n" uscommandline "\n\n" msg_us2)
         (help ushilfe)
         (command uscommandline)
      )
   ))
))

;***** ANLEITUNG LESEN *****

(complete 95)

(run "SYS:Tools/Editpad Anleitung" (safe))

;***** FERTIG *****

(complete 100)

(message msg_pstart)

(run "rx bekuna")

(exit (cat msg_ende1 "\n\n" msg_ende2))