/*
	PerfectPaint StartUp Script
	Load Random Backgrounds
	V1.0
*/

	options results
	parse ARG Port b	
	ADDRESS value Port

	Desktop_path='PerfectPaint:'
	Requester_path='PerfectPaint:'

	IF EXISTS('PerfectPaint:Prefs/Rd_Backgrounds') THEN DO
		IF OPEN('lfile','PerfectPaint:Prefs/Rd_Backgrounds', "R") then DO
			Desktop_path=READLN('lfile')
			Requester_path=READLN('lfile')
			CALL CLOSE('lfile')
		END
	END
	ELSE
	DO
		pp_DialogInit 330 90 "*Random*Backgrounds*" 5
			pp_Text 4 10 20 "Select*Path*for:"
			pp_String 0 140 20 150 16 "Backgrounds*Desktop" 1 100 'PerfectPaint:'
			pp_Getfile 1 295 21 0 "Select*Path" 1 'PerfectPaint:'
			pp_String 2 140 40 150 16 "Backgrounds*Requester" 1 100 'PerfectPaint:'
			pp_Getfile 3 295 41 2 "Select*Path" 1 'PerfectPaint:'
		pp_Dialog
		IF result=0 then EXIT

		pp_GetDialog 1
		Desktop_path=result

		pp_GetDialog 3
		Requester_Path=result	

		IF OPEN('pfile','PerfectPaint:Prefs/Rd_Backgrounds','W') THEN DO
			CALL WRITELN('pfile',Desktop_path)
			CALL WRITELN('pfile',Requester_path)
			CALL CLOSE('pfile')
		END

	END

ADDRESS COMMAND 'List >ram:script1 '||Desktop_path||' NOHEAD LFORMAT="%s"'
ADDRESS COMMAND 'List >ram:script2 '||Requester_path||' NOHEAD LFORMAT="%s"'

i=0
IF OPEN('listfile',"ram:script1") THEN DO
	DO FOREVER
		fline = READLN('listfile')
		IF EOF('listfile') THEN BREAK
		i=i+1
		nom1.i=fline
	END
	CALL CLOSE('listfile')
END
i1=i

i=0
IF OPEN('listfile',"ram:script2") THEN DO
	DO FOREVER
		fline = READLN('listfile')
		IF EOF('listfile') THEN BREAK
		i=i+1
		nom2.i=fline
	END
	CALL CLOSE('listfile')
END
i2=i

IF OPEN('listfile',"perfectpaint:prefs/Backgrounds") THEN DO
	Mode=READLN('listfile')
	CALL CLOSE('listfile')
	ADDRESS COMMAND	'delete >nil:PerfectPaint:Prefs/Backgrounds'
END
ELSE
DO
	Mode=1
END

R1=random(1,i1,time(s))
R2=random(1,i2,time(s))

CALL OPEN(out,'PerfectPaint:Prefs/Backgrounds',write)
CALL WRITELN(out,Mode)
CALL WRITELN(out,Desktop_path||nom1.R1)
CALL WRITELN(out,Requester_path||nom2.R2)
CALL CLOSE(out)

EXIT