/* Conversion des pastilles simple face en double face */
/* Version 1.00: 7 novembre 2001
   Version 1.01: 2 décembre 2001 (localisation anglais)
   Version 1.02: 27 décembre 2001 (ajout SAVEALL, pastilles sur sérigraphie ignorées)
   Version 1.03, 03-Feb-2002, German localization by A. Greve
   $VER: DoublePads.AmiPCB 1.02, © R.Florac, 3/2/2002
********************************************************/

options results     /* indispensable pour récupérer le résultat des macros */

signal on error     /* pour l'interception des erreurs */
signal on syntax

fr='ARexx/InitVars.AmiPCB'()

np=0
'FINDOBJ(0,-PAD,-1,-1)'
p=result
if p>0 then '_P_=-PAD'
else do
    'FINDOBJ(0,PAD,-1,-1)'
    p=result
    '_P_=PAD'
end
do while p>0
    'SETSIDE('p',0)'
    if result ~= 4 then do	/* pour éviter les pastilles placées côté sérigraphie */
	'SETPAD('p',0,-1,-1,-1)'
	t=result
	if t>0 then do
	    if np=0 then 'SAVEALL'
	    np=np+1
	    'SETPAD('p',-'t',-1,-1,-1)'
	end
    end
    'FINDOBJ('p',_P_,-1,-1)'
    p=result
end
select
    when fr=1 then 'MESSAGE("'np' pastilles traitées")'
    when fr=2 then 'MESSAGE("'np' konvertierte Pads")'
    otherwise	   'MESSAGE("'np' converted pads")'
end
exit

/* Traitement des erreurs, interruption du programme */
syntax:
erreur=RC
Call 'ARexx/_Syntax.rexx'(fr,'DoublePads.AmiPCB',SIGL,erreur)
exit

error:
Call 'ARexx/_Error.rexx'(fr,'DoublePads.AmiPCB',SIGL)
exit